117 lines
3.1 KiB
NASM
117 lines
3.1 KiB
NASM
; ***************************************************************************
|
|
; copyright : (C) 2025 by Martin Preuss
|
|
; email : martin@libchipcard.de
|
|
;
|
|
; ***************************************************************************
|
|
; * This file is part of the project "AqHome". *
|
|
; * Please see toplevel file COPYING of that project for license details. *
|
|
; ***************************************************************************
|
|
|
|
|
|
.cseg
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine UART_HW_Init @global
|
|
;
|
|
; Initializes buffers.
|
|
;
|
|
; @clobbers R16, R17, X, Y
|
|
|
|
UART_HW_Init:
|
|
ldi xh, HIGH(uartHwDataBegin)
|
|
ldi xl, LOW(uartHwDataBegin)
|
|
clr r16
|
|
ldi r17, (uartHwDataEnd-uartHwDataBegin)
|
|
rcall Utils_FillSram
|
|
|
|
rcall UART_HW_FixedBuffers_Init
|
|
|
|
ldi r16, UART_HW_MSGNUMINBUF_SIZE
|
|
ldi yl, LOW(uartHw_ringBufferMsgNumIn)
|
|
ldi yh, HIGH(uartHw_ringBufferMsgNumIn)
|
|
rcall RingBufferY_Init
|
|
|
|
ldi r16, UART_HW_MSGNUMOUTBUF_SIZE
|
|
ldi yl, LOW(uartHw_ringBufferMsgNumOut)
|
|
ldi yh, HIGH(uartHw_ringBufferMsgNumOut)
|
|
rcall RingBufferY_Init
|
|
|
|
sec
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine UART_HW_InterfaceInit @global
|
|
;
|
|
; @param Y pointer to interface data in SRAM (see @ref UART_HW_IFACE_OFFS_STATE)
|
|
; @clobbers R16, R17, X
|
|
|
|
UART_HW_InterfaceInit:
|
|
mov xl, yl
|
|
mov xh, yh
|
|
ldi r17, UART_HW_IFACE_SIZE
|
|
clr r16
|
|
rcall Utils_FillSram ; (R17, X)
|
|
m_ringbuffer_y_reset UART_HW_IFACE_READBUF_SIZE, \
|
|
UART_HW_IFACE_OFFS_RINGBUF_USED, \
|
|
UART_HW_IFACE_OFFS_RINGBUF_RDPOS, \
|
|
UART_HW_IFACE_OFFS_RINGBUF_WRPOS, \
|
|
UART_HW_IFACE_OFFS_RINGBUF_DATA
|
|
m_ringbuffer_y_reset UART_HW_IFACE_MSGIDBUF_SIZE, \
|
|
UART_HW_IFACE_OFFS_MSGIDBUF_USED, \
|
|
UART_HW_IFACE_OFFS_MSGIDBUF_RDPOS, \
|
|
UART_HW_IFACE_OFFS_MSGIDBUF_WRPOS, \
|
|
UART_HW_IFACE_OFFS_MSGIDBUF_DATA
|
|
ldi r16, 0xff
|
|
std Y+UART_HW_IFACE_OFFS_READBUFFERNUM, r16
|
|
std Y+UART_HW_IFACE_OFFS_WRITEBUFFERNUM, r16
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine UART_HW_InterfaceAddReadByte
|
|
;
|
|
; @return CFLAG on success, cleared on error
|
|
; @param r16 byte to write
|
|
; @param Y pointer to start of interface data
|
|
; @clobbers R17, R18, X
|
|
|
|
UART_HW_InterfaceAddReadByte:
|
|
push yl
|
|
push yh
|
|
adiw yh:yl, UART_HW_IFACE_OFFS_RINGBUF_MAX
|
|
rcall RingBufferY_WriteByte ; R17, R18, X
|
|
pop yh
|
|
pop yl
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine UART_HW_InterfaceGetNextReadByte
|
|
;
|
|
; @return CFLAG on success, cleared on error
|
|
; @return R16 byte read
|
|
; @param Y pointer to start of interface data
|
|
; @clobbers R17, R18, X
|
|
|
|
UART_HW_InterfaceGetNextReadByte:
|
|
push yl
|
|
push yh
|
|
adiw yh:yl, UART_HW_IFACE_OFFS_RINGBUF_MAX
|
|
rcall RingBufferY_ReadByte ; R17, R18, X
|
|
pop yh
|
|
pop yl
|
|
ret
|
|
; @end
|
|
|
|
|
|
|