martin/aqhomecontrol
Public Access
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
Files
ea83c46cb500ba54b348c6ffad6e6f2f06019f06
aqhomecontrol/avr/comproto.asm
Martin Preuss 910bb78e52 COMPROTO: Added CPRO_EnqueueNeedAddress
2023-02-04 16:01:48 +01:00

440 lines
10 KiB
NASM
Raw Blame History

; ***************************************************************************
; defines
.equ CPRO_CMD_PING = 10
.equ CPRO_CMD_PONG = 11
.equ CPRO_CMD_COMSENDSTATS = 20
.equ CPRO_CMD_COMRECVSTATS = 21
.equ CPRO_CMD_I2CBUSMEMBER = 30
.equ CPRO_CMD_DEBUG = 40
.equ CPRO_CMD_VALUE = 50
.equ CPRO_CMD_NEED_ADDRESS = 60
.equ CPRO_CMD_HAVE_ADDRESS = 61
; ***************************************************************************
; data
.dseg
; ***************************************************************************
; code
.cseg
; ---------------------------------------------------------------------------
; Enqueue a PING packet.
;
; IN:
; - R16: destination address
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R18, R20 (R15, R16, R17, X, Y)
CPRO_EnqueuePing:
ldi r18, CPRO_CMD_PING
ldi r20, COM_BUFFER_PRIO_INFO
rjmp cproEnqueueMsgWithCmdAndSrcAddr
; ---------------------------------------------------------------------------
; Enqueue a PONG packet.
;
; IN:
; - R16: destination address
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R18, R20 (R15, R16, R17, X, Y)
CPRO_EnqueuePong:
ldi r18, CPRO_CMD_PONG
ldi r20, COM_BUFFER_PRIO_INFO
rjmp cproEnqueueMsgWithCmdAndSrcAddr
; ---------------------------------------------------------------------------
; Enqueue a COM Send stats packet.
;
; IN:
; - R16: destination address
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
CPRO_EnqueueComSendStats:
push r15
in r15, SREG
cli
push r16
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r16
brcc CPRO_EnqueueComSendStats_error
clr r17 ; r17: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r17, r16
ldi r16, 12 ; 8 bytes payload
st X+, r16
eor r17, r16
; write payload
ldi r16, CPRO_CMD_COMSENDSTATS ; 0: cmd
st X+, r16
eor r17, r16
lds r16, comAddress ; 1: src addr
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs ; 2-5: current seconds counter
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+1
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+2
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+3
st X+, r16
eor r17, r16
lds r16, comStatsPacketsOut ; 6: packets out
st X+, r16
eor r17, r16
lds r16, comStatsPacketsOut+1
st X+, r16
eor r17, r16
lds r16, comStatsCollisions ; 8: collisions
st X+, r16
eor r17, r16
lds r16, comStatsCollisions+1
st X+, r16
eor r17, r16
lds r16, comStatsAborted ; 10: aborted
st X+, r16
eor r17, r16
lds r16, comStatsAborted+1
st X+, r16
eor r17, r16
; store XOR byte
st X+, r17
; mark buffer as enqueued with PRIO "info" (limited amount of retries)
ldi r20, COM_BUFFER_PRIO_INFO
rcall COM_EnqueuePacket ; (R15, R16)
brcc CPRO_EnqueueComSendStats_error
pop r15
out SREG, r15
sec
ret
CPRO_EnqueueComSendStats_error:
pop r15
out SREG, r15
clc
ret
; ---------------------------------------------------------------------------
; Enqueue a I2C Bus Member packet.
;
; IN:
; - R16: destination address
; - R1 : Address of the bus member
; - R2 : availability (0=not available, 1=available)
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
CPRO_EnqueueI2cBusMember:
push r16
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r16
brcc CPRO_EnqueueI2cBusMember_error
clr r17 ; r17: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r17, r16
ldi r16, 4 ; 4 bytes payload
st X+, r16
eor r17, r16
; write payload
ldi r16, CPRO_CMD_I2CBUSMEMBER ; send command
st X+, r16
eor r17, r16
lds r16, comAddress ; send source address
st X+, r16
eor r17, r16
mov r16, r1 ; send i2c bus member address
st X+, r16
eor r17, r16
mov r16, r2 ; send i2c bus member availability
st X+, r16
eor r17, r16
; store XOR byte
st X+, r17
; mark buffer as enqueued with PRIO "info" (limited amount of retries)
ldi r20, COM_BUFFER_PRIO_INFO
rcall COM_EnqueuePacket ; (R15, R16)
brcc CPRO_EnqueueI2cBusMember_error
sec
ret
CPRO_EnqueueI2cBusMember_error:
clc
ret
; ---------------------------------------------------------------------------
; Enqueue a DEBUG packet.
;
; IN:
; - R16: destination address
; - R1: debug value 1
; - R2: debug value 2
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
CPRO_EnqueueDebug:
push r16
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r16
brcc CPRO_EnqueueDebug_error
clr r17 ; r17: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r17, r16
ldi r16, 4 ; 2 bytes payload
st X+, r16
eor r17, r16
; write payload
ldi r16, CPRO_CMD_DEBUG
st X+, r16
eor r17, r16
lds r16, comAddress
st X+, r16
eor r17, r16
mov r16, r1 ; debug 1
st X+, r16
eor r17, r16
mov r16, r2 ; debug 2
st X+, r16
eor r17, r16
; store XOR byte
st X+, r17
; mark buffer as enqueued with PRIO "info" (limited amount of retries)
ldi r20, COM_BUFFER_PRIO_INFO
rcall COM_EnqueuePacket ; (R15, R16)
brcc CPRO_EnqueueDebug_error
sec
ret
CPRO_EnqueueDebug_error:
clc
ret
; ---------------------------------------------------------------------------
; Enqueue a VALUE packet.
;
; IN:
; - R16: destination address
; - R17: value id
; - R19:R18: value
; - R21:R20: denom (e.g. 100, meaning value must be divided by 100)
; - R22: value type
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS:
CPRO_EnqueueValue:
push r16
push r17
push r21
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r21
pop r17
pop r16
brcc CPRO_EnqueueValue_error
clr r1 ; r1: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r1, r16
ldi r16, 12 ; 12 bytes payload
st X+, r16 ; msglen
eor r1, r16
; write payload
ldi r16, CPRO_CMD_VALUE ; 0: msg type
st X+, r16
eor r1, r16
lds r16, comAddress ; 1: source address
st X+, r16
eor r1, r16
lds r16, timerModuleCounterSecs ; 2-5: current seconds counter
st X+, r16
eor r1, r16
lds r16, timerModuleCounterSecs+1
st X+, r16
eor r1, r16
lds r16, timerModuleCounterSecs+2
st X+, r16
eor r1, r16
lds r16, timerModuleCounterSecs+3
st X+, r16
eor r1, r16
st X+, r17 ; 6: value id
eor r1, r17
st X+, r22 ; 7: value type
eor r1, r22
st X+, r18 ; 8: low value
eor r1, r18
st X+, r19 ; 9: high value
eor r1, r19
st X+, r20 ; 10: low denom
eor r1, r20
st X+, r21 ; 11: high denom
eor r1, r21
; store XOR byte
mov r16, r1
st X+, r16
; mark buffer as enqueued with PRIO "normal" (slightly limited number of retries)
ldi r20, COM_BUFFER_PRIO_NORMAL
rcall COM_EnqueuePacket ; (R15, R16)
brcc CPRO_EnqueueValue_error
sec
ret
CPRO_EnqueueValue_error:
clc
ret
; ---------------------------------------------------------------------------
; Enqueue a NEEDADDRESS packet.
;
; IN:
; - R16: destination address
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R16, R18, R19, R20, R21, X, Y (R15, R17)
CPRO_EnqueueNeedAddress:
push r16
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r16
brcc CPRO_EnqueueNeedAddress_error
clr r1 ; r1: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r1, r16
ldi r16, 6 ; 6 bytes payload
st X+, r16 ; msglen
eor r1, r16
; write payload
ldi r16, CPRO_CMD_NEED_ADDRESS ; 0: msg type
st X+, r16
eor r1, r16
clr r16 ; dummy src address
st X+, r16
eor r1, r16
push xh ; 2-5: UID
push xl
rcall Utils_ReadUid ; (R16, X)
pop xl
pop xh
st X+, r18
eor r1, r18
st X+, r19
eor r1, r19
st X+, r20
eor r1, r20
st X+, r21
eor r1, r21
; store XOR byte
mov r16, r1
st X+, r16
; mark buffer as enqueued with PRIO "important" (higher retry count)
ldi r20, COM_BUFFER_PRIO_IMPORTANT
rcall COM_EnqueuePacket ; (R15, R16)
brcc CPRO_EnqueueNeedAddress_error
sec
ret
CPRO_EnqueueNeedAddress_error:
clc
ret
; ---------------------------------------------------------------------------
; Enqueue a simple packet with payload only CMD and source address.
;
; IN:
; - R16: destination address
; - R18: command (e.g. CPRO_CMD_PING or CPRO_CMD_PONG)
; - R20: priority of the message
; OUT:
; - CFLAG: set if okay, clear otherwise
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
cproEnqueueMsgWithCmdAndSrcAddr:
push r16
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
pop r16
brcc cproEnqueueMsgWithCmdAndSrcAddr_error
clr r17 ; r17: XOR byte
; write header (dest address, msg length)
st X+, r16 ; destination address
eor r17, r16
ldi r16, 6 ; 6 bytes payload
st X+, r16
eor r17, r16
; write payload
mov r16, r18 ; 0: CMD
st X+, r16
eor r17, r16
lds r16, comAddress ; 1: source address
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs ; 2-5: current seconds counter
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+1
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+2
st X+, r16
eor r17, r16
lds r16, timerModuleCounterSecs+3
st X+, r16
eor r17, r16
; store XOR byte
st X+, r17
; mark buffer as enqueued with PRIO "info" (limited amount of retries)
rcall COM_EnqueuePacket ; (R15, R16)
brcc cproEnqueueMsgWithCmdAndSrcAddr_error
sec
ret
cproEnqueueMsgWithCmdAndSrcAddr_error:
clc
ret
Reference in New Issue View Git Blame Copy Permalink