martin/aqhomecontrol
Public Access
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity
Files
6e25647c0a8fc3aae0d596d806c9582b760daa9c
aqhomecontrol/avr/devices/t03/main.asm
Martin Preuss 6e25647c0a avr: echoing messages via tty now basically works.
2025-02-13 23:52:55 +01:00

510 lines
13 KiB
NASM
Raw Blame History

; ***************************************************************************
; copyright : (C) 2024 by Martin Preuss
; email : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome". *
; * Please see toplevel file COPYING of that project for license details. *
; ***************************************************************************
; ***************************************************************************
; Source file for temperature sensor node on AtTiny 84
;
; This is for the full system (i.e. not the boot loader).
;
; All definitions and changes should go into this file.
;
;
; ***************************************************************************
;.equ clock=1000000 ; Define the clock frequency
.equ clock=8000000 ; Define the clock frequency
;.equ SEND_DEVICE_EVERY = 3000
.equ SEND_DEVICE_EVERY = 350 ; every 30s
.equ SEND_STATS_EVERY = 600 ; every minute
.nolist
.include "include/tn841def.inc" ; Define device ATtiny841
.list
.include "./defs.asm"
.include "defs_all.asm"
; ***************************************************************************
; defines
; ---------------------------------------------------------------------------
; generic
.include "common/utils_wait.asm"
; ---------------------------------------------------------------------------
; firmware settings including list of modules used
.equ FIRMWARE_VERSION_MAJOR = 0
.equ FIRMWARE_VERSION_MINOR = 0
.equ FIRMWARE_VERSION_PATCHLEVEL = 1
;#define MODULES_TIMER
;#define MODULES_COM
;#define MODULES_COM_WITH_ADDR_PROTO
;#define MODULES_LED
#define MODULES_LED_SIMPLE
;#define MODULES_TWI_MASTER
;#define MODULES_LCD
;#define LCD_MINIMAL_FONT
;#define MODULES_SI7021
;#define MODULES_STATS
;#define MODULES_CNY70
;#define MODULES_REED
;#define MODULES_OWI_MASTER
;#define MODULES_DS18B20
;#define MODULES_MOTION
.equ NET_BUFFERS_NUM = 6
.equ NET_BUFFERS_SIZE = 32
.equ UART_HW_MSGNUMINBUF_SIZE = 6
.equ UART_HW_MSGNUMOUTBUF_SIZE = 6
; ***************************************************************************
; code segment
.cseg
.org 000000
; ---------------------------------------------------------------------------
; Reset and interrupt vectors
rjmp BOOTLOADER_ADDR ; 1: RESET Reset vector use this for flashed system
reti ; 2: INT0 External Interrupt Request 0
reti ; 3: PCINT0 Pin Change Interrupt 0
reti ; 4: PCINT1 Pin Change Interrupt 1
reti ; 5: WDT Watchdog Time-out
reti ; 6: TIM1_CAPT Timer/Counter1 Capture Event
reti ; 7: TIM1_COMPA (OC1A) Timer/Counter1 Compare Match A
reti ; 8: TIM1_COMPB (OC1B) Timer/Counter1 Compare Match B
reti ; 9: TIM1_OVF (OVF1) Timer/Counter1 Overflow
rjmp baseTimerIrqOC0A ; 10: TIM0_COMPA (OC0A) Timer/Counter0 Compare Match A
reti ; 11: TIM0_COMPB (OC0B) Timer/Counter0 Compare Match B
reti ; 12: TIM0_OVF (OVF0) Timer/Counter0 Overflow
reti ; 13: ANA_COMP0 Analog Comparator 0
reti ; 14: ADC_READY ADC Conversion Complete
reti ; 15: EE_RDY (ERDY) EEPROM Ready
reti ; 16: ANA_COMP1 Analog Comparator 1
reti ; 17: TIM2_CAPT Timer/Counter2 Capture Event
reti ; 18: TIM2_COMPA (OC2A) Timer/Counter2 Compare Match A
reti ; 19: TIM2_COMPB (OC2B) Timer/Counter2 Compare Match B
reti ; 20: TIM2_OVF (OVF2) Timer/Counter2 Overflow
reti ; 21: SPI SPI Serial Transfer Complete
reti ; 22: USART0_RXS USART0 Rx Start
reti ; 23: USART0_RXC USART0 Rx Complete
reti ; 24: USART0_DRE USART0 Data Register Empty
reti ; 25: USART0_TXC USART0 Tx Complete
reti ; 26: USART1_RXS USART1 Rx Start
rjmp TtyOnUart1_RxCharIsr ; 27: USART1_RXC USART1 Rx Complete
rjmp TtyOnUart1_TxUdreIsr ; 28: USART1_DRE USART1 Data Register Empty
rjmp TtyOnUart1_TxCharIsr ; 29: USART1_TXC USART1 Tx Complete
reti ; 30: TWI Two-Wire-Interface
reti ; 31: RESERVED reserved
devInfoBlock: ; 12 bytes
devInfoManufacturer: .db 'A', 'Q', 'U', 'A'
devInfoId: .db DEVICEINFO_ID, 0
devInfoVersion: .db DEVICEINFO_VERSION, DEVICEINFO_REVISION ; version, revision
firmwareVersion: .db FIRMWARE_VARIANT_TEMP_WINDOW, FIRMWARE_VERSION_MAJOR
.db FIRMWARE_VERSION_MINOR, FIRMWARE_VERSION_PATCHLEVEL
firmwareStart:
cli
; setup stack
.ifdef SPH ; if SPH is defined
ldi r16, High(RAMEND)
out SPH, r16 ; init MSB stack pointer
.endif
ldi r16, Low(RAMEND)
out SPL, r16 ; init LSB stack pointer
rcall systemSetSpeed
rcall initHardware
; rcall watchdogOff ; turn off watchdog timer (sometimes it stays on after reboot)
rcall Utils_Init
rcall Utils_SetupUid
rcall initModules
sbi LED_SIMPLE_DDR, LED_SIMPLE_PINNUM ; out
sbi LED_SIMPLE_PORT, LED_SIMPLE_PINNUM ; off
sei
main_loop:
; only modify SE, SM1 and SM0
cli
in r16, MCUCR
ldi r17, (1<<SE) | (1<<SM1) | (1<<SM0)
neg r17
and r16, r17
ori r16, (1<<SE) ; sleep mode "idle", enable
out MCUCR, r16
sei ; make sure interrupts really are enabled
sleep ; sleep, wait for interrupt
rcall BaseTimer_Run
rcall TtyOnUart1_Run
; check incoming msg
rcall checkRecvdMsg
rjmp main_loop
systemSetSpeed:
.if clock == 1000000
ldi r17, 0xd8
ldi r16, (1<<CLKPS1) | (1<<CLKPS0) ; SUT=0, CLKPS=0011b
sts CCP, r17
sts CLKPR, r16
.endif
.if clock == 8000000
ldi r17, 0xd8
clr r16 ; SUT=0, CLKPS=0
sts CCP, r17
sts CLKPR, r16
.endif
ret
; ---------------------------------------------------------------------------
; Called every 100ms. Add your routine calls here. No arguments, no results.
onSystemTimerTick:
#ifdef MODULES_LED_SIMPLE
rcall LedSimple_Every100ms
#endif
rcall maybeSendDeviceMsg
rcall maybeSendTStatsMsg
rcall maybeSendRStatsMsg
rcall TtyOnUart1_Periodically
ret
initHardware:
; set all ports as inputs and enable internal pull-up resistors
ldi r16, 0xff
clr r17
.ifdef PORTA
out DDRA, r17 ; all input
sts PUEA, r16 ; enable pull-up on all
.endif
.ifdef PORTB
out DDRB, r17 ; all input
sts PUEB, r16 ; enable pull-up on all
.endif
.ifdef PORTC
out DDRC, r17 ; all input
sts PUEC, r16 ; enable pull-up on all
.endif
ret
; @end
initModules:
rcall BaseTimer_Init
rcall LedSimple_Init
rcall NET_Init
rcall TtyOnUart1_Init
ldi r16, LOW(SEND_DEVICE_EVERY)
sts deviceCounter, r16
ldi r16, HIGH(SEND_DEVICE_EVERY)
sts deviceCounter+1, r16
ldi r16, LOW(SEND_STATS_EVERY)
sts sendTStatsCounter, r16
ldi r16, HIGH(SEND_STATS_EVERY)
sts sendTStatsCounter+1, r16
ldi r16, LOW(SEND_STATS_EVERY)
sts sendRStatsCounter, r16
ldi r16, HIGH(SEND_STATS_EVERY)
sts sendRStatsCounter+1, r16
ret
; @end
; ***************************************************************************
; includes
.include "common/utils.asm"
.include "common/utils_wait_fixed.asm"
.include "common/utils_copy_from_flash.asm"
.include "common/utils_copy_sdram.asm"
.include "common/m_ringbuffer_y.asm"
.include "common/ringbuffer_y.asm"
.include "common/m_fixedbuffers.asm"
.include "modules/basetimer/main.asm"
.include "modules/led_simple/main.asm"
.include "modules/network/defs.asm"
.include "modules/network/buffer.asm"
.include "modules/network/data.asm"
.include "modules/network/main.asm"
.include "modules/network/iface.asm"
.include "modules/network/msg/defs.asm"
.include "modules/network/msg/common.asm"
.include "modules/network/msg/device-w.asm"
.include "modules/network/msg/sendstats-w.asm"
.include "modules/network/msg/recvstats-w.asm"
.include "modules/uart_hw/defs.asm"
.include "modules/uart_hw/lowlevel.asm"
.include "modules/uart_hw/m_lowlevel_uart.asm"
.include "modules/uart_hw/lowlevel_uart1.asm"
.include "modules/uart_hw/ttyonuart1.asm"
maybeSendDeviceMsg:
ldi yl, LOW(ttyOnUart1_iface)
ldi yh, HIGH(ttyOnUart1_iface)
lds r24, deviceCounter
lds r25, deviceCounter+1
sbiw r25:r24, 1
brne maybeSendDeviceMsg_storeCounter
; send device msg
rcall NET_Buffer_Alloc ; (R16, R17, X)
brcc maybeSendDeviceMsg_end
push r16
adiw xh:xl, 1
rcall NETMSG_Device_Write ; (R16, R17, R18, R19, R20, R21, Z)
sbiw xh:xl, 1
pop r16
push r16
rcall NET_Interface_AddOutgoingMsgNum ; (R17, R18, X)
pop r16
brcs maybeSendDeviceMsg_resetCounter
rcall NET_Buffer_ReleaseByNum ; (R16, X)
rjmp maybeSendDeviceMsg_end
; reset counter
maybeSendDeviceMsg_resetCounter:
ldi r24, LOW(SEND_DEVICE_EVERY)
ldi r25, HIGH(SEND_DEVICE_EVERY)
maybeSendDeviceMsg_storeCounter:
sts deviceCounter, r24
sts deviceCounter+1, r25
maybeSendDeviceMsg_end:
ret
maybeSendTStatsMsg:
ldi yl, LOW(ttyOnUart1_iface)
ldi yh, HIGH(ttyOnUart1_iface)
lds r24, sendTStatsCounter
lds r25, sendTStatsCounter+1
sbiw r25:r24, 1
brne maybeSendTStatsMsg_storeCounter
; send device msg
rcall NET_Buffer_Alloc ; (R16, R17, X)
; brcc maybeSendTStatsMsg_resetCounter
brcc maybeSendTStatsMsg_end
push r16
adiw xh:xl, 1
rcall NETMSG_SendStats_Write ; (R16, R17, R18, R19, R20, R21, Z)
sbiw xh:xl, 1
pop r16
push r16
rcall NET_Interface_AddOutgoingMsgNum ; (R17, R18, X)
pop r16
brcs maybeSendTStatsMsg_resetCounter
rcall NET_Buffer_ReleaseByNum ; (R16, X)
rjmp maybeSendTStatsMsg_end
; reset counter
maybeSendTStatsMsg_resetCounter:
ldi r24, LOW(SEND_STATS_EVERY)
ldi r25, HIGH(SEND_STATS_EVERY)
maybeSendTStatsMsg_storeCounter:
sts sendTStatsCounter, r24
sts sendTStatsCounter+1, r25
maybeSendTStatsMsg_end:
ret
maybeSendRStatsMsg:
ldi yl, LOW(ttyOnUart1_iface)
ldi yh, HIGH(ttyOnUart1_iface)
lds r24, sendRStatsCounter
lds r25, sendRStatsCounter+1
sbiw r25:r24, 1
brne maybeSendRStatsMsg_storeCounter
; send device msg
rcall NET_Buffer_Alloc ; (R16, R17, X)
; brcc maybeSendTStatsMsg_resetCounter
brcc maybeSendRStatsMsg_end
push r16
adiw xh:xl, 1
rcall NETMSG_RecvStats_Write ; (R16, R17, R18, R19, R20, R21, Z)
sbiw xh:xl, 1
pop r16
push r16
rcall NET_Interface_AddOutgoingMsgNum ; (R17, R18, X)
pop r16
brcs maybeSendRStatsMsg_resetCounter
rcall NET_Buffer_ReleaseByNum ; (R16, X)
rjmp maybeSendRStatsMsg_end
; reset counter
maybeSendRStatsMsg_resetCounter:
ldi r24, LOW(SEND_STATS_EVERY)
ldi r25, HIGH(SEND_STATS_EVERY)
maybeSendRStatsMsg_storeCounter:
sts sendRStatsCounter, r24
sts sendRStatsCounter+1, r25
maybeSendRStatsMsg_end:
ret
checkRecvdMsg:
ldi yl, LOW(ttyOnUart1_iface)
ldi yh, HIGH(ttyOnUart1_iface)
rcall NET_PeekNextIncomingMsgNum ; check read queue
brcc checkRecvdMsg_end ; no msg, jmp
rcall NET_Buffer_Locate ; (R17)
adiw xh:xl, 1
push r16
rcall NETMSG_CheckMessageInBuffer ; (R16, R17, R18, R19, R20, X)
pop r16
brcs checkRecvdMsg_sendMsg
rcall NET_GetNextIncomingMsgNum ; take off the queue
rcall NET_Buffer_ReleaseByNum ; delete
ldi r16, NET_IFACE_OFFS_ERR_CONTENT_LOW
rcall NET_Interface_IncCounter16 ; (R24, R25)
rjmp checkRecvdMsg_end
checkRecvdMsg_sendMsg:
rcall NET_Interface_AddOutgoingMsgNum ; try to add msg to interface
brcc checkRecvdMsg_end ; could not add, jmp
rcall NET_GetNextIncomingMsgNum ; take off the queue
checkRecvdMsg_end:
ret
DEBUG1:
ldi r19, 10
ldi r20, 2
ldi r21, 8
rcall blinkLed
rjmp DEBUG1
DEBUG2:
ldi r19, 50
ldi r20, 1
ldi r21, 1
rcall blinkLed
rjmp DEBUG2
; @param r19 loop count
; @param r20 on time
; @param r21 off time
; @clobbers (R16, R18, R22, R24, R25)
blinkLed:
cbi LED_SIMPLE_PORT, LED_SIMPLE_PINNUM ; on
mov r22, r20
rcall waitForMultiple100ms ; (R252
sbi LED_SIMPLE_PORT, LED_SIMPLE_PINNUM ; off
mov r22, r21
rcall waitForMultiple100ms ; (R22)
dec r19
brne blinkLed
ret
; @param r22 number of 100ms periods to wait
waitForMultiple100ms:
waitForMultiple100ms_loop:
push r22
rcall waitFor100ms
pop r22
dec r22
brne waitForMultiple100ms_loop
ret
waitFor100ms:
ldi r22, 10
waitFor100ms_loop:
push r22
rcall waitFor10ms
pop r22
dec r22
brne waitFor100ms_loop
ret
waitFor10ms:
ldi r22, 100
waitFor10ms_loop:
push r22
rcall Utils_WaitFor100MicroSecs
pop r22
dec r22
brne waitFor10ms_loop
ret
; ***************************************************************************
; data in SRAM
.dseg
programRamBegin:
flashUid: .byte 4
deviceCounter: .byte 2
sendTStatsCounter: .byte 2
sendRStatsCounter: .byte 2
programRamEnd:
Reference in New Issue View Git Blame Copy Permalink