; ***************************************************************************
; copyright   : (C) 2023 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************


; ***************************************************************************
; Source file for temperature sensor node on AtTiny 84
;
; This is for the full system (i.e. not the boot loader).
; ***************************************************************************

.equ clock=1000000 ; Define the clock frequency



.nolist
.include "include/tn84def.inc" ; Define device ATtiny84
.list

.include "n12_defs.asm"
.include "defs.asm"
.include "common/utils_wait.asm" ; wait macro



; ***************************************************************************
; defines

; ---------------------------------------------------------------------------
; firmware settings including list of modules used

.equ FIRMWARE_VERSION_MAJOR       = 0
.equ FIRMWARE_VERSION_MINOR       = 0
.equ FIRMWARE_VERSION_PATCHLEVEL  = 1


#define MODULES_TIMER
#define MODULES_COM
#define MODULES_COM_WITH_ADDR_PROTO
;#define MODULES_LED
#define MODULES_LED_SIMPLE
#define MODULES_TWI_MASTER
;#define MODULES_LCD
#define MODULES_SI7021
#define MODULES_STATS
;#define MODULES_CNY70
#define MODULES_REED


; ---------------------------------------------------------------------------
; defines for modules

.equ VALUE_ID_TEMP1 = 0x01
.equ VALUE_ID_HUM1  = 0x02

.equ VALUE_ID_ADC   = 0x03
.equ VALUE_ID_REED1 = 0x04
.equ VALUE_ID_REED2 = 0x05

.equ VALUE_ID_REED_CONF = 0x81



; ***************************************************************************
; code segment

.cseg
.org 000000



; ---------------------------------------------------------------------------
; Reset and interrupt vectors

;	rjmp main ; Reset vector
        rjmp BOOTLOADER_ADDR ; Reset vector  ; use this for flashed system
	reti ; EXT_INT0
	rjmp com2IsrPcint0 ; PCI0
	reti ; PCI1
	reti ; WATCHDOG
	reti ; ICP1
	reti ; OC1A
	reti ; OC1B
	reti ; OVF1
        rjmp timerIrqOC0A ; OC0A
	reti ; OC0B
	reti ; OVF0
	reti ; ACI
#ifdef MODULES_CNY70
	rjmp cny70Isr ; ADCC
#else
        reti ; ADCC
#endif
	reti ; ERDY
	reti ; USI_STR
	reti ; USI_OVF


devInfoBlock:        ; 12 bytes
devInfoManufacturer: .db 'A', 'Q', 'U', 'A'
devInfoId:           .db 'N', 0
devInfoVersion:      .db 12, 0                 ; version, revision
firmwareVersion:     .db FIRMWARE_VARIANT_TEMP_WINDOW, FIRMWARE_VERSION_MAJOR
                     .db FIRMWARE_VERSION_MINOR, FIRMWARE_VERSION_PATCHLEVEL

firmwareStart:   rjmp main


; ***************************************************************************
; includes

.include "common/utils.asm"
.include "common/utils_wait_fixed.asm"
.include "common/utils_copy_from_flash.asm"
.include "common/utils_copy_sdram.asm"
.include "common/crc8.asm"

#ifdef MODULES_TIMER
  .include "modules/timer/main.asm"
#endif
#ifdef MODULES_LED
.include "modules/led/main.asm"
#endif
#ifdef MODULES_LED_SIMPLE
.include "modules/led_simple/main.asm"
#endif
#ifdef MODULES_COM
  .include "modules/com2/defs.asm"
  .include "modules/com2/main.asm"
  #ifdef MODULES_COM_WITH_ADDR_PROTO
    .include "modules/comproto/defs.asm"
    .include "modules/comproto/main.asm"
    .include "modules/comproto/addr.asm"
    .include "modules/comproto/msg_recvstats.asm"
    .include "modules/comproto/msg_sendstats.asm"
    .include "modules/comproto/msg_sysstats.asm"
    .include "modules/comproto/msg_memstats.asm"
    .include "modules/comproto/msg_pong.asm"
    .include "modules/comproto/msg_value.asm"
    .include "modules/comproto/msg_device.asm"
    .include "modules/comproto/msg_reboot.asm"
  #endif
#endif
#ifdef MODULES_TWI_MASTER
  .include "modules/twimaster/main.asm"
#endif
#ifdef MODULES_LCD
  .include "modules/lcd/main.asm"
#endif
#ifdef MODULES_SI7021
  .include "modules/si7021/main.asm"
#endif
#ifdef MODULES_STATS
  .include "modules/stats/main.asm"
#endif
#ifdef MODULES_CNY70
  .include "modules/cny70/main.asm"
#endif
#ifdef MODULES_REED
  .include "modules/reed/main.asm"
#endif



; ***************************************************************************
; data in SRAM

.dseg


#ifdef MODULES_LCD
  sramTimerWriteStats:       .byte 2
#endif
sramTimerEnqueueValues:      .byte 2
#ifdef MODULES_SI7021
  sramTimerSI7021Measure:      .byte 2
  sramTimerSI7021SendTemp:     .byte 2
  sramTimerSI7021SendHumidity: .byte 2
#endif
#ifdef MODULES_CNY70
  sramTimerCny70SendAdc:       .byte 2
#endif
#ifdef MODULES_LCD
  sramPeriodicalLcdMark:       .byte 2
#endif


; ***************************************************************************
; data in FLASH

.cseg

#ifdef MODULES_LED
ledA3Flash:    .db DDRA+0x20, PORTA+0x20, PINA+0x20, (1<<PORTA3)
blinkPattern:  .db 2, 50, 0xff, 0xff   ; 1 short blink, 5s pause, restart
;blinkPattern2: .db 2, 2, 0xff, 0xff   ; 1 short blink, short pause, restart
#endif



; ---------------------------------------------------------------------------
; timer list


timerList:
;     SRAM variable/counter        routine                     flags                secs (0=don't start or restart)
#ifdef MODULES_COM_WITH_ADDR_PROTO
  .dw cproAddresModeTimer,         CPRO_Address_OnTimer,       0,                   0     ; (no restart)
#endif
#ifdef MODULES_STATS
  .dw statsSendTimer,              Stats_Timer,                TIMER_FLAGS_IF_ADDR, 300   ; every 5m
#endif
#ifdef MODULES_LCD
  .dw sramPeriodicalLcdMark,       periodicalLcdMark,          0,                    1    ; every sec
  .dw sramTimerWriteStats,         writeStats,                 0,                   10
#endif
#ifdef MODULES_SI7021
  .dw sramTimerSI7021Measure,      SI7021_PeriodicMeasurement, 0,                   30    ; every 30s
  .dw sramTimerSI7021SendTemp,     sendTemp,                   TIMER_FLAGS_IF_ADDR, 60    ; every 60s
  .dw sramTimerSI7021SendHumidity, sendHumidity,               TIMER_FLAGS_IF_ADDR, 60    ; every 60s
#endif
#ifdef MODULES_CNY70
  .dw sramTimerCny70SendAdc,       sendAdc,                    TIMER_FLAGS_IF_ADDR, 30    ; every 30s
#endif
  .dw 0 ; end of list





.include "main.asm"


; ---------------------------------------------------------------------------
; Called on first time run, i.e. on system start. No arguments, no results.

onSystemStart:
  ret


#ifdef MODULES_LCD
periodicalLcdMark:
  rcall printTimerMark
  ret


writeStats:
  rcall printSendStats
  ret
#endif



#ifdef MODULES_SI7021

sendHumidity:
  rcall SI7021_SendHumidity
  brcs sendHumidity_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramTimerSI7021SendHumidity)
  ldi xh, HIGH(sramTimerSI7021SendHumidity)
  rjmp Timer_SetValueTo1s
sendHumidity_okay:
  ret


sendTemp:
  rcall SI7021_SendTemp
  brcs sendTemp_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramTimerSI7021SendTemp)
  ldi xh, HIGH(sramTimerSI7021SendTemp)
  rjmp Timer_SetValueTo1s
sendTemp_okay:
  ret

#endif



#ifdef MODULES_CNY70
sendAdc:
  rcall CNY70_SendAdc
  brcs sendAdc_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramTimerCny70SendAdc)
  ldi xh, HIGH(sramTimerCny70SendAdc)
  rjmp Timer_SetValueTo1s
sendAdc_okay:
  ret
#endif



; ---------------------------------------------------------------------------
; Called every 100ms. Add your routine calls here. No arguments, no results.

onEvery100ms:
#ifdef MODULES_LED
  ; ticker for LED module
  ldi zl, LOW(ledA3Flash)
  ldi zh, HIGH(ledA3Flash)
  ldi yl, LOW(ledA3Sram)
  ldi yh, HIGH(ledA3Sram)
  rcall Led_Tick
#endif

#ifdef MODULES_LED_SIMPLE
  rcall LedSimple_Every100ms
#endif


#ifdef MODULES_CNY70
  rcall CNY70_Every100ms
#endif

#ifdef MODULES_REED
  rcall REED_Every100ms
#endif

  ret



; ---------------------------------------------------------------------------
; @routine onPacketReceived:
;
; Called after a packet was received via COM module. Add your routine calls here.
;
; The packet will be released in any case after return from this call.
;
; @return CFLAG set if message handled, cleared otherwise
; @param X  pointer to received buffer
; @clobbers all

onPacketReceived:
  ; get msg code
  adiw xh:xl, COM2_MSG_OFFS_CMD
  ld r16, x
  sbiw xh:xl, COM2_MSG_OFFS_CMD

  cpi r16, CPRO_CMD_VALUE_SET
  brne onPacketReceived_l1
  ; msg code is CPRO_CMD_VALUE_SET
  ; TODO

onPacketReceived_l1:
  rjmp CPRO_OnPacketReceived
; @end




onSetValueReceived:
  adiw xh:xl, CPRO_PACKET_SETVALUE_OFFS_VALUEID
  ld r16, X
  sbiw xh:xl, CPRO_PACKET_SETVALUE_OFFS_VALUEID
  cpi r16, VALUE_ID_REED_CONF
  brne onSetValueReceived_l1
  rjmp onSetReedConf
onSetValueReceived_l1:
  clc
  ret


onSetReedConf:
  ; get new value
  adiw xh:xl, CPRO_PACKET_SETVALUE_OFFS_VALUE
  ld r16, X
  sbiw xh:xl, CPRO_PACKET_SETVALUE_OFFS_VALUE
  ; set config
  rcall REED_SetConfig
  ; send ACK
  ldi r16, CPRO_CMD_VALUE_SET_ACK
  rcall CPRO_SendSetValueResponse
  sec
  ret