; ***************************************************************************
; copyright   : (C) 2026 by Martin Preuss
; email       : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome".                              *
; * Please see toplevel file COPYING of that project for license details.   *
; ***************************************************************************

#ifndef AQH_AVR_GUI2_HLAYOUT_ASM
#define AQH_AVR_GUI2_HLAYOUT_ASM


; ***************************************************************************
; defines

.equ HLAYOUT_OFFS_BEGIN    =  WIDGET_SIZE
; no data for now
.equ HLAYOUT_SIZE          =  HLAYOUT_OFFS_BEGIN+0




; ***************************************************************************
; code

.cseg



; ---------------------------------------------------------------------------
; @routine HLayout_new @global
;
; @return CFLAG set of okay, cleared otherwise
; @return Y address of newly created object
; @param X parent widget
; @param r16 value for OBJECT_OFFS_OPTS_LO
; @param r17 value for OBJECT_OFFS_OPTS_HI
; @param r21:r20 ressource id for title
; @clobbers any

HLayout_new:
  push r20
    push r21
      ldi r24, LOW(HLAYOUT_SIZE)
      ldi r25, HIGH(HLAYOUT_SIZE)
      bigcall Object_Alloc         ; (!r16, !r17, !X)
    pop r21
  pop r20
  brcc HLayout_new_ret
  rcall HLayout_Init               ; (r16, r17, X)
  sec
HLayout_new_ret:
  ret
; @end



; ---------------------------------------------------------------------------
; @routine HLayout_Init @global
;
; @param Y address of widget
; @param X parent widget (if any)
; @clobbers r16, r17, X

HLayout_Init:
  push r20
    push r21
      ; call base class
      bigcall Widget_Init             ; (r16, r17, X)
    pop r21
  pop r20

  ; set default signal map
  ldi r16, LOW(HLayout_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
  ldi r16, HIGH(HLayout_DefaultSignalmap*2)
  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16

  ret
; @end



; ---------------------------------------------------------------------------
; @routine HLayout_OnLayout
;
; @param Y pointer to widget
; @clobbers any, !Y

HLayout_OnLayout:
  rcall hLayoutHorizontally
  rcall hLayoutVerticalAdjust
  ; force re-drawing of this widget
  ldd r16, Y+OBJECT_OFFS_FLAGS
  ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
  std Y+OBJECT_OFFS_FLAGS, r16
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine HLayout_OnGetDefaultWidth
;
; @param Y pointer to widget
; @return r19:r18 value
; @clobbers any, !Y

HLayout_OnGetDefaultWidth:
  rcall Layout_SetDefaultWidths
  rcall Layout_SumTmpValues     ; r19:r18=default width
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine HLayout_OnGetDefaultHeight
;
; @param Y pointer to widget
; @return r19:r18 value
; @clobbers any, !Y

HLayout_OnGetDefaultHeight:
  rcall Layout_SetDefaultHeights
  rcall Layout_GetMaxTmp

  ; get outer border
  ldd zl, Y+WIDGET_OFFS_STYLE_LO
  ldd zh, Y+WIDGET_OFFS_STYLE_HI
  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
  lpm r16, Z
  clr r17
  sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
  
  add r18, r16  ; add outer border (top)
  adc r19, r17

  add r18, r16  ; add outer border (bottom)
  adc r19, r17
  
  sec
  ret
; @end



; ---------------------------------------------------------------------------
; @routine hLayoutCountFillXChildren
;
; @param Y pointer to widget
; @return r16 number of children with opt WIDGET_OPTSLO_FILLX_BIT
; @clobbers r17, r18, r19

hLayoutCountFillXChildren:
  clr r16
  push yl
    push yh
      bigcall OBJ_GetFirstChild
hLayoutCountFillXChildren_loop:
        brcc hLayoutCountFillXChildren_done
        mov yl, r18
        mov yh, r19
        ldd r17, Y+OBJECT_OFFS_OPTS_LO
        sbrc r17, WIDGET_OPTSLO_FILLX_BIT
          inc r16
        rcall OBJ_GetNext
      rjmp hLayoutCountFillXChildren_loop
hLayoutCountFillXChildren_done:
    pop yh
  pop yl
  ret
; @end



; ---------------------------------------------------------------------------
; @routine hLayoutSetX
;
; @param Y pointer to widget
; @clobbers r16, r17, r18, r19, r20, r21, r22, r23, Z

hLayoutSetX:
  ldd zl, Y+WIDGET_OFFS_STYLE_LO
  ldd zh, Y+WIDGET_OFFS_STYLE_HI

  ; get spacing
  adiw zh:zl, WIDGET_STYLE_OFFS_SPACING
  lpm r22, Z
  clr r23
  sbiw zh:zl, WIDGET_STYLE_OFFS_SPACING
  ; get outer border
  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
  lpm r20, Z
  clr r21
  sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE

  push yl
    push yh
      bigcall OBJ_GetFirstChild
hLayoutSetX_loop:
        brcc hLayoutSetX_loopEnd
        mov yl, r18
        mov yh, r19
        ; set X
        std Y+WIDGET_OFFS_X_LO, r20
        std Y+WIDGET_OFFS_X_HI, r21
        ; set width
        ldd r16, Y+WIDGET_OFFS_TMP_LO
        ldd r17, Y+WIDGET_OFFS_TMP_HI
        std Y+WIDGET_OFFS_WIDTH_LO, r16
        std Y+WIDGET_OFFS_WIDTH_HI, r17
        ; advance r21:r20
        add r20, r16    ; add widget size
        adc r21, r17
        add r20, r22    ; add spacing
        adc r21, r23

        ; force direct children to re-layout and re-draw
        ldd r16, Y+OBJECT_OFFS_FLAGS
        ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT) | (1<<WIDGET_FLAGS_LAYOUT_BIT)
        std Y+OBJECT_OFFS_FLAGS, r16

        rcall OBJ_GetNext
      rjmp hLayoutSetX_loop
hLayoutSetX_loopEnd:
    pop yh
  pop yl
  ret
; @end



; ---------------------------------------------------------------------------
; @routine hLayoutVerticalAdjust
;
; @param Y pointer to widget
; @clobbers r17, r18, r19, r20, r21, r22, r23, Z

hLayoutVerticalAdjust:
  bigcall Layout_SetDefaultHeights
  
  ldd zl, Y+WIDGET_OFFS_STYLE_LO
  ldd zh, Y+WIDGET_OFFS_STYLE_HI

  ; get outer border
  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
  lpm r20, Z
  clr r21
  sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE

  ldd r22, Y+WIDGET_OFFS_HEIGHT_LO
  ldd r23, Y+WIDGET_OFFS_HEIGHT_HI
  sub r22, r20   ; subtract border (top)
  sbc r23, r21
  sub r22, r20   ; subtract border (bottom)
  sbc r23, r21

  push yl
    push yh
      bigcall OBJ_GetFirstChild
hLayoutVerticalAdjust_loop:
        brcc hLayoutVerticalAdjust_loopEnd
        mov yl, r18
        mov yh, r19
        std Y+WIDGET_OFFS_Y_LO, r20
        std Y+WIDGET_OFFS_Y_HI, r21
        
        ldd r18, Y+WIDGET_OFFS_TMP_LO
        ldd r19, Y+WIDGET_OFFS_TMP_HI
        
        ldd r17, Y+OBJECT_OFFS_OPTS_LO
        sbrs r17, WIDGET_OPTSLO_FILLY_BIT
          rjmp hLayoutVerticalAdjust_setHeight
        mov r18, r22                          ; increase height to full height
        mov r19, r23
hLayoutVerticalAdjust_setHeight:
        std Y+WIDGET_OFFS_HEIGHT_LO, r18
        std Y+WIDGET_OFFS_HEIGHT_HI, r19
        rcall OBJ_GetNext
      rjmp hLayoutVerticalAdjust_loop
hLayoutVerticalAdjust_loopEnd:
    pop yh
  pop yl
  ret
; @end



hLayoutHorizontally:
  rcall Layout_SetDefaultWidths
  rcall Layout_SumTmpValues         ; r21:r20=width

  ldd r22, Y+WIDGET_OFFS_WIDTH_LO
  ldd r23, Y+WIDGET_OFFS_WIDTH_HI
  sub r22, r20
  sbc r23, r21
  breq hLayoutHorizontally_setX
  brcs hLayoutHorizontally_setX

  ; r23:r22=remaining space to distribute
  rcall hLayoutCountFillXChildren ; r16=number of expandable child widgets
  tst r16
  breq hLayoutHorizontally_setX

  ; calc space to add to each expandable child widget and add it
  mov r20, r22
  mov r21, r23
  mov r22, r16
  clr r23
  bigcall Utils_Divu16_16_16 ; r17:r16=space per expandable child widget
  mov r20, r16
  mov r21, r17
  rcall Layout_AddToTmpOfFillXChildren

hLayoutHorizontally_setX:
  rcall hLayoutSetX
  ret
; @end





; ***************************************************************************
; data in FLASH

HLayout_DefaultSignalmap:
  ; header
  .dw Widget_DefaultSignalmap  ; next table to use
  ; entries
  .db 0,                           WIDGET_SIGNAL_LAYOUT,   LOW(HLayout_OnLayout),           HIGH(HLayout_OnLayout)
  .db WIDGET_VALUE_DEFAULT_WIDTH,  WIDGET_SIGNAL_GETVALUE, LOW(HLayout_OnGetDefaultWidth),  HIGH(HLayout_OnGetDefaultWidth)
  .db WIDGET_VALUE_DEFAULT_HEIGHT, WIDGET_SIGNAL_GETVALUE, LOW(HLayout_OnGetDefaultHeight), HIGH(HLayout_OnGetDefaultHeight)

  .db 0, 0, 0, 0  ; end of table



#endif