090122a192
- prepared for use of CRC8 - organized code in more files - recv stats message now contains crc errors and io errors
118 lines
3.0 KiB
NASM
118 lines
3.0 KiB
NASM
|
|
; ***************************************************************************
|
|
; code
|
|
|
|
.cseg
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; Enqueue a COM Send stats packet.
|
|
;
|
|
; IN:
|
|
; - R16: destination address
|
|
; OUT:
|
|
; - CFLAG: set if okay, clear otherwise
|
|
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
|
|
|
|
CPRO_EnqueueComSendStats:
|
|
push r15
|
|
in r15, SREG
|
|
cli
|
|
push r16
|
|
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21) -> Y=buffer, X=msg
|
|
pop r16
|
|
brcc CPRO_EnqueueComSendStats_error
|
|
|
|
ldi r17, CPRO_PAYLOAD_FLAGS_UID | (6<<CPRO_PAYLOAD_FLAGS_SHIFT_NUM) ; seconds + 6 bytes payload
|
|
ldi r18, CPRO_CMD_COMSENDSTATS
|
|
push xh
|
|
push xl
|
|
rcall cproBeginMsgWithVariablePayload ; (R3, R4, R16, R17, R18, R19, R20, R21, X)
|
|
lds r16, comStatsPacketsOut ; 6: packets out
|
|
st X+, r16
|
|
lds r16, comStatsPacketsOut+1
|
|
st X+, r16
|
|
lds r16, comStatsCollisions ; 8: collisions
|
|
st X+, r16
|
|
lds r16, comStatsCollisions+1
|
|
st X+, r16
|
|
lds r16, comStatsAborted ; 10: aborted
|
|
st X+, r16
|
|
lds r16, comStatsAborted+1
|
|
st X+, r16
|
|
pop xl
|
|
pop xh
|
|
rcall comCalcAndAddChecksumByte
|
|
|
|
; mark buffer as enqueued with PRIO "important" (higher retry count)
|
|
ldi r20, COM_BUFFER_PRIO_IMPORTANT
|
|
rcall COM_EnqueuePacket ; (R15, R16)
|
|
brcc CPRO_EnqueueComSendStats_error
|
|
pop r15
|
|
out SREG, r15
|
|
sec
|
|
ret
|
|
CPRO_EnqueueComSendStats_error:
|
|
pop r15
|
|
out SREG, r15
|
|
clc
|
|
ret
|
|
|
|
|
|
|
|
; ---------------------------------------------------------------------------
|
|
; Enqueue a COM reception stats packet.
|
|
;
|
|
; IN:
|
|
; - R16: destination address
|
|
; OUT:
|
|
; - CFLAG: set if okay, clear otherwise
|
|
; MODIFIED REGS: R16, R17, R20, X (R15, Y)
|
|
|
|
CPRO_EnqueueComRecvStats:
|
|
push r15
|
|
in r15, SREG
|
|
cli
|
|
push r16
|
|
rcall COM_AllocBufferAndGetXY ; (r16, r17, r21)
|
|
pop r16
|
|
brcc CPRO_EnqueueComRecvStats_error
|
|
|
|
ldi r17, CPRO_PAYLOAD_FLAGS_UID | (6<<CPRO_PAYLOAD_FLAGS_SHIFT_NUM) ; seconds + 6 bytes payload
|
|
ldi r18, CPRO_CMD_COMRECVSTATS
|
|
push xh
|
|
push xl
|
|
rcall cproBeginMsgWithVariablePayload ; (R3, R4, R16, R17, R18, R19, R20, R21, X)
|
|
lds r16, comStatsPacketsIn ; 6: packets in
|
|
st X+, r16
|
|
lds r16, comStatsPacketsIn+1
|
|
st X+, r16
|
|
lds r16, comStatsRecvCrcErrs ; 8: CRC errors
|
|
st X+, r16
|
|
lds r16, comStatsRecvCrcErrs+1
|
|
st X+, r16
|
|
lds r16, comStatsRecvErrs ; 10: IO errors
|
|
st X+, r16
|
|
lds r16, comStatsRecvErrs+1
|
|
st X+, r16
|
|
pop xl
|
|
pop xh
|
|
rcall comCalcAndAddChecksumByte
|
|
|
|
; mark buffer as enqueued with PRIO "important" (higher retry count)
|
|
ldi r20, COM_BUFFER_PRIO_IMPORTANT
|
|
rcall COM_EnqueuePacket ; (R15, R16)
|
|
brcc CPRO_EnqueueComRecvStats_error
|
|
pop r15
|
|
out SREG, r15
|
|
sec
|
|
ret
|
|
CPRO_EnqueueComRecvStats_error:
|
|
pop r15
|
|
out SREG, r15
|
|
clc
|
|
ret
|
|
|
|
|
|
|