; ***************************************************************************
; copyright   : (C) 2026 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************

#ifndef AQH_AVR_W_LIGHTSETTINGS_ASM
#define AQH_AVR_W_LIGHTSETTINGS_ASM


; ***************************************************************************
; defines

.equ LIGHTSETTINGSWIN_NUM_COLORS    = 8


.equ LIGHTSETTINGSWIN_OFFS_BEGIN            = MAINWINDOW_SIZE
.equ LIGHTSETTINGSWIN_OFFS_ID               = LIGHTSETTINGSWIN_OFFS_BEGIN+0
.equ LIGHTSETTINGSWIN_OFFS_TYPE             = LIGHTSETTINGSWIN_OFFS_BEGIN+1
.equ LIGHTSETTINGSWIN_OFFS_TEXTRES_LO       = LIGHTSETTINGSWIN_OFFS_BEGIN+2
.equ LIGHTSETTINGSWIN_OFFS_TEXTRES_HI       = LIGHTSETTINGSWIN_OFFS_BEGIN+3
.equ LIGHTSETTINGSWIN_OFFS_NODEADDR         = LIGHTSETTINGSWIN_OFFS_BEGIN+4
.equ LIGHTSETTINGSWIN_OFFS_EEPROM_ID        = LIGHTSETTINGSWIN_OFFS_BEGIN+5   ; maybe remove...
.equ LIGHTSETTINGSWIN_OFFS_LEDNUM_LO        = LIGHTSETTINGSWIN_OFFS_BEGIN+6
.equ LIGHTSETTINGSWIN_OFFS_LEDNUM_HI        = LIGHTSETTINGSWIN_OFFS_BEGIN+7
.equ LIGHTSETTINGSWIN_OFFS_ONTIME_LO        = LIGHTSETTINGSWIN_OFFS_BEGIN+8
.equ LIGHTSETTINGSWIN_OFFS_ONTIME_HI        = LIGHTSETTINGSWIN_OFFS_BEGIN+9
.equ LIGHTSETTINGSWIN_OFFS_SOURCE1_NODEADDR = LIGHTSETTINGSWIN_OFFS_BEGIN+10
.equ LIGHTSETTINGSWIN_OFFS_SOURCE1_VALUEID  = LIGHTSETTINGSWIN_OFFS_BEGIN+11
.equ LIGHTSETTINGSWIN_OFFS_SOURCE2_NODEADDR = LIGHTSETTINGSWIN_OFFS_BEGIN+12
.equ LIGHTSETTINGSWIN_OFFS_SOURCE2_VALUEID  = LIGHTSETTINGSWIN_OFFS_BEGIN+13
.equ LIGHTSETTINGSWIN_OFFS_BSOURCE_NODEADDR = LIGHTSETTINGSWIN_OFFS_BEGIN+14
.equ LIGHTSETTINGSWIN_OFFS_BSOURCE_VALUEID  = LIGHTSETTINGSWIN_OFFS_BEGIN+15
.equ LIGHTSETTINGSWIN_OFFS_COLORS           = LIGHTSETTINGSWIN_OFFS_BEGIN+16
.equ LIGHTSETTINGSWIN_SIZE                  = LIGHTSETTINGSWIN_OFFS_COLORS+(LIGHTSETTINGSWIN_NUM_COLORS*2)



; ***************************************************************************
; code

.cseg



; ---------------------------------------------------------------------------
; @routine LightSettingsWin_new @global
;
; @param Y pointer to GUIAPP
; @return CFLAG set of okay, cleared otherwise
; @return Y address of newly created object

LightSettingsWin_new:
  bigcall GuiApp_GetRootWindow
  brcc LightSettingsWin_new_ret
  mov xl, r18  ; use root window as parent for main window
  mov xh, r19
  ldi r24, LOW(LIGHTSETTINGSWIN_SIZE)
  ldi r25, HIGH(LIGHTSETTINGSWIN_SIZE)
  bigcall Object_Alloc                ; Y=space (!r16, !r17, !X)
  brcc LightSettingsWin_new_ret
  rcall LightSettingsWin_Init
LightSettingsWin_new_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine LightSettingsWin_new @global
;
; @param Y pointer to newly allocated widget data
; @param X pointer to root window
; @return CFLAG set of okay, cleared otherwise
; @clobbers any, !Y

LightSettingsWin_Init:
  ldi r16, 0                                                                                           ; OPTS
  ldi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; PACK
  ldi r20, LOW(RESSOURCE_TXT_ROOMCLIMATE)
  ldi r21, HIGH(RESSOURCE_TXT_ROOMCLIMATE)
  bigcall MainWindow_new               ; Y=main window
  brcc LightSettingsWin_Init_ret

  bigcall MainWindow_GetContentWidget  ; r19:r18=content window
  brcc LightSettingsWin_Init_ret
  mov xl, r18                          ; use content window as parent
  mov xh, r19

  ; Y=MainWindow
  push yl                              ; main window
    push yh
      push xl                          ; content window
        push xh
          rcall lightSettingsWinCreateSensorWatches
        pop xh                         ; content window
      pop xl
      bigcall C03App_CreateBackButton
    pop yh                             ; main window
  pop yl  
LightSettingsWin_Init_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine lightSettingsWinCreateSensorWatches
;
; @param X pointer to MainWindow content window (becomes parent)
; @return CFLAG set of okay, cleared otherwise

lightSettingsWinCreateSensorWatches:
  ldi r16, 0                                                                                           ; OPTS
  ldi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; PACK
  ldi r20, HLAYOUT_MODE_SPREAD
  bigcall HLayout_new
  brcc lightSettingsWinCreateSensorWatches_ret

  ldi r16, LOW(LightSettingsWindow_HLayoutStyle*2)
  std Y+WIDGET_OFFS_STYLE_LO, r16
  ldi r16, HIGH(LightSettingsWindow_HLayoutStyle*2)
  std Y+WIDGET_OFFS_STYLE_HI, r16

  mov xl, yl                          ; use HLayout as parent
  mov xh, yh

  ; CO2 sensor watch
  push xl    ; HLayout
    push xh
      ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | \
               (1<<WIDGET_OPTS_INPUT_BIT) | \
               (1<<OBJECT_OPTS_MSGRECV_BIT)                    ; OPTS
      ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
               (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT)     ; PACK
      ldi r20, VALUE_ID_SENSOR_CO2_BASE
      ldi r21, C03_EEID_SENSOR_CO2
      ldi r22, SENSORWATCH_TYPE_CO2
      bigcall SensorWatch_new
    pop xh
  pop xl
  brcc lightSettingsWinCreateSensorWatches_ret

  ; temp sensor watch
  push xl    ; HLayout
    push xh
      ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | \
               (1<<WIDGET_OPTS_INPUT_BIT) | \
               (1<<OBJECT_OPTS_MSGRECV_BIT); OPTS
      ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
               (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) ; PACK
      ldi r20, VALUE_ID_SENSOR_TEMP_BASE
      ldi r21, C03_EEID_SENSOR_TEMP
      ldi r22, SENSORWATCH_TYPE_TEMP
      bigcall SensorWatch_new
    pop xh
  pop xl
  brcc lightSettingsWinCreateSensorWatches_ret

  ; humidity sensor watch
  push xl    ; HLayout
    push xh
      ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | \
               (1<<WIDGET_OPTS_INPUT_BIT) | \
               (1<<OBJECT_OPTS_MSGRECV_BIT); OPTS
      ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
               (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) ; PACK
      ldi r20, VALUE_ID_SENSOR_HUM_BASE
      ldi r21, C03_EEID_SENSOR_HUM
      ldi r22, SENSORWATCH_TYPE_HUM
      bigcall SensorWatch_new
    pop xh
  pop xl

lightSettingsWinCreateSensorWatches_ret:
  ret
; @end






#endif