482 lines
13 KiB
NASM
482 lines
13 KiB
NASM
; ***************************************************************************
|
|
; copyright : (C) 2026 by Martin Preuss
|
|
; email : martin@libchipcard.de
|
|
;
|
|
; ***************************************************************************
|
|
; * This file is part of the project "AqHome". *
|
|
; * Please see toplevel file COPYING of that project for license details. *
|
|
; ***************************************************************************
|
|
|
|
#ifndef AQH_AVR_GUI2_VLAYOUT_ASM
|
|
#define AQH_AVR_GUI2_VLAYOUT_ASM
|
|
|
|
|
|
; ***************************************************************************
|
|
; defines
|
|
|
|
.equ VLAYOUT_OFFS_BEGIN = WIDGET_SIZE
|
|
.equ VLAYOUT_OFFS_MODE = VLAYOUT_OFFS_BEGIN+0
|
|
.equ VLAYOUT_SIZE = VLAYOUT_OFFS_BEGIN+1
|
|
|
|
|
|
; values for VLAYOUT_OFFS_MODE
|
|
.equ VLAYOUT_MODE_EXPAND = 0
|
|
.equ VLAYOUT_MODE_SPREAD = 1
|
|
|
|
|
|
|
|
|
|
|
|
; ***************************************************************************
|
|
; code
|
|
|
|
.cseg
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine VLayout_new @global
|
|
;
|
|
; @return CFLAG set of okay, cleared otherwise
|
|
; @return Y address of newly created object
|
|
; @param X parent widget
|
|
; @param r16 value for OBJECT_OFFS_OPTS
|
|
; @param r17 value for WIDGET_OFFS_PACK
|
|
; @param r20 layout mode (VLAYOUT_MODE_EXPAND, VLAYOUT_MODE_SPREAD)
|
|
; @clobbers any
|
|
|
|
VLayout_new:
|
|
push r20
|
|
ldi r24, LOW(VLAYOUT_SIZE)
|
|
ldi r25, HIGH(VLAYOUT_SIZE)
|
|
bigcall Object_Alloc ; (!r16, !r17, !X)
|
|
pop r20
|
|
brcc VLayout_new_ret
|
|
rcall VLayout_Init ; (r16, r17, X)
|
|
sec
|
|
VLayout_new_ret:
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine VLayout_Init @global
|
|
;
|
|
; @param Y address of widget
|
|
; @param X parent widget (if any)
|
|
; @param r16 value for OBJECT_OFFS_OPTS
|
|
; @param r17 value for WIDGET_OFFS_PACK
|
|
; @param r20 layout mode (VLAYOUT_MODE_EXPAND, VLAYOUT_MODE_SPREAD)
|
|
; @clobbers r16, r17, X
|
|
|
|
VLayout_Init:
|
|
push r20
|
|
; call base class
|
|
bigcall Widget_Init ; (r16, r17, X)
|
|
pop r20
|
|
|
|
; set widget-specific data
|
|
std Y+VLAYOUT_OFFS_MODE, r20
|
|
|
|
; set default signal map
|
|
ldi r16, LOW(VLayout_DefaultSignalmap*2)
|
|
std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
|
|
ldi r16, HIGH(VLayout_DefaultSignalmap*2)
|
|
std Y+OBJECT_OFFS_SIGNALMAP_HI, r16
|
|
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine VLayout_OnLayout
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers any, !Y
|
|
|
|
VLayout_OnLayout:
|
|
rcall vLayoutVertically
|
|
rcall vLayoutHorizontally
|
|
; force re-drawing of this widget, clear layout bit
|
|
ldd r16, Y+OBJECT_OFFS_FLAGS
|
|
sbr r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
|
|
cbr r16, (1<<WIDGET_FLAGS_LAYOUT_BIT)
|
|
std Y+OBJECT_OFFS_FLAGS, r16
|
|
sec
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine VLayout_OnGetDefaultWidth
|
|
;
|
|
; @param Y pointer to widget
|
|
; @return r19:r18 value
|
|
; @clobbers any, !Y
|
|
|
|
VLayout_OnGetDefaultWidth:
|
|
rcall Layout_SetDefaultWidths
|
|
rcall Layout_GetMaxTmp
|
|
bigcall Widget_AddOuterStyleBorders ; (r20, r21)
|
|
sec
|
|
ret
|
|
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine VLayout_OnGetDefaultHeight
|
|
;
|
|
; @param Y pointer to widget
|
|
; @return r19:r18 value
|
|
; @clobbers any, !Y
|
|
|
|
VLayout_OnGetDefaultHeight:
|
|
rcall Layout_SetDefaultHeights
|
|
rcall Layout_SumTmpValues ; r19:r18=default width
|
|
sec
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutSetY
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers r16, r17, r18, r19, r20, r21, r22, r23, Z
|
|
|
|
vLayoutSetY:
|
|
ldd zl, Y+WIDGET_OFFS_STYLE_LO
|
|
ldd zh, Y+WIDGET_OFFS_STYLE_HI
|
|
|
|
; get spacing
|
|
adiw zh:zl, WIDGET_STYLE_OFFS_SPACING
|
|
lpm r22, Z
|
|
clr r23
|
|
sbiw zh:zl, WIDGET_STYLE_OFFS_SPACING
|
|
; get outer border
|
|
adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
|
|
lpm r20, Z
|
|
clr r21
|
|
sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
|
|
|
|
push yl
|
|
push yh
|
|
bigcall OBJ_GetFirstChild
|
|
brcc vLayoutSetY_loopEnd
|
|
vLayoutSetY_loop:
|
|
mov yl, r18
|
|
mov yh, r19
|
|
ldd r16, Y+OBJECT_OFFS_FLAGS
|
|
sbrs r16, WIDGET_FLAGS_VISIBLE_BIT
|
|
rjmp vLayoutSetY_next
|
|
; set Y
|
|
std Y+WIDGET_OFFS_Y_LO, r20
|
|
std Y+WIDGET_OFFS_Y_HI, r21
|
|
; set width
|
|
ldd r16, Y+WIDGET_OFFS_TMP_LO
|
|
ldd r17, Y+WIDGET_OFFS_TMP_HI
|
|
std Y+WIDGET_OFFS_HEIGHT_LO, r16
|
|
std Y+WIDGET_OFFS_HEIGHT_HI, r17
|
|
; advance r21:r20
|
|
add r20, r16 ; add widget size
|
|
adc r21, r17
|
|
add r20, r22 ; add spacing
|
|
adc r21, r23
|
|
|
|
; force direct children to re-layout and re-draw
|
|
ldd r16, Y+OBJECT_OFFS_FLAGS
|
|
ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT) | (1<<WIDGET_FLAGS_LAYOUT_BIT)
|
|
std Y+OBJECT_OFFS_FLAGS, r16
|
|
vLayoutSetY_next:
|
|
rcall OBJ_GetNext
|
|
brcs vLayoutSetY_loop
|
|
vLayoutSetY_loopEnd:
|
|
pop yh
|
|
pop yl
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutHorizontally
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers any, !Y
|
|
|
|
vLayoutHorizontally:
|
|
bigcall Layout_SetDefaultWidths ; (any, !Y)
|
|
; calc usable width of host widget
|
|
ldd r22, Y+WIDGET_OFFS_WIDTH_LO
|
|
ldd r23, Y+WIDGET_OFFS_WIDTH_HI
|
|
ldd zl, Y+WIDGET_OFFS_STYLE_LO
|
|
ldd zh, Y+WIDGET_OFFS_STYLE_HI
|
|
adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
|
|
lpm r18, Z+
|
|
; lpm r19, Z
|
|
clr r19
|
|
sub r22, r18
|
|
sbc r23, r19
|
|
sub r22, r18
|
|
sbc r23, r19
|
|
; r23:r22=width of host widget
|
|
push yl
|
|
push yh
|
|
mov xl, yl
|
|
mov xh, yh
|
|
bigcall OBJ_GetFirstChild
|
|
vLayoutHorizontally_loop:
|
|
brcc vLayoutHorizontally_loopEnd
|
|
mov yl, r18
|
|
mov yh, r19
|
|
|
|
ldd r12, Y+WIDGET_OFFS_TMP_LO ; default width
|
|
ldd r13, Y+WIDGET_OFFS_TMP_HI
|
|
|
|
ldd r17, Y+WIDGET_OFFS_PACK
|
|
andi r17, (1<<WIDGET_PACK_HSELF1_BIT) | (1<<WIDGET_PACK_HSELF0_BIT)
|
|
cpi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT)
|
|
brne vLayoutHorizontally_setWidth
|
|
mov r12, r22 ; TODO: need to check size, subtract borders!!!
|
|
mov r13, r23
|
|
vLayoutHorizontally_setWidth:
|
|
std Y+WIDGET_OFFS_WIDTH_LO, r12
|
|
std Y+WIDGET_OFFS_WIDTH_HI, r13
|
|
push yl
|
|
push yh
|
|
ldd r17, Y+WIDGET_OFFS_PACK
|
|
mov yl, xl ; use parent
|
|
mov yh, xh
|
|
bigcall Widget_PackSelfX ; R5:R4=new pos (r17, r18, r19, r20, r21) !! TODO: ERROR when FILLED !!
|
|
pop yh
|
|
pop yl
|
|
std Y+WIDGET_OFFS_X_LO, r4
|
|
std Y+WIDGET_OFFS_X_HI, r5
|
|
rcall OBJ_GetNext
|
|
rjmp vLayoutHorizontally_loop
|
|
vLayoutHorizontally_loopEnd:
|
|
pop yh
|
|
pop yl
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutVertically
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers any, !Y
|
|
|
|
vLayoutVertically:
|
|
ldd r16, Y+VLAYOUT_OFFS_MODE
|
|
cpi r16, VLAYOUT_MODE_SPREAD
|
|
breq vLayoutVertically_spread
|
|
rjmp vLayoutExpand
|
|
vLayoutVertically_spread:
|
|
rjmp vLayoutSpread
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutExpand
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers any, !Y
|
|
|
|
vLayoutExpand:
|
|
rcall Layout_SetDefaultHeights
|
|
rcall Layout_SumTmpValues ; r19:r18=width+borders
|
|
|
|
ldd r22, Y+WIDGET_OFFS_HEIGHT_LO
|
|
ldd r23, Y+WIDGET_OFFS_HEIGHT_HI
|
|
sub r22, r18
|
|
sbc r23, r19 ; r23:r22=(height-usedSpace)=unusedSpace
|
|
breq vLayoutExpand_setY
|
|
brcs vLayoutExpand_setY
|
|
|
|
; r23:r22=remaining space to distribute
|
|
push r22
|
|
push r23
|
|
ldi r22, (1<<WIDGET_PACK_VSELF1_BIT) | (1<<WIDGET_PACK_VSELF0_BIT) ; mask
|
|
ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; value
|
|
rcall LayoutCountChildrenWithPackMode ; r16=number of expandable child widgets
|
|
pop r23
|
|
pop r22
|
|
tst r16
|
|
breq vLayoutExpand_setY
|
|
|
|
; calc space to add to each expandable child widget and add it
|
|
mov r20, r22
|
|
mov r21, r23
|
|
mov r22, r16
|
|
clr r23
|
|
bigcall Utils_Divu16_16_16 ; r17:r16=space per expandable child widget
|
|
mov r20, r16
|
|
mov r21, r17
|
|
|
|
ldi r22, (1<<WIDGET_PACK_VSELF1_BIT) | (1<<WIDGET_PACK_VSELF0_BIT) ; mask
|
|
ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; value
|
|
bigcall LayoutIncTmpOnMatchingPack
|
|
|
|
vLayoutExpand_setY:
|
|
rcall vLayoutSetY
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutExpand
|
|
;
|
|
; @param Y pointer to widget
|
|
; @clobbers any, !Y
|
|
|
|
vLayoutSpread:
|
|
rcall vLayoutPrepareSpread ; (any, !Y)
|
|
rcall vLayoutFinalizeSpread ; (r18, r19, X)
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutPrepareSpread
|
|
;
|
|
; @param Y pointer to widget
|
|
; @return X startpos
|
|
; @return r21:r20 extra space (in pixels)
|
|
; @return r25:r24 spacing (including extra space)
|
|
; @clobbers any, !Y
|
|
|
|
vLayoutPrepareSpread:
|
|
rcall Layout_SetDefaultHeights ; (any, !Y)
|
|
rcall Layout_SumTmpValues ; r21:r20=width+borders
|
|
|
|
ldd r18, Y+WIDGET_OFFS_HEIGHT_LO
|
|
ldd r19, Y+WIDGET_OFFS_HEIGHT_HI
|
|
sub r18, r20
|
|
sbc r19, r21
|
|
brcc vLayoutPrepareSpread_calcAdd
|
|
clr r20
|
|
clr r21
|
|
rjmp vLayoutPrepareSpread_finish
|
|
vLayoutPrepareSpread_calcAdd:
|
|
mov r20, r18
|
|
mov r21, r19 ; remaining space
|
|
|
|
rcall LayoutCountVisibleChildren ; r16=number of visible child widgets (r17, r18, r19)
|
|
inc r16
|
|
mov r22, r16
|
|
push r22
|
|
ldi r22, (1<<WIDGET_PACK_VSELF1_BIT) | \
|
|
(1<<WIDGET_PACK_VSELF0_BIT) ; mask
|
|
ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; value
|
|
rcall LayoutCountChildrenWithPackMode ; r16=number of expandable children (r17, r18, r19)
|
|
pop r22
|
|
add r22, r16
|
|
clr r23
|
|
bigcall Utils_Divu16_16_16 ; r17:r16=space per element
|
|
mov r20, r16
|
|
mov r21, r17 ; r21:20=additional space per element
|
|
|
|
vLayoutPrepareSpread_finish:
|
|
; get and adjust spacing, setup start pos
|
|
ldd zl, Y+WIDGET_OFFS_STYLE_LO
|
|
ldd zh, Y+WIDGET_OFFS_STYLE_HI
|
|
adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
|
|
lpm xl, Z+ ; border
|
|
clr xh
|
|
lpm r24, Z ; spacing
|
|
clr r25
|
|
|
|
add r24, r20 ; add extra space to spacing
|
|
adc r25, r21
|
|
|
|
add xl, r20 ; add extra space to border
|
|
adc xh, r21
|
|
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; @routine vLayoutFinalizeSpread
|
|
;
|
|
; @param Y pointer to widget
|
|
; @param X startpos
|
|
; @param r21:r20 extra space (in pixels)
|
|
; @param r25:r24 spacing (including extra space)
|
|
; @clobbers r18, r19, X
|
|
|
|
vLayoutFinalizeSpread:
|
|
push yl
|
|
push yh
|
|
bigcall OBJ_GetFirstChild
|
|
brcc vLayoutFinalizeSpread_done
|
|
vLayoutFinalizeSpread_loop:
|
|
mov yl, r18
|
|
mov yh, r19
|
|
ldd r17, Y+OBJECT_OFFS_FLAGS
|
|
sbrs r17, WIDGET_FLAGS_VISIBLE_BIT ; skip invisible widgets
|
|
rjmp vLayoutFinalizeSpread_next
|
|
; store pos
|
|
std Y+WIDGET_OFFS_Y_LO, xl
|
|
std Y+WIDGET_OFFS_Y_HI, xh
|
|
; determine final height of child widget
|
|
ldd r18, Y+WIDGET_OFFS_TMP_LO
|
|
ldd r19, Y+WIDGET_OFFS_TMP_HI
|
|
ldd r16, Y+WIDGET_OFFS_PACK
|
|
andi r16, (1<<WIDGET_PACK_VSELF1_BIT) | (1<<WIDGET_PACK_VSELF0_BIT)
|
|
cpi r16, (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT)
|
|
brne vLayoutFinalizeSpread_setHeight
|
|
add r18, r20 ; add extra space
|
|
adc r19, r21
|
|
vLayoutFinalizeSpread_setHeight:
|
|
std Y+WIDGET_OFFS_HEIGHT_LO, r18
|
|
std Y+WIDGET_OFFS_HEIGHT_HI, r19
|
|
; advance pos
|
|
add xl, r18 ; add height to current pos
|
|
adc xh, r19
|
|
add xl, r24 ; add spacing to current pos
|
|
adc xh, r25
|
|
vLayoutFinalizeSpread_next:
|
|
rcall OBJ_GetNext ; r19:r18=object (none)
|
|
brcs vLayoutFinalizeSpread_loop
|
|
vLayoutFinalizeSpread_done:
|
|
pop yh
|
|
pop yl
|
|
ret
|
|
; @end
|
|
|
|
|
|
|
|
|
|
|
|
|
|
; ***************************************************************************
|
|
; data in FLASH
|
|
|
|
VLayout_DefaultSignalmap:
|
|
; header
|
|
.dw Widget_DefaultSignalmap*2 ; next table to use
|
|
; entries
|
|
.db 0, WIDGET_SIGNAL_LAYOUT, LOW(VLayout_OnLayout), HIGH(VLayout_OnLayout)
|
|
.db WIDGET_VALUE_DEFAULT_WIDTH, WIDGET_SIGNAL_GETVALUE, LOW(VLayout_OnGetDefaultWidth), HIGH(VLayout_OnGetDefaultWidth)
|
|
.db WIDGET_VALUE_DEFAULT_HEIGHT, WIDGET_SIGNAL_GETVALUE, LOW(VLayout_OnGetDefaultHeight), HIGH(VLayout_OnGetDefaultHeight)
|
|
|
|
.db 0, 0, 0, 0 ; end of table
|
|
|
|
|
|
|
|
#endif
|
|
|