; ***************************************************************************
; copyright   : (C) 2023 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************


; ***************************************************************************
; Source file for temperature sensor node on AtTiny 84
;
; This is for the full system (i.e. not the boot loader).
; ***************************************************************************

.equ clock=8000000 ; Define the clock frequency



.nolist
.include "include/tn84def.inc" ; Define device ATtiny84
.list

.include "n12_defs.asm"
.include "defs.asm"
.include "common/utils_wait.asm" ; wait macro



; ***************************************************************************
; defines

; ---------------------------------------------------------------------------
; firmware settings including list of modules used

.equ FIRMWARE_VERSION_MAJOR       = 0
.equ FIRMWARE_VERSION_MINOR       = 0
.equ FIRMWARE_VERSION_PATCHLEVEL  = 1


#define MODULES_TIMER
#define MODULES_COM
#define MODULES_COM_WITH_ADDR_PROTO
;#define MODULES_LED
#define MODULES_LED_SIMPLE
;#define MODULES_TWI_MASTER
;#define MODULES_LCD
;#define LCD_MINIMAL_FONT
;#define MODULES_SI7021
#define MODULES_STATS
;#define MODULES_CNY70
;#define MODULES_REED
;#define MODULES_OWI_MASTER
;#define MODULES_DS18B20
#define MODULES_SK6812



; ---------------------------------------------------------------------------
; defines for modules

.equ VALUE_ID_SI7021_TEMP    = 0x01
.equ VALUE_ID_SI7021_HUM     = 0x02

.equ VALUE_ID_ADC            = 0x03
.equ VALUE_ID_REED1          = 0x04
.equ VALUE_ID_REED2          = 0x05

.equ VALUE_ID_REED_CONF      = 0x81
.equ VALUE_ID_LED_NUMLEDS    = 0x82
.equ VALUE_ID_LED_RGBW_VALUE = 0x83



; ***************************************************************************
; code segment

.cseg
.org 000000



; ---------------------------------------------------------------------------
; Reset and interrupt vectors

;	rjmp main ; Reset vector
        rjmp BOOTLOADER_ADDR ; Reset vector  ; use this for flashed system
	reti ; EXT_INT0
	rjmp com2IsrPcint0 ; PCI0
	reti ; PCI1
	reti ; WATCHDOG
	reti ; ICP1
	reti ; OC1A
	reti ; OC1B
	reti ; OVF1
        rjmp baseTimerIrqOC0A ; OC0A
	reti ; OC0B
	reti ; OVF0
	reti ; ACI
        reti ; ADCC
	reti ; ERDY
	reti ; USI_STR
	reti ; USI_OVF


devInfoBlock:        ; 12 bytes
devInfoManufacturer: .db 'A', 'Q', 'U', 'A'
devInfoId:           .db 'N', 0
devInfoVersion:      .db 12, 0                 ; version, revision
firmwareVersion:     .db FIRMWARE_VARIANT_TEMP_WINDOW, FIRMWARE_VERSION_MAJOR
                     .db FIRMWARE_VERSION_MINOR, FIRMWARE_VERSION_PATCHLEVEL

firmwareStart:   rjmp main


; ***************************************************************************
; includes

.include "common/utils.asm"
.include "common/utils_wait_fixed.asm"
.include "common/utils_copy_from_flash.asm"
.include "common/utils_copy_sdram.asm"
.include "common/crc8.asm"

.include "modules/basetimer/main.asm"

#ifdef MODULES_TIMER
  .include "modules/timer/main.asm"
#endif
#ifdef MODULES_LED
.include "modules/led/main.asm"
#endif
#ifdef MODULES_LED_SIMPLE
.include "modules/led_simple/main.asm"
#endif
#ifdef MODULES_COM
  .include "modules/com2/defs.asm"
  .include "modules/com2/main.asm"
  #ifdef MODULES_COM_WITH_ADDR_PROTO
    .include "modules/comproto/defs.asm"
    .include "modules/comproto/main.asm"
    .include "modules/comproto/addr.asm"
    .include "modules/comproto/msg_recvstats.asm"
    .include "modules/comproto/msg_sendstats.asm"
    .include "modules/comproto/msg_sysstats.asm"
    .include "modules/comproto/msg_memstats.asm"
    .include "modules/comproto/msg_pong.asm"
    .include "modules/comproto/msg_value.asm"
    .include "modules/comproto/msg_device.asm"
    .include "modules/comproto/msg_reboot.asm"
  #endif
#endif
#ifdef MODULES_TWI_MASTER
  .include "modules/twimaster/main.asm"
#endif
#ifdef MODULES_LCD
  .include "modules/lcd/main.asm"
#endif
#ifdef MODULES_SI7021
  .include "modules/si7021/main.asm"
#endif
#ifdef MODULES_STATS
  .include "modules/stats/main.asm"
#endif
#ifdef MODULES_CNY70
  .include "modules/cny70/main.asm"
#endif
#ifdef MODULES_REED
  .include "modules/reed/main.asm"
#endif
#ifdef MODULES_OWI_MASTER
  .include "modules/owimaster/main.asm"
#endif
#ifdef MODULES_DS18B20
  .include "modules/ds18b20/main.asm"
#endif
#ifdef MODULES_SK6812
  .include "modules/sk6812/main.asm"
#endif


; ***************************************************************************
; data in SRAM

.dseg


#ifdef MODULES_LCD
  sramTimerWriteStats:       .byte 2
#endif
sramTimerEnqueueValues:      .byte 2
#ifdef MODULES_SI7021
  sramTimerSI7021Measure:      .byte 2
  sramTimerSI7021SendTemp:     .byte 2
  sramTimerSI7021SendHumidity: .byte 2
#endif
#ifdef MODULES_CNY70
  sramTimerCny70SendAdc:       .byte 2
#endif
#ifdef MODULES_LCD
  sramPeriodicalLcdMark:       .byte 2
#endif
#ifdef MODULES_DS18B20
  sramDs18b20Timer:            .byte 2
  sramSendDs18b20TempTimer:    .byte 2
#endif


; ***************************************************************************
; data in FLASH

.cseg

#ifdef MODULES_LED
ledA3Flash:    .db DDRA+0x20, PORTA+0x20, PINA+0x20, (1<<PORTA3)
blinkPattern:  .db 2, 50, 0xff, 0xff   ; 1 short blink, 5s pause, restart
;blinkPattern2: .db 2, 2, 0xff, 0xff   ; 1 short blink, short pause, restart
#endif



; ---------------------------------------------------------------------------
; timer list


timerList:
;     SRAM variable/counter        routine                     flags                secs (0=don't start or restart)
#ifdef MODULES_COM_WITH_ADDR_PROTO
  .dw cproAddresModeTimer,         CPRO_Address_OnTimer,       0,                   0     ; (no restart)
#endif
#ifdef MODULES_STATS
  .dw statsSendTimer,              Stats_Timer,                TIMER_FLAGS_IF_ADDR, 3000   ; every 5m
#endif
#ifdef MODULES_LCD
  .dw sramPeriodicalLcdMark,       periodicalLcdMark,          0,                    10    ; every sec
  .dw sramTimerWriteStats,         writeStats,                 0,                   100
#endif
#ifdef MODULES_SI7021
  .dw sramTimerSI7021Measure,      SI7021_OnTimer,             0,                   300    ; every 30s
  .dw sramTimerSI7021SendTemp,     sendSI7021Temp,             TIMER_FLAGS_IF_ADDR, 600    ; every 60s
  .dw sramTimerSI7021SendHumidity, sendSI7021Humidity,         TIMER_FLAGS_IF_ADDR, 600    ; every 60s
#endif
#ifdef MODULES_CNY70
  .dw sramTimerCny70SendAdc,       CNY70_OnTimer,              TIMER_FLAGS_IF_ADDR, 50     ; every 5s
#endif
#ifdef MODULES_DS18B20
  .dw sramDs18b20Timer,            Ds18b20_OnTimer,            0,                   300    ; every 30s
  .dw sramSendDs18b20TempTimer,    sendDs18b20Temp,            TIMER_FLAGS_IF_ADDR, 600    ; every 60s
#endif
  .dw 0 ; end of list





.include "main.asm"


systemSetSpeed:
.if clock == 1000000
  ldi r16, (1<<CLKPCE)
  ldi r17, (1<<CLKPS1) | (1<<CLKPS0)
  out CLKPR, r16
  out CLKPR, r17
.endif

.if clock == 8000000
  ldi r16, (1<<CLKPCE)
  ldi r17, 0
  out CLKPR, r16
  out CLKPR, r17
.endif
  ret


systemSetBootSpeed:
  ldi r16, (1<<CLKPCE)
  ldi r17, (1<<CLKPS1) | (1<<CLKPS0)
  out CLKPR, r16
  out CLKPR, r17
  ret


; ---------------------------------------------------------------------------
; Called on first time run, i.e. on system start. No arguments, no results.

onSystemStart:
  ret


#ifdef MODULES_LCD
periodicalLcdMark:
  rcall printTimerMark
  ret


writeStats:
  rcall printSendStats
  ret
#endif


#ifdef MODULES_SI7021

sendSI7021Humidity:
  rcall SI7021_SendHumidity
  brcs sendSI7021Humidity_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramTimerSI7021SendHumidity)
  ldi xh, HIGH(sramTimerSI7021SendHumidity)
  rjmp Timer_SetValueTo1s
sendSI7021Humidity_okay:
  ret


sendSI7021Temp:
  rcall SI7021_SendTemp
  brcs sendSI7021Temp_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramTimerSI7021SendTemp)
  ldi xh, HIGH(sramTimerSI7021SendTemp)
  rjmp Timer_SetValueTo1s
sendSI7021Temp_okay:
  ret
#endif


#ifdef MODULES_DS18B20
sendDs18b20Temp:
  rcall Ds18b20_SendTemp
  brcs sendDs18b20Temp_okay
  ; set timer to 1s to retry later
  ldi xl, LOW(sramSendDs18b20TempTimer)
  ldi xh, HIGH(sramSendDs18b20TempTimer)
  rjmp Timer_SetValueTo1s
sendDs18b20Temp_okay:
  ret
#endif



; ---------------------------------------------------------------------------
; Called every 100ms. Add your routine calls here. No arguments, no results.

onEvery100ms:
#ifdef MODULES_LED
  ; ticker for LED module
  ldi zl, LOW(ledA3Flash)
  ldi zh, HIGH(ledA3Flash)
  ldi yl, LOW(ledA3Sram)
  ldi yh, HIGH(ledA3Sram)
  rcall Led_Tick
#endif

#ifdef MODULES_LED_SIMPLE
  rcall LedSimple_Every100ms
#endif


#ifdef MODULES_REED
  rcall REED_Every100ms
#endif

  ret



; ---------------------------------------------------------------------------
; @routine onPacketReceived:
;
; Called after a packet was received via COM module. Add your routine calls here.
;
; The packet will be released in any case after return from this call.
;
; @return CFLAG set if message handled, cleared otherwise
; @param X  pointer to received buffer
; @clobbers all

onPacketReceived:
  ; get msg code
  adiw xh:xl, COM2_MSG_OFFS_CMD
  ld r16, x
  sbiw xh:xl, COM2_MSG_OFFS_CMD

  cpi r16, CPRO_CMD_VALUE_SET
  brne onPacketReceived_l1
  ; msg code is CPRO_CMD_VALUE_SET
  rjmp onSetValueReceived

onPacketReceived_l1:
  rjmp CPRO_OnPacketReceived
; @end



onSetValueReceived:
  adiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUEID
  ld r16, X
  sbiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUEID
  cpi r16, VALUE_ID_REED_CONF
  brne onSetValueReceived_l1
#ifdef MODULES_REED
  rjmp onSetReedConf
#else
  ret
#endif
onSetValueReceived_l1:
  cpi r16, VALUE_ID_LED_RGBW_VALUE
  brne onSetValueReceived_l2
#ifdef MODULES_SK6812
  rjmp onSetRgbwValue
#endif
onSetValueReceived_l2:
  cpi r16, VALUE_ID_LED_NUMLEDS
  brne onSetValueReceived_l3
#ifdef MODULES_SK6812
  rjmp onSetNumLeds
#endif
onSetValueReceived_l3:
  ldi r16, CPRO_CMD_VALUE_SET_NACK
  rcall CPRO_SendSetValueResponse
  clc
  ret


#ifdef MODULES_REED
onSetReedConf:
  ; get new value
  adiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE
  ld r16, X
  sbiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE
  ; set config
  rcall REED_SetConfig
  ; send ACK
  ldi r16, CPRO_CMD_VALUE_SET_ACK
  rcall CPRO_SendSetValueResponse
  sec
  ret
#endif


#ifdef MODULES_SK6812
onSetRgbwValue:
  ; get new value
  adiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE
  ld r18, X+ ; R
  ld r19, X+ ; G
  ld r20, X+ ; B
  ld r21, X+ ; W
  sbiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE+4
  rcall SK6812_SetAllColor
  ; send ACK
  ldi r16, CPRO_CMD_VALUE_SET_ACK
  rcall CPRO_SendSetValueResponse
  sec
  ret

onSetNumLeds:
  ; get new value
  adiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE
  ld r16, X ; number of leds
  sbiw xh:xl, CPRO_PACKET_VALUE_OFFS_VALUE
  sts sk6812NumLeds, r16
  ; send ACK
  ldi r16, CPRO_CMD_VALUE_SET_ACK
  rcall CPRO_SendSetValueResponse
  sec
  ret

#endif