; ***************************************************************************
; copyright   : (C) 2026 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************

#ifndef AQH_AVR_GUI2_AQHOME_D_LIGHT_CONNS_ASM
#define AQH_AVR_GUI2_AQHOME_D_LIGHT_CONNS_ASM


; ***************************************************************************
; defines


; widget
.equ DLGLIGHTCONNS_OFFS_BEGIN            = CDIALOG_SIZE
.equ DLGLIGHTCONNS_OFFS_SETTINGS_LO      = DLGLIGHTCONNS_OFFS_BEGIN+0
.equ DLGLIGHTCONNS_OFFS_SETTINGS_HI      = DLGLIGHTCONNS_OFFS_BEGIN+1
.equ DLGLIGHTCONNS_OFFS_CURRDLG_LO       = DLGLIGHTCONNS_OFFS_BEGIN+2
.equ DLGLIGHTCONNS_OFFS_CURRDLG_HI       = DLGLIGHTCONNS_OFFS_BEGIN+3
.equ DLGLIGHTCONNS_SIZE                  = DLGLIGHTCONNS_OFFS_BEGIN+4


; selectors
.equ DLGLIGHTCONNS_SEL_BTN_MOTION1       = DIALOG_SEL_NEXTFREE+0
.equ DLGLIGHTCONNS_SEL_ADDR_MOTION1      = DIALOG_SEL_NEXTFREE+1
.equ DLGLIGHTCONNS_SEL_VALUE_MOTION1     = DIALOG_SEL_NEXTFREE+2
.equ DLGLIGHTCONNS_SEL_DLG_MOTION1       = DIALOG_SEL_NEXTFREE+3
.equ DLGLIGHTCONNS_SEL_BTN_MOTION2       = DIALOG_SEL_NEXTFREE+4
.equ DLGLIGHTCONNS_SEL_ADDR_MOTION2      = DIALOG_SEL_NEXTFREE+5
.equ DLGLIGHTCONNS_SEL_VALUE_MOTION2     = DIALOG_SEL_NEXTFREE+6
.equ DLGLIGHTCONNS_SEL_DLG_MOTION2       = DIALOG_SEL_NEXTFREE+7
.equ DLGLIGHTCONNS_SEL_BTN_LIGHT         = DIALOG_SEL_NEXTFREE+8
.equ DLGLIGHTCONNS_SEL_ADDR_LIGHT        = DIALOG_SEL_NEXTFREE+9
.equ DLGLIGHTCONNS_SEL_VALUE_LIGHT       = DIALOG_SEL_NEXTFREE+10
.equ DLGLIGHTCONNS_SEL_DLG_LIGHT         = DIALOG_SEL_NEXTFREE+11
.equ DLGLIGHTCONNS_SEL_BTN_NEXTFREE      = DIALOG_SEL_NEXTFREE+12




; ***************************************************************************
; code

.cseg

; ---------------------------------------------------------------------------
; @routine DlgLightConns_new @global
;
; @param  Y       pointer to GUIAPP
; @return CFLAG   set of okay, cleared otherwise
; @return Y       address of newly created object
; @param r21:r20  pointer to settings

DlgLightConns_new:
  bigcall GuiApp_GetRootWindow        ; r19:r18=root window (none)
  brcc DlgLightConns_new_ret
  mov xl, r18                         ; use root window as parent for main window
  mov xh, r19
  ldi r24, LOW(DLGLIGHTCONNS_SIZE)
  ldi r25, HIGH(DLGLIGHTCONNS_SIZE)
  push r20
    push r21
      bigcall Object_Alloc            ; Y=space (!r16, !r17, !X)
    pop r21
  pop r20
  brcc DlgLightConns_new_ret
  rcall DlgLightConns_Init
DlgLightConns_new_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_Init @global
;
; @param  Y       pointer to dialog
; @param  X       pointer to root window
; @return CFLAG set of okay, cleared otherwise
; @param r21:r20  pointer to settings
; @clobbers any, !Y

DlgLightConns_Init:
  push r20
    push r21
      ldi r16, 0                                                                                           ; OPTS
      ldi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; PACK
      ldi r20, LOW(RESSOURCE_TXT_LEDCONNECTIONS)
      ldi r21, HIGH(RESSOURCE_TXT_LEDCONNECTIONS)
      ldi r22, LOW(DlgLightConns_Config*2)
      ldi r23, HIGH(DlgLightConns_Config*2)
      bigcall CDialog_Init               ; Y=main window
    pop r21
  pop r20
  brcc DlgLightConns_Init_ret

  ; store data
  std Y+DLGLIGHTCONNS_OFFS_SETTINGS_LO, r20
  std Y+DLGLIGHTCONNS_OFFS_SETTINGS_HI, r21

  ; set default signal map
  ldi r16, LOW(DlgLightConns_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
  ldi r16, HIGH(DlgLightConns_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16

  bigcall Dialog_AddDefaultButtons   ; (any, !Y)

  rcall DlgLightConns_toGui

DlgLightConns_Init_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_toGui @global
;
; @param  Y       pointer to dialog

DlgLightConns_toGui:
  ldd zl, Y+DLGLIGHTCONNS_OFFS_SETTINGS_LO
  ldd zh, Y+DLGLIGHTCONNS_OFFS_SETTINGS_HI
  
  ; motion source 1
  ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE1_NODEADDR
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_ADDR_MOTION1
  rcall dlgLightConnsSetValue

  ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE1_VALUEID
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_VALUE_MOTION1
  rcall dlgLightConnsSetValue

  ; motion source 2
  ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE2_NODEADDR
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_ADDR_MOTION2
  rcall dlgLightConnsSetValue

  ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE2_VALUEID
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_VALUE_MOTION2
  rcall dlgLightConnsSetValue

  ; light source
  ldd xl, Z+LIGHTSETTINGS_OFFS_BSOURCE_NODEADDR
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_ADDR_LIGHT
  rcall dlgLightConnsSetValue

  ldd xl, Z+LIGHTSETTINGS_OFFS_BSOURCE_VALUEID
  clr xh
  ldi r16, DLGLIGHTCONNS_SEL_VALUE_LIGHT
  rcall dlgLightConnsSetValue
  
  ret
; @end



; ---------------------------------------------------------------------------
; @routine dlgLightConnsSetValue
; @param Y   pointer to dialog
; @param r16 selector of widget to modify
; @param X   value to set

dlgLightConnsSetValue:
  bigcall CDialog_GetChildBySelector   ; r19:r18=result (R16-R19)
  brcc dlgLightConnsSetValue_ret
  push yl
    push yh
      mov yl, r18
      mov yh, r19
      push zl
        push zh
          bigcall Widget_SetCurrentValue
        pop zh
      pop zl
    pop yh
  pop yl
dlgLightConnsSetValue_ret:
  ret
; @end







; ***************************************************************************
; signal handlers


; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnCmdMotion1 @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnCmdMotion1:
  push yl
    push yh
      ldd zl, Y+DLGLIGHTCONNS_OFFS_SETTINGS_LO
      ldd zh, Y+DLGLIGHTCONNS_OFFS_SETTINGS_HI
      bigcall Widget_GetApp                     ; R19:R18=gui
      mov yl, r18
      mov yh, r19
      ldi r20, LOW(RESSOURCE_TXT_LEDMOTIONSRC1)
      ldi r21, HIGH(RESSOURCE_TXT_LEDMOTIONSRC1)
      push zl
        push zh
          bigcall DlgNodeValueId_new
        pop zh
      pop zl

      ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE1_NODEADDR
      clr xh
      push zl
        push zh
          bigcall DlgNodeValueId_SetNodeAddr
        pop zh
      pop zl
      ldd xl, Z+LIGHTSETTINGS_OFFS_SOURCE1_VALUEID
      clr xh
      bigcall DlgNodeValueId_SetValueId

      mov xl, yl
      mov xh, yh
    pop yh
  pop yl
  std Y+DLGLIGHTCONNS_OFFS_CURRDLG_LO, xl
  std Y+DLGLIGHTCONNS_OFFS_CURRDLG_HI, xh
  
  ldi r16, DLGLIGHTCONNS_SEL_DLG_MOTION1
  adiw xh:xl, OBJECT_OFFS_SELECTOR
  st X, r16
  sbiw xh:xl, OBJECT_OFFS_SELECTOR
  adiw xh:xl, OBJECT_OFFS_TARGET_LO
  st X+, yl
  st X, yh
  sbiw xh:xl, (OBJECT_OFFS_TARGET_LO+1)
  
  push yl
    push yh
      bigcall Widget_GetApp                     ; R19:R18=gui (none)
      mov yl, r18
      mov yh, r19
      bigcall GuiApp_EnterWindow
    pop yh
  pop yl

  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnDlgEndMotion1 @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnDlgEndMotion1:
  cpi xl, DIALOG_RESULT_OK
  brne DlgLightConns_OnDlgEndMotion1_leave

  ; get values
  ldd zl, Y+DLGLIGHTCONNS_OFFS_SETTINGS_LO
  ldd zh, Y+DLGLIGHTCONNS_OFFS_SETTINGS_HI
  push yl
    push yh
      ldd r16, Y+DLGLIGHTCONNS_OFFS_CURRDLG_LO
      ldd yh, Y+DLGLIGHTCONNS_OFFS_CURRDLG_HI
      mov yl, r16
      push zl
        push zh
          bigcall DlgNodeValueId_GetNodeAddr
        pop zh
      pop zl
      std Z+LIGHTSETTINGS_OFFS_SOURCE1_NODEADDR, r18
      push zl
        push zh
          bigcall DlgNodeValueId_GetValueId
        pop zh
      pop zl
      std Z+LIGHTSETTINGS_OFFS_SOURCE1_VALUEID, r18
    pop yh
  pop yl

  rcall DlgLightConns_toGui

DlgLightConns_OnDlgEndMotion1_leave:
  ; leave sub-dialog
  push yl
    push yh
      bigcall Widget_GetApp                     ; R19:R18=gui
      mov yl, r18
      mov yh, r19
      bigcall GuiApp_LeaveWindow
    pop yh
  pop yl

  ; mark sub-dialog for destruction
  ldd xl, Y+DLGLIGHTCONNS_OFFS_CURRDLG_LO
  ldd xh, Y+DLGLIGHTCONNS_OFFS_CURRDLG_HI
  clr r16
  std Y+DLGLIGHTCONNS_OFFS_CURRDLG_LO, r16
  std Y+DLGLIGHTCONNS_OFFS_CURRDLG_HI, r16
  adiw xh:xl, OBJECT_OFFS_FLAGS
  ld r16, X
  sbr r16, (1<<OBJECT_FLAGS_DESTROY_BIT)
  st X, r16

  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnCmdMotion2 @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnCmdMotion2:
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnDlgEndMotion2 @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnDlgEndMotion2:
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnCmdLight @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnCmdLight:
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine DlgLightConns_OnDlgEndLight @global
;
; @param Y pointer to dialog
; @clobbers any, !Y

DlgLightConns_OnDlgEndLight:
  sec
  ret
; @end






; ***************************************************************************
; data in FLASH


DlgLightConns_Config:
  .db CWIDGETCFG_MAINWIDGET_TYPE_MLAYOUT, 0                 ; TYPE, FLAGS
  .dw 0                                                     ; STYLE
  .db 3, 0                                                  ; PARAM1, PARAM2
  

  ; header widget1
  .db CWIDGETCFG_WIDGET_TYPE_LABEL, 0                       ; TYPE, FLAGS
  .db 0, 0                                                  ; SELECTOR, RESERVED
  .db 0, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
         (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)    ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .dw RESSOURCE_TXT_TYPE                                    ; PARAM1, PARAM2
  .dw 0                                                     ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; header widget2
  .db CWIDGETCFG_WIDGET_TYPE_LABEL, 0                       ; TYPE, FLAGS
  .db 0, 0                                                  ; SELECTOR, RESERVED
  .db 0, (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
         (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)    ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .dw RESSOURCE_TXT_NODEADDR_S                              ; PARAM1, PARAM2
  .dw 0                                                     ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; header widget3
  .db CWIDGETCFG_WIDGET_TYPE_LABEL, 0                       ; TYPE, FLAGS
  .db 0, 0                                                  ; SELECTOR, RESERVED
  .db 0, (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
         (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
         (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)    ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .dw RESSOURCE_TXT_VALUEID_S                               ; PARAM1, PARAM2
  .dw 0                                                     ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL


  ; line1 widget1
  .db CWIDGETCFG_WIDGET_TYPE_TEXTBUTTON, 0                  ; TYPE, FLAGS
  .db DLGLIGHTCONNS_SEL_BTN_MOTION1, 0                      ; SELECTOR, RESERVED
  .db (1<<WIDGET_OPTS_BORDER_BIT), \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw (DefaultStyle_SpacyButton*2)                          ; STYLE
  .dw RESSOURCE_TXT_MOTIONSENSOR1_S                         ; PARAM1, PARAM2 (text ressource)
  .db 0, BUTTON_MODE_NORMAL                                 ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line1 widget2
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_ADDR_MOTION1, 0                     ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line1 widget3
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_VALUE_MOTION1, 0                    ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL


  ; line2 widget1
  .db CWIDGETCFG_WIDGET_TYPE_TEXTBUTTON, 0                  ; TYPE, FLAGS
  .db DLGLIGHTCONNS_SEL_BTN_MOTION2, 0                      ; SELECTOR, RESERVED
  .db (1<<WIDGET_OPTS_BORDER_BIT), \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw (DefaultStyle_SpacyButton*2)                          ; STYLE
  .dw RESSOURCE_TXT_MOTIONSENSOR2_S                         ; PARAM1, PARAM2 (text ressource)
  .db 0, BUTTON_MODE_NORMAL                                 ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line2 widget2
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_ADDR_MOTION2, 0                     ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line2 widget3
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_VALUE_MOTION2, 0                    ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL


  ; line3 widget1
  .db CWIDGETCFG_WIDGET_TYPE_TEXTBUTTON, 0                  ; TYPE, FLAGS
  .db DLGLIGHTCONNS_SEL_BTN_LIGHT, 0                      ; SELECTOR, RESERVED
  .db (1<<WIDGET_OPTS_BORDER_BIT), \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw (DefaultStyle_SpacyButton*2)                          ; STYLE
  .dw RESSOURCE_TXT_LIGHTSENSOR_S                           ; PARAM1, PARAM2 (text ressource)
  .db 0, BUTTON_MODE_NORMAL                                 ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line3 widget2
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_ADDR_LIGHT, 0                     ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; line3 widget3
  .db CWIDGETCFG_WIDGET_TYPE_VALUELABEL, 0
  .db DLGLIGHTCONNS_SEL_VALUE_LIGHT, 0                      ; SELECTOR, RESERVED
  .db 0, \
      (WIDGET_PACK_END<<WIDGET_PACK_HSELF0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
      (WIDGET_PACK_END<<WIDGET_PACK_HCONTENT0_BIT) | \
      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
  .dw 0                                                     ; STYLE
  .db 0, 0                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
  .db 0, 0                                                  ; PARAM3, PARAM4
  .dw 0, 0                                                  ; MINVAL, MAXVAL

  ; end of dialog configuration
  .dw 0





; signal map
DlgLightConns_DefaultSignalmap:
  ; header
  .dw Dialog_DefaultSignalmap*2  ; next table to use
  ; entries
  .db DLGLIGHTCONNS_SEL_BTN_MOTION1,  WIDGET_SIGNAL_COMMAND,    LOW(DlgLightConns_OnCmdMotion1),    HIGH(DlgLightConns_OnCmdMotion1)
  .db DLGLIGHTCONNS_SEL_BTN_MOTION2,  WIDGET_SIGNAL_COMMAND,    LOW(DlgLightConns_OnCmdMotion2),    HIGH(DlgLightConns_OnCmdMotion2)
  .db DLGLIGHTCONNS_SEL_BTN_LIGHT,    WIDGET_SIGNAL_COMMAND,    LOW(DlgLightConns_OnCmdLight),      HIGH(DlgLightConns_OnCmdLight)
  .db DLGLIGHTCONNS_SEL_DLG_MOTION1,  WIDGET_SIGNAL_DIALOG_END, LOW(DlgLightConns_OnDlgEndMotion1), HIGH(DlgLightConns_OnDlgEndMotion1)
  .db DLGLIGHTCONNS_SEL_DLG_MOTION2,  WIDGET_SIGNAL_DIALOG_END, LOW(DlgLightConns_OnDlgEndMotion2), HIGH(DlgLightConns_OnDlgEndMotion2)
  .db DLGLIGHTCONNS_SEL_DLG_LIGHT,    WIDGET_SIGNAL_DIALOG_END, LOW(DlgLightConns_OnDlgEndLight),   HIGH(DlgLightConns_OnDlgEndLight)
  ; end of table
  .db 0, 0, 0, 0



#endif