aqhomecontrol/avr/modules/lcd2/gui/base/dialog.asm

; ***************************************************************************
; copyright   : (C) 2026 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************

#ifndef AQH_AVR_GUI_BASE_DIALOG_ASM
#define AQH_AVR_GUI_BASE_DIALOG_ASM


; ***************************************************************************
; defines

; DIALOG data
.equ DIALOG_OFFS_BEGIN            = MAINWINDOW_SIZE
.equ DIALOG_SIZE                  = DIALOG_OFFS_BEGIN+0


; selectors
.equ DIALOG_SEL_OKBUTTON    = 1
.equ DIALOG_SEL_ABORTBUTTON = 2
.equ DIALOG_SEL_NEXTFREE    = 3



; ***************************************************************************
; code

.cseg



; ---------------------------------------------------------------------------
; @routine Dialog_Init @global
;
; @param Y pointer to MainWindow
; @param X pointer to root window
; @param R21:R20 title ressource
; @return CFLAG set of okay, cleared otherwise
; @clobbers any, !Y

Dialog_Init:
  ldi r16, 0                                                                                           ; OPTS
  ldi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; PACK
  bigcall MainWindow_Init
  brcc Dialog_Init_ret

  ; set default signal map
  ldi r16, LOW(Dialog_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
  ldi r16, HIGH(Dialog_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16

Dialog_Init_ret:
  ret
; @end




; ---------------------------------------------------------------------------
; @routine Dialog_AddDefaultButtons @global
;
; @param Y pointer to MainWindow
; @clobbers any, !Y

Dialog_AddDefaultButtons:
  bigcall MainWindow_GetContentWidget  ; r19:r18=content window
  brcc Dialog_AddDefaultButtons_ret
  mov xl, r18                          ; use content window as parent
  mov xh, r19

  ; create HLayout
  push yl
    push yh
      ldi r16, 0                                                                                     ; OPTS
      ldi r17, (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_END<<WIDGET_PACK_VSELF0_BIT) ; PACK
      ldi r20, HLAYOUT_MODE_EXPAND
      bigcall HLayout_new
      mov xl, yl                   ; use layout as new parent
      mov xh, yh
    pop yh
  pop yl
  brcc Dialog_AddDefaultButtons_ret
  
  ; create OK button
  ldi r20, LOW(RESSOURCE_TXT_DIALOGOK)
  ldi r21, HIGH(RESSOURCE_TXT_DIALOGOK)
  ldi r22, DIALOG_SEL_OKBUTTON
  rcall dialogCreateButton
  brcc Dialog_AddDefaultButtons_ret

  ; create Abort button
  ldi r20, LOW(RESSOURCE_TXT_DIALOGABORT)
  ldi r21, HIGH(RESSOURCE_TXT_DIALOGABORT)
  ldi r22, DIALOG_SEL_ABORTBUTTON
  rcall dialogCreateButton
  brcc Dialog_AddDefaultButtons_ret

  ; change style of HLayout (more space)
  adiw xh:xl, WIDGET_OFFS_STYLE_LO
  ldi r16, LOW(Dialog_HLayoutStyle*2)
  st X+, r16
  ldi r16, HIGH(Dialog_HLayoutStyle*2)
  st X, r16
  sec

Dialog_AddDefaultButtons_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine dialogCreateButton
;
; @param Y       pointer to MainWindow (target)
; @param r21:r20 text ressource
; @param r22     selector
; @clobbers any, !X, !Y, !Z

dialogCreateButton:
  push zl
    push zh
      push yl
        push yh
          ldi r16, (1<<WIDGET_OPTS_BORDER_BIT)                                                           ; OPTS
          ldi r17, (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_END<<WIDGET_PACK_VSELF0_BIT) ; PACK
          ldi r23, BUTTON_MODE_NORMAL
          push xl
            push xh
              bigcall TextButton_new
            pop xh
          pop xl
          mov zl, yl
          mov zh, yh
        pop yh
      pop yl
      brcc dialogCreateButton_done
      std Z+OBJECT_OFFS_TARGET_LO, yl
      std Z+OBJECT_OFFS_TARGET_HI, yh
      ; set button style
      push xl
        push xh
          push yl
            push yh
              mov yl, zl
              mov yh, zh
              ldi xl, LOW(DefaultStyle_SpacyButton*2)
              ldi xh, HIGH(DefaultStyle_SpacyButton*2)
              bigcall Widget_SetStyle
            pop yh
          pop yl
        pop xh
      pop xl
      sec
dialogCreateButton_done:
    pop zh
  pop zl  
  ret
; @end




; ***************************************************************************
; signal handlers

Dialog_OnOk:
  ; TODO: emit signal
  sec
  ret
; @end


Dialog_OnAbort:
  ; TODO: emit signal
  sec
  ret
; @end




; ***************************************************************************
; data in FLASH

; ---------------------------------------------------------------------------
; @data Dialog_HLayoutStyle

Dialog_HLayoutStyle:
  .dw STYLE_WIN_FGCOL_NORM           ; frontCol_norm
  .dw STYLE_WIN_BGCOL_NORM           ; backCol_norm
  .dw STYLE_WIN_BORDERCOL_NORM       ; borderCol_norm
  .dw STYLE_WIN_SHADOWCOL_NORM       ; shadowCol_norm
  
  .dw STYLE_WIN_FGCOL_ACTIVATED      ; frontCol_activated
  .dw STYLE_WIN_BGCOL_ACTIVATED      ; backCol_activated
  .dw STYLE_WIN_BORDERCOL_ACTIVATED  ; borderCol_activated
  .dw STYLE_WIN_SHADOWCOL_ACTIVATED  ; shadowCol_activated

  .db 2, 10                          ; outerBorderSize, innerBorderSize
  .dw (STYLE_WIN_FONT*2)             ; font
  .db STYLE_WIN_FONT_WIDTH, \
      STYLE_WIN_FONT_HEIGHT          ; charWidth, charHeight
; @end



Dialog_DefaultSignalmap:
  ; header
  .dw MainWindow_DefaultSignalmap*2  ; next table to use
  ; entries
  .db DIALOG_SEL_OKBUTTON,    WIDGET_SIGNAL_COMMAND,  LOW(Dialog_OnOk),    HIGH(Dialog_OnOk)
  .db DIALOG_SEL_ABORTBUTTON, WIDGET_SIGNAL_COMMAND,  LOW(Dialog_OnAbort), HIGH(Dialog_OnAbort)
  ; end of table
  .db 0, 0, 0, 0




#endif