diff --git a/avr/devices/c03/test/main.asm b/avr/devices/c03/test/main.asm
index 271cbfd..f878a99 100644
--- a/avr/devices/c03/test/main.asm
+++ b/avr/devices/c03/test/main.asm
@@ -250,7 +250,6 @@ test:
   ldi r16, 0
   ldi r17, 0
   bigcall GuiApp_new
-  brcc DEBUG_STOP
   sts guiApp, yl
   sts guiApp+1, yh
 
@@ -273,20 +272,43 @@ test:
         push xh
           mov xl, r18
           mov xh, r19
+
+          push xl  ; content window
+            push xh
+              ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | (1<<WIDGET_OPTS_INPUT_BIT)                                   ; OPTS
+              ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) ; PACK
+              ldi r20, BUTTON_MODE_NORMAL
+              bigcall Button_new
+              mov xl, yl
+              mov xh, yh
+              
+              ldi r16, (1<<WIDGET_OPTS_BORDER_BIT)
+              ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) |\
+                       (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VCONTENT0_BIT)
+              ldi r20, LOW(RESSSOURCE_TXT_BUERO)
+              ldi r21, HIGH(RESSSOURCE_TXT_BUERO)
+              bigcall Label_new
+            pop xh
+          pop xl
+
+          push xl
+            push xh
+              ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | (1<<WIDGET_OPTS_INPUT_BIT)                                   ; OPTS
+              ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) ; PACK
+              ldi r20, BUTTON_MODE_NORMAL
+              bigcall Button_new
+              mov xl, yl
+              mov xh, yh
+              
+              ldi r16, (1<<WIDGET_OPTS_BORDER_BIT)
+              ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) |\
+                       (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VCONTENT0_BIT)
+              ldi r20, LOW(RESSSOURCE_IMG_TEMP96)
+              ldi r21, HIGH(RESSSOURCE_IMG_TEMP96)
+              bigcall ImageView_new
+            pop xh
+          pop xl
           
-          ldi r16, (1<<OBJECT_OPTS_TIMER_BIT) | (1<<WIDGET_OPTS_INPUT_BIT)                                   ; OPTS
-          ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) ; PACK
-          ldi r20, BUTTON_MODE_NORMAL
-          bigcall Button_new
-          mov xl, yl
-          mov xh, yh
-          
-          ldi r16, (1<<WIDGET_OPTS_BORDER_BIT)
-          ldi r17, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VSELF0_BIT) |\
-                   (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | (WIDGET_PACK_BEGIN<<WIDGET_PACK_VCONTENT0_BIT)
-          ldi r20, LOW(RESSSOURCE_TXT_BUERO)
-          ldi r21, HIGH(RESSSOURCE_TXT_BUERO)
-          bigcall Label_new
         pop xh
       pop xl
     pop yh
@@ -353,6 +375,8 @@ DEBUG_STOP3:
 .include "modules/lcd2/gui2/base/rootwindow.asm"
 .include "modules/lcd2/gui2/base/label.asm"
 .include "modules/lcd2/gui2/base/button.asm"
+.include "modules/lcd2/gui2/base/imageview.asm"
+.include "modules/lcd2/gui2/base/valuelabel.asm"
 
 
 
diff --git a/avr/modules/lcd2/gui2/base/0BUILD b/avr/modules/lcd2/gui2/base/0BUILD
new file mode 100644
index 0000000..3e41430
--- /dev/null
+++ b/avr/modules/lcd2/gui2/base/0BUILD
@@ -0,0 +1,21 @@
+<?xml?>
+
+<gwbuild>
+
+  <extradist>
+    button.asm
+    guiapp.asm
+    hlayout.asm
+    imageview.asm
+    label.asm
+    layout.asm
+    mainwindow.asm
+    object.asm
+    rootwindow.asm
+    valuelabel.asm
+    widget.asm
+  </extradist>
+
+</gwbuild>
+
+
diff --git a/avr/modules/lcd2/gui2/base/hlayout.asm b/avr/modules/lcd2/gui2/base/hlayout.asm
index 724e43d..0766658 100644
--- a/avr/modules/lcd2/gui2/base/hlayout.asm
+++ b/avr/modules/lcd2/gui2/base/hlayout.asm
@@ -15,8 +15,14 @@
 ; defines
 
 .equ HLAYOUT_OFFS_BEGIN    =  WIDGET_SIZE
-; no data for now
-.equ HLAYOUT_SIZE          =  HLAYOUT_OFFS_BEGIN+0
+.equ HLAYOUT_OFFS_MODE     =  HLAYOUT_OFFS_BEGIN+0
+.equ HLAYOUT_SIZE          =  HLAYOUT_OFFS_BEGIN+1
+
+
+; values for HLAYOUT_OFFS_MODE
+.equ HLAYOUT_MODE_EXPAND   = 0
+.equ HLAYOUT_MODE_SPREAD   = 1
+
 
 
 
@@ -36,17 +42,12 @@
 ; @param X parent widget
 ; @param r16 value for OBJECT_OFFS_OPTS
 ; @param r17 value for WIDGET_OFFS_PACK
-; @param r21:r20 ressource id for title
 ; @clobbers any
 
 HLayout_new:
-  push r20
-    push r21
-      ldi r24, LOW(HLAYOUT_SIZE)
-      ldi r25, HIGH(HLAYOUT_SIZE)
-      bigcall Object_Alloc         ; (!r16, !r17, !X)
-    pop r21
-  pop r20
+  ldi r24, LOW(HLAYOUT_SIZE)
+  ldi r25, HIGH(HLAYOUT_SIZE)
+  bigcall Object_Alloc         ; (!r16, !r17, !X)
   brcc HLayout_new_ret
   rcall HLayout_Init               ; (r16, r17, X)
   sec
@@ -61,6 +62,8 @@ HLayout_new_ret:
 ;
 ; @param Y address of widget
 ; @param X parent widget (if any)
+; @param r16 value for OBJECT_OFFS_OPTS
+; @param r17 value for WIDGET_OFFS_PACK
 ; @clobbers r16, r17, X
 
 HLayout_Init:
@@ -90,7 +93,7 @@ HLayout_Init:
 
 HLayout_OnLayout:
   rcall hLayoutHorizontally
-  rcall hLayoutVerticalAdjust
+  rcall hLayoutVertically
   ; force re-drawing of this widget, clear layout bit
   ldd r16, Y+OBJECT_OFFS_FLAGS
   sbr r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
@@ -102,6 +105,24 @@ HLayout_OnLayout:
 
 
 
+; ---------------------------------------------------------------------------
+; @routine HLayout_OnGetDefaultHeight
+;
+; @param Y pointer to widget
+; @return r19:r18 value
+; @clobbers any, !Y
+
+HLayout_OnGetDefaultHeight:
+  rcall Layout_SetDefaultHeights
+  rcall Layout_GetMaxTmp
+  bigcall Widget_AddOuterStyleBorders   ; (r20, r21)
+  sec
+  ret
+
+; @end
+
+
+
 ; ---------------------------------------------------------------------------
 ; @routine HLayout_OnGetDefaultWidth
 ;
@@ -118,37 +139,6 @@ HLayout_OnGetDefaultWidth:
 
 
 
-; ---------------------------------------------------------------------------
-; @routine HLayout_OnGetDefaultHeight
-;
-; @param Y pointer to widget
-; @return r19:r18 value
-; @clobbers any, !Y
-
-HLayout_OnGetDefaultHeight:
-  rcall Layout_SetDefaultHeights
-  rcall Layout_GetMaxTmp                          ; r19:r18=max tmp value (r20, r21)
-
-  ; get outer border
-  ldd zl, Y+WIDGET_OFFS_STYLE_LO
-  ldd zh, Y+WIDGET_OFFS_STYLE_HI
-  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
-  lpm r20, Z
-  clr r21
-  sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
-  
-  add r18, r20  ; add outer border (top)
-  adc r19, r21
-
-  add r18, r20  ; add outer border (bottom)
-  adc r19, r21
-  
-  sec
-  ret
-; @end
-
-
-
 ; ---------------------------------------------------------------------------
 ; @routine hLayoutSetX
 ;
@@ -156,29 +146,307 @@ HLayout_OnGetDefaultHeight:
 ; @clobbers r16, r17, r18, r19, r20, r21, r22, r23, Z
 
 hLayoutSetX:
+  ldd zl, Y+WIDGET_OFFS_STYLE_LO
+  ldd zh, Y+WIDGET_OFFS_STYLE_HI
+
+  ; get spacing
+  adiw zh:zl, WIDGET_STYLE_OFFS_SPACING
+  lpm r22, Z
+  clr r23
+  sbiw zh:zl, WIDGET_STYLE_OFFS_SPACING
+  ; get outer border
+  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
+  lpm r20, Z
+  clr r21
+  sbiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
+
+  push yl
+    push yh
+      bigcall OBJ_GetFirstChild
+      brcc hLayoutSetX_loopEnd
+hLayoutSetX_loop:
+        mov yl, r18
+        mov yh, r19
+        ldd r16, Y+OBJECT_OFFS_FLAGS
+        sbrs r16, WIDGET_FLAGS_VISIBLE_BIT
+          rjmp hLayoutSetX_next
+        ; set Y
+        std Y+WIDGET_OFFS_X_LO, r20
+        std Y+WIDGET_OFFS_X_HI, r21
+        ; set width
+        ldd r16, Y+WIDGET_OFFS_TMP_LO
+        ldd r17, Y+WIDGET_OFFS_TMP_HI
+        std Y+WIDGET_OFFS_WIDTH_LO, r16
+        std Y+WIDGET_OFFS_WIDTH_HI, r17
+        ; advance r21:r20
+        add r20, r16    ; add widget size
+        adc r21, r17
+        add r20, r22    ; add spacing
+        adc r21, r23
+
+        ; force direct children to re-layout and re-draw
+        ldd r16, Y+OBJECT_OFFS_FLAGS
+        ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT) | (1<<WIDGET_FLAGS_LAYOUT_BIT)
+        std Y+OBJECT_OFFS_FLAGS, r16
+hLayoutSetX_next:
+        rcall OBJ_GetNext
+      brcs hLayoutSetX_loop
+hLayoutSetX_loopEnd:
+    pop yh
+  pop yl
   ret
 ; @end
 
 
 
 ; ---------------------------------------------------------------------------
-; @routine hLayoutVerticalAdjust
+; @routine hLayoutVertically
 ;
 ; @param Y pointer to widget
-; @clobbers r17, r18, r19, r20, r21, r22, r23, Z
+; @clobbers any, !Y
 
-hLayoutVerticalAdjust:
+hLayoutVertically:
+  bigcall Layout_SetDefaultWidths ; (any, !Y)
+  ; calc usable height of host widget
+  ldd r22, Y+WIDGET_OFFS_HEIGHT_LO
+  ldd r23, Y+WIDGET_OFFS_HEIGHT_HI
+  ldd zl, Y+WIDGET_OFFS_STYLE_LO
+  ldd zh, Y+WIDGET_OFFS_STYLE_HI
+  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
+  lpm r18, Z+
+  lpm r19, Z
+  sub r22, r18
+  sbc r23, r19
+  sub r22, r18
+  sbc r23, r19
+  ; r23:r22=width of host widget
+  push yl
+    push yh
+      mov xl, yl
+      mov xh, yh
+      bigcall OBJ_GetFirstChild
+hLayoutVertically_loop:
+        brcc hLayoutVertically_loopEnd
+        mov yl, r18
+        mov yh, r19
+        
+        ldd r12, Y+WIDGET_OFFS_TMP_LO
+        ldd r13, Y+WIDGET_OFFS_TMP_HI
+        
+        ldd r17, Y+WIDGET_OFFS_PACK
+        andi r17, (1<<WIDGET_PACK_VSELF1_BIT) | (1<<WIDGET_PACK_VSELF0_BIT)
+        cpi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT)
+        brne hLayoutVertically_setHeight
+        mov r12, r22
+        mov r13, r23
+hLayoutVertically_setHeight:
+        std Y+WIDGET_OFFS_HEIGHT_LO, r12
+        std Y+WIDGET_OFFS_HEIGHT_HI, r13
+        push yl
+          push yh
+            mov yl, xl
+            mov yh, xh
+            rcall Widget_PackSelfY                ; R7:R6=new pos (r17, r18, r19, r20, r21)
+          pop yh
+        pop yl  
+        std Y+WIDGET_OFFS_Y_LO, r6
+        std Y+WIDGET_OFFS_Y_HI, r7
+        rcall OBJ_GetNext
+      rjmp hLayoutVertically_loop
+hLayoutVertically_loopEnd:
+    pop yh
+  pop yl
   ret
 ; @end
 
 
 
+; ---------------------------------------------------------------------------
+; @routine hLayoutHorizontally
+;
+; @param Y pointer to widget
+; @clobbers any, !Y
+
 hLayoutHorizontally:
+  ldd r16, Y+HLAYOUT_OFFS_MODE
+  cpi r16, HLAYOUT_MODE_SPREAD
+  breq hLayoutHorizontally_spread
+  rjmp hLayoutExpand
+hLayoutHorizontally_spread:
+  rjmp hLayoutSpread
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine hLayoutExpand
+;
+; @param Y pointer to widget
+; @clobbers any, !Y
+
+hLayoutExpand:
+  rcall Layout_SetDefaultWidths
+  rcall Layout_SumTmpValues         ; r19:r18=width+borders
+
+  ldd r22, Y+WIDGET_OFFS_WIDTH_LO
+  ldd r23, Y+WIDGET_OFFS_WIDTH_HI
+  sub r22, r18
+  sbc r23, r19                      ; r23:r22=(height-usedSpace)=unusedSpace
+  breq hLayoutExpand_setX           
+  brcs hLayoutExpand_setX
+
+  ; r23:r22=remaining space to distribute
+  push r22
+    push r23
+      ldi r22, (1<<WIDGET_PACK_HSELF1_BIT) | (1<<WIDGET_PACK_HSELF0_BIT) ; mask
+      ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT)              ; value
+      rcall LayoutCountChildrenWithPackMode                              ; r16=number of expandable child widgets
+    pop r23
+  pop r22
+  tst r16
+  breq hLayoutExpand_setX
+
+  ; calc space to add to each expandable child widget and add it
+  mov r20, r22
+  mov r21, r23
+  mov r22, r16
+  clr r23
+  bigcall Utils_Divu16_16_16 ; r17:r16=space per expandable child widget
+  mov r20, r16
+  mov r21, r17
+
+  ldi r22, (1<<WIDGET_PACK_HSELF1_BIT) | (1<<WIDGET_PACK_HSELF0_BIT) ; mask
+  ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT)              ; value
+  bigcall LayoutIncTmpOnMatchingPack
+
+hLayoutExpand_setX:
+  rcall hLayoutSetX
   ret
 ; @end
 
 
 
+; ---------------------------------------------------------------------------
+; @routine hLayoutExpand
+;
+; @param Y pointer to widget
+; @clobbers any, !Y
+
+hLayoutSpread:
+  rcall hLayoutPrepareSpread        ; (any, !Y)
+  rcall hLayoutFinalizeSpread       ; (r18, r19, X)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine hLayoutPrepareSpread
+;
+; @param Y pointer to widget
+; @return X startpos
+; @return r21:r20 extra space (in pixels)
+; @return r25:r24 spacing (including extra space)
+; @clobbers any, !Y
+
+hLayoutPrepareSpread:
+  rcall Layout_SetDefaultWidths                           ; (any, !Y)
+  rcall Layout_SumTmpValues                               ; r21:r20=width+borders
+
+  ldd r18, Y+WIDGET_OFFS_WIDTH_LO
+  ldd r19, Y+WIDGET_OFFS_WIDTH_HI
+  sub r18, r20
+  sbc r19, r21                                                       
+  mov r20, r18
+  mov r21, r19                                            ; remaining space
+  
+  rcall LayoutCountVisibleChildren                        ; r16=number of visible child widgets (r17, r18, r19)
+  inc r16
+  mov r22, r16
+  push r22
+    ldi r22, (1<<WIDGET_PACK_HSELF1_BIT) | \
+             (1<<WIDGET_PACK_HSELF0_BIT)                  ; mask
+    ldi r23, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) ; value
+    rcall LayoutCountChildrenWithPackMode                 ; r16=number of expandable children (r17, r18, r19)
+  pop r22
+  add r22, r16
+  clr r23
+  bigcall Utils_Divu16_16_16                              ; r17:r16=space per element
+  mov r20, r18
+  mov r21, r19                                            ; r21:20=additional space per element
+
+  ; get and adjust spacing, setup start pos
+  ldd zl, Y+WIDGET_OFFS_STYLE_LO
+  ldd zh, Y+WIDGET_OFFS_STYLE_HI
+  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
+  lpm xl, Z+                                              ; border
+  clr xh
+  lpm r24, Z                                              ; spacing
+  clr r25
+
+  add r24, r20                                            ; add extra space to spacing
+  adc r25, r21
+  
+  add xl, r20                                             ; add extra space to border
+  adc xh, r21
+
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine hLayoutFinalizeSpread
+;
+; @param Y pointer to widget
+; @param X startpos
+; @param r21:r20 extra space (in pixels)
+; @param r25:r24 spacing (including extra space)
+; @clobbers r18, r19, X
+
+hLayoutFinalizeSpread:
+  push yl
+    push yh
+      bigcall OBJ_GetFirstChild
+      brcc hLayoutFinalizeSpread_done
+hLayoutFinalizeSpread_loop:
+        mov yl, r18
+        mov yh, r19
+        ldd r17, Y+OBJECT_OFFS_FLAGS
+        sbrs r17, WIDGET_FLAGS_VISIBLE_BIT            ; skip invisible widgets
+          rjmp hLayoutFinalizeSpread_next
+        ; store pos
+        std Y+WIDGET_OFFS_X_LO, xl
+        std Y+WIDGET_OFFS_X_LO, xh
+        ; determine final height of child widget
+        ldd r18, Y+WIDGET_OFFS_TMP_LO
+        ldd r19, Y+WIDGET_OFFS_TMP_LO
+        ldd r16, Y+WIDGET_OFFS_PACK
+        andi r16, (1<<WIDGET_PACK_HSELF1_BIT) | (1<<WIDGET_PACK_HSELF0_BIT)
+        cpi r16, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT)
+        brne hLayoutFinalizeSpread_setWidth
+        add r18, r20                      ; add extra space
+        adc r19, r21
+hLayoutFinalizeSpread_setWidth:
+        std Y+WIDGET_OFFS_WIDTH_LO, r18
+        std Y+WIDGET_OFFS_WIDTH_HI, r19
+        ; advance pos
+        add xl, r18                       ; add width to current pos
+        adc xh, r19
+        add xl, r24                       ; add spacing to current pos
+        adc xh, r25
+hLayoutFinalizeSpread_next:
+        rcall OBJ_GetNext                 ; r19:r18=object (none)
+      brcs hLayoutFinalizeSpread_loop
+hLayoutFinalizeSpread_done:
+    pop yh
+  pop yl
+  ret
+; @end
+
+
+
+
 
 
 ; ***************************************************************************
diff --git a/avr/modules/lcd2/gui2/base/imageview.asm b/avr/modules/lcd2/gui2/base/imageview.asm
new file mode 100644
index 0000000..5e7987d
--- /dev/null
+++ b/avr/modules/lcd2/gui2/base/imageview.asm
@@ -0,0 +1,350 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+#ifndef AQH_AVR_GUI2_IMAGEVIEW_ASM
+#define AQH_AVR_GUI2_IMAGEVIEW_ASM
+
+
+; ***************************************************************************
+; defines
+
+.equ IMAGEVIEW_OFFS_BEGIN           =  WIDGET_SIZE
+.equ IMAGEVIEW_OFFS_RESSOURCEID_LO  =  IMAGEVIEW_OFFS_BEGIN+0
+.equ IMAGEVIEW_OFFS_RESSOURCEID_HI  =  IMAGEVIEW_OFFS_BEGIN+1
+.equ IMAGEVIEW_OFFS_BGCOLOR_LO      =  IMAGEVIEW_OFFS_BEGIN+2
+.equ IMAGEVIEW_OFFS_BGCOLOR_HI      =  IMAGEVIEW_OFFS_BEGIN+3
+.equ IMAGEVIEW_SIZE                 =  IMAGEVIEW_OFFS_BEGIN+4
+
+
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_new @global
+;
+; @return CFLAG set of okay, cleared otherwise
+; @return Y address of newly created object
+; @param X parent widget
+; @param r16 value for OBJECT_OFFS_OPTS
+; @param r17 value for WIDGET_OFFS_PACK
+; @param r21:r20 ressource id for image
+; @clobbers any
+
+ImageView_new:
+  ldi r24, LOW(IMAGEVIEW_SIZE)
+  ldi r25, HIGH(IMAGEVIEW_SIZE)
+  push r20
+    push r21
+      bigcall Object_Alloc           ; (!r16, !r17, !X)
+    pop r21
+  pop r20
+  brcc ImageView_new_ret
+  rcall ImageView_Init               ; (r16, r17, X)
+  sec
+ImageView_new_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_Init @global
+;
+; @param Y address of widget
+; @param X parent widget (if any)
+; @param r16 value for OBJECT_OFFS_OPTS
+; @param r17 value for WIDGET_OFFS_PACK
+; @param r21:r20 ressource id for image
+; @clobbers r16, r17, X
+
+ImageView_Init:
+  push r20
+    push r21
+      ; call base class
+      bigcall Widget_Init                       ; (r16, r17, X)
+    pop r21
+  pop r20
+  
+  ; setup label data
+  std Y+IMAGEVIEW_OFFS_RESSOURCEID_LO, r20
+  std Y+IMAGEVIEW_OFFS_RESSOURCEID_HI, r21
+  
+  ; set default signal map
+  ldi r16, LOW(ImageView_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
+  ldi r16, HIGH(ImageView_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16
+
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_SetRessourceId @global
+;
+; @param Y address of widget
+; @param X id of text ressource
+; @clobbers r16, r17, r18, r19
+
+ImageView_SetRessourceId:
+  std Y+IMAGEVIEW_OFFS_RESSOURCEID_LO, xl
+  std Y+IMAGEVIEW_OFFS_RESSOURCEID_HI, xh
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  std Y+OBJECT_OFFS_FLAGS, r16
+  ; force layout of this and all parent widgets
+  ldi r16, (1<<WIDGET_FLAGS_LAYOUT_BIT)
+  bigcall OBJ_AddFlagsUp                 ; (r17, r18, r19)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_SetBgCol @global
+;
+; @param Y address of widget
+; @param X color
+; @clobbers r16
+
+ImageView_SetBgCol:
+  std Y+IMAGEVIEW_OFFS_BGCOLOR_LO, xl
+  std Y+IMAGEVIEW_OFFS_BGCOLOR_HI, xh
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  ori r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  std Y+OBJECT_OFFS_FLAGS, r16
+  ret
+; @end
+
+
+
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_OnDraw @global
+;
+; @param Y address of widget
+; @clobbers any, !Y
+
+ImageView_OnDraw:
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  andi r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  breq ImageView_OnDraw_ret
+
+;  bigcall Widget_Clear
+  rcall imageViewDraw
+  
+  ldd r16, Y+OBJECT_OFFS_OPTS
+  andi r16, (1<<WIDGET_OPTS_BORDER_BIT)
+  breq ImageView_OnDraw_done
+  bigcall Widget_DrawBorder
+
+ImageView_OnDraw_done:
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  cbr r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  std Y+OBJECT_OFFS_FLAGS, r16
+
+ImageView_OnDraw_ret:
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_OnGetDefaultWidth @global
+;
+; @param Y address of widget
+; @param r17 value requested
+; @param xl param1
+; @param xh param2
+; @return CFLAG set if signal handled
+; @return r19:r18 value
+; @clobbers any, !Y
+
+ImageView_OnGetDefaultWidth:
+  rcall imageViewGetRessource
+  brcs ImageView_OnGetDefaultWidth_getImageWidth
+  ldi r18, 1
+  clr r19
+  rjmp ImageView_OnGetDefaultWidth_addBorders
+ImageView_OnGetDefaultWidth_getImageWidth:
+  rcall imageViewGetImageWidth
+  mov r18, r12
+  mov r19, r13
+ImageView_OnGetDefaultWidth_addBorders:
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_OnGetDefaultHeight @global
+;
+; @param Y address of widget
+; @param xl param1
+; @param xh param2
+; @return CFLAG set if signal handled
+; @return r19:r18 value
+; @clobbers any, !Y
+
+ImageView_OnGetDefaultHeight:
+  rcall imageViewGetRessource
+  brcs ImageView_OnGetDefaultHeight_getImageHeight
+  ldi r18, 1
+  clr r19
+  rjmp ImageView_OnGetDefaultHeight_addBorders
+ImageView_OnGetDefaultHeight_getImageHeight:
+  rcall imageViewGetImageHeight
+  mov r18, r12
+  mov r19, r13
+ImageView_OnGetDefaultHeight_addBorders:
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ImageView_OnDraw @global
+;
+; @param Y address of widget
+; @clobbers any, !Y
+
+imageViewDraw:
+  rcall imageViewGetRessource
+  brcc imageViewDraw_ret
+  rcall imageViewAlignContentXY ; (r17, r18, r19, r20, r21, Z)
+  ldd r0, Y+IMAGEVIEW_OFFS_BGCOLOR_LO
+  ldd r1, Y+IMAGEVIEW_OFFS_BGCOLOR_LO
+  ; select background color
+  mov r16, r0
+  or r16, r1
+  breq imageViewDraw_useStyleColors
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  sbrc r16, WIDGET_FLAGS_ACTIVATED_BIT
+    rjmp imageViewDraw_useStyleColors
+  rjmp imageViewDraw_draw
+imageViewDraw_useStyleColors:
+  bigcall Widget_SelectColors           ; (R16)
+imageViewDraw_draw:
+  bigcall Widget_DrawImage
+imageViewDraw_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine imageViewGetRessource
+;
+; @param  Y     address of widget
+; @return CFLAG set if ressource found, cleared on error
+; @return Z     pointer to ressource
+
+imageViewGetRessource:
+  ldd r16, Y+IMAGEVIEW_OFFS_RESSOURCEID_LO
+  ldd r17, Y+IMAGEVIEW_OFFS_RESSOURCEID_HI
+  ldi zl, LOW(RESSOURCE_ADDR*2)
+  ldi zh, HIGH(RESSOURCE_ADDR*2)
+  bigcall RES_GetRessource            ; (r16, r17, r18)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine imageViewAlignContentXY
+;
+; @param  Y       address of widget
+; @param  Z       byte address pointer to image (for LPM!)
+; @return R5:R4   X
+; @return R7:R6   Y
+; @clobbers r17, r18, r19, r20, r21, Z
+
+imageViewAlignContentXY:
+  rcall imageViewGetImageWidth  ; R13:R12=width (r16, r17, r18, Z)
+  rcall Widget_PackContentX     ; R5:R4=X (r17, r18, r19, r20, r21)
+
+  rcall imageViewGetImageHeight ; R13:R12=height (r16, r17, r18, Z)
+  rcall Widget_PackContentY     ; R7:R6=Y (r17, r18, r19, r20, r21)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine imageViewGetImageWidth
+;
+; @param Y address of widget
+; @return Z byte address pointer to text in FLASH
+; @return r13:r12 image width
+; @clobbers r16, r17, r18, Z
+
+imageViewGetImageWidth:
+  adiw zh:zl, RES_IMAGE_OFFS_WIDTH_LO
+  lpm r12, Z+
+  lpm r13, Z
+  sbiw zh:zl, (RES_IMAGE_OFFS_WIDTH_LO+1)
+  sec
+imageViewGetImageWidth_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine imageViewGetImageHeight
+;
+; @param Y address of widget
+; @param Z byte address pointer to image ressource
+; @return r13:r12 image height
+; @clobbers r16, r17, r18
+
+imageViewGetImageHeight:
+  adiw zh:zl, RES_IMAGE_OFFS_HEIGHT_LO
+  lpm r12, Z+
+  lpm r13, Z
+  sbiw zh:zl, (RES_IMAGE_OFFS_HEIGHT_LO+1)
+  sec
+imageViewGetImageHeight_ret:
+  ret
+; @end
+
+
+
+
+
+; ***************************************************************************
+; data in FLASH
+
+ImageView_DefaultSignalmap:
+  ; header
+  .dw Widget_DefaultSignalmap*2  ; next table to use
+  ; entries
+  .db 0,                           WIDGET_SIGNAL_DRAW,     LOW(ImageView_OnDraw),             HIGH(ImageView_OnDraw)
+  .db WIDGET_VALUE_DEFAULT_WIDTH,  WIDGET_SIGNAL_GETVALUE, LOW(ImageView_OnGetDefaultWidth),  HIGH(ImageView_OnGetDefaultWidth)
+  .db WIDGET_VALUE_DEFAULT_HEIGHT, WIDGET_SIGNAL_GETVALUE, LOW(ImageView_OnGetDefaultHeight), HIGH(ImageView_OnGetDefaultHeight)
+
+  .db 0, 0, 0, 0  ; end of table
+
+
+#endif
+
diff --git a/avr/modules/lcd2/gui2/base/label.asm b/avr/modules/lcd2/gui2/base/label.asm
index cb86bb5..ce4b485 100644
--- a/avr/modules/lcd2/gui2/base/label.asm
+++ b/avr/modules/lcd2/gui2/base/label.asm
@@ -161,17 +161,7 @@ Label_OnGetDefaultWidth:
   rcall labelCalcTextWidth
   mov r18, r12
   mov r19, r13
-
-  ; add borders
-  ldd zl, Y+WIDGET_OFFS_STYLE_LO
-  ldd zh, Y+WIDGET_OFFS_STYLE_HI
-  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
-  lpm r20, Z
-  clr r21
-  add r18, r20                   ; add border at begin
-  adc r19, r21
-  add r18, r20                   ; add border at end
-  adc r19, r21
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
   sec
   ret
 ; @end
@@ -192,17 +182,7 @@ Label_OnGetDefaultHeight:
   rcall Widget_GetCharHeight    ; R16=char height
   mov r18, r16
   clr r19
-
-  ; add borders
-  ldd zl, Y+WIDGET_OFFS_STYLE_LO
-  ldd zh, Y+WIDGET_OFFS_STYLE_HI
-  adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
-  lpm r20, Z
-  clr r21
-  add r18, r20                   ; add border at begin
-  adc r19, r21
-  add r18, r20                   ; add border at end
-  adc r19, r21
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
   sec
   ret
 ; @end
diff --git a/avr/modules/lcd2/gui2/base/rootwindow.asm b/avr/modules/lcd2/gui2/base/rootwindow.asm
index ed9fa90..6b448d0 100644
--- a/avr/modules/lcd2/gui2/base/rootwindow.asm
+++ b/avr/modules/lcd2/gui2/base/rootwindow.asm
@@ -130,7 +130,7 @@ RootWindow_OnLayout_loop:
         mov yh, r19
         ; all children are MainWindow, set to fullscreen
         bigcall Widget_SetFullScreen    ; (R16)
-        rcall OBJ_GetNext
+        bigcall OBJ_GetNext
       brcs RootWindow_OnLayout_loop
 RootWindow_OnLayout_done:
     pop yh
diff --git a/avr/modules/lcd2/gui2/base/valuelabel.asm b/avr/modules/lcd2/gui2/base/valuelabel.asm
new file mode 100644
index 0000000..50c03ae
--- /dev/null
+++ b/avr/modules/lcd2/gui2/base/valuelabel.asm
@@ -0,0 +1,263 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+#ifndef AQH_AVR_GUI2_VALUELABEL_ASM
+#define AQH_AVR_GUI2_VALUELABEL_ASM
+
+
+; ***************************************************************************
+; defines
+
+.equ VLABEL_OFFS_BEGIN           =  WIDGET_SIZE
+.equ VLABEL_OFFS_VALUE_LO        =  VLABEL_OFFS_BEGIN+0
+.equ VLABEL_OFFS_VALUE_HI        =  VLABEL_OFFS_BEGIN+1
+.equ VLABEL_OFFS_POSTKOMMADIGITS =  VLABEL_OFFS_BEGIN+2
+.equ VLABEL_SIZE                 =  VLABEL_OFFS_BEGIN+3
+
+
+.equ VLABEL_VALUE          = WIDGET_VALUE_NEXTFREE+0
+.equ VLABEL_VALUE_NEXTFREE = VLABEL_VALUE+1
+
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_new @global
+;
+; @return CFLAG set of okay, cleared otherwise
+; @return Y address of newly created object
+; @param X parent widget
+; @param r16 value for OBJECT_OFFS_OPTS
+; @param r17 value for WIDGET_OFFS_PACK
+; @param r20 number of postkomma digits
+; @clobbers any
+
+ValueLabel_new:
+  push r20
+    ldi r24, LOW(VLABEL_SIZE)
+    ldi r25, HIGH(VLABEL_SIZE)
+    bigcall Object_Alloc           ; (!r16, !r17, !X)
+  pop r20
+  brcc ValueLabel_new_ret
+  rcall ValueLabel_Init               ; (r16, r17, X)
+  sec
+ValueLabel_new_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_Init @global
+;
+; @param Y address of widget
+; @param X parent widget (if any)
+; @param r16 value for OBJECT_OFFS_OPTS
+; @param r17 value for WIDGET_OFFS_PACK
+; @param r20 number of postkomma digits
+; @clobbers r16, r17, X
+
+ValueLabel_Init:
+  push r20
+    ; call base class
+    bigcall Widget_Init                       ; (r16, r17, X)
+  pop r20
+
+  ; setup valueLabel data
+  std Y+VLABEL_OFFS_POSTKOMMADIGITS, r20
+  
+  ; set default signal map
+  ldi r16, LOW(ValueLabel_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
+  ldi r16, HIGH(ValueLabel_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16
+
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_OnSetValue @global
+;
+; @param Y address of widget
+; @return CFLAG set if signal handled
+; @clobbers r17
+
+ValueLabel_OnSetValue:
+  std Y+VLABEL_OFFS_VALUE_LO, xl
+  std Y+VLABEL_OFFS_VALUE_HI, xh
+  
+  ldd r17, Y+OBJECT_OFFS_FLAGS
+  ori r17, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  std Y+OBJECT_OFFS_FLAGS, r17
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_OnDraw @global
+;
+; @param Y address of widget
+; @param xl param1
+; @param xh param2
+; @clobbers any, !Y
+
+ValueLabel_OnDraw:
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  andi r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  breq ValueLabel_OnDraw_ret
+
+  bigcall Widget_Clear
+  rcall valueLabelWriteValue
+  
+  ldd r16, Y+OBJECT_OFFS_OPTS
+  andi r16, (1<<WIDGET_OPTS_BORDER_BIT)
+  breq ValueLabel_OnDraw_done
+  bigcall Widget_DrawBorder
+
+ValueLabel_OnDraw_done:
+  ldd r16, Y+OBJECT_OFFS_FLAGS
+  cbr r16, (1<<WIDGET_FLAGS_DIRTY_BIT)
+  std Y+OBJECT_OFFS_FLAGS, r16
+
+ValueLabel_OnDraw_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_OnGetDefaultWidth @global
+;
+; @param Y address of widget
+; @param r17 value requested
+; @param xl param1
+; @param xh param2
+; @return CFLAG set if signal handled
+; @return r19:r18 value
+; @clobbers any, !Y
+
+ValueLabel_OnGetDefaultWidth:
+  rcall labelCalcTextWidth
+  mov r18, r12
+  mov r19, r13
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ValueLabel_OnGetDefaultHeight @global
+;
+; @param Y address of widget
+; @param xl param1
+; @param xh param2
+; @return CFLAG set if signal handled
+; @return r19:r18 value
+; @clobbers any, !Y
+
+ValueLabel_OnGetDefaultHeight:
+  rcall Widget_GetCharHeight    ; R16=char height
+  mov r18, r16
+  clr r19
+  bigcall Widget_AddOuterStyleBorders  ; (r20, r21)
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine valueLabelWriteValue
+;
+; @param Y address of widget
+; @clobbers any, !Y
+
+valueLabelWriteValue:
+  rcall valueLabelAlignTextXY  ; X=ptr to text (r8, r9, r10, r11, r12, r13, r14, r15, r16, r17, r18, r19)
+  bigcall Widget_DrawTextRam   ; (any, !Y)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine valueLabelAlignTextXY
+;
+; @param  Y       address of widget
+; @param  R13:R12 width of object to align
+; @return R5:R4   X
+; @return R7:R6   Y
+; @return X pointer to text in SDRAM
+; @clobbers r8, r9, r10, r11, r12, r13, r14, r15, r16, r17, r18, r19, r20, r21, r22, r23, r24, r25
+
+valueLabelAlignTextXY:
+  rcall valueLabelCalcTextWidth   ; X=ptr to text in SDRAM, R13:R12=text width (r16, r17, r18)
+  rcall Widget_PackContentX       ; R5:R4=X (r17, r18, r19, r20, r21)
+
+  rcall Widget_GetCharHeight      ; R16=char height
+  mov r12, r16
+  clr r13
+  rcall Widget_PackContentY       ; R7:R6=Y (r17, r18, r19, r20, r21)
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine valueLabelCalcTextWidth
+;
+; @param  Y       address of widget
+; @return X       pointer to text in SDRAM
+; @return r13:r12 width of string
+; @clobbers r16, r17, r18
+
+valueLabelCalcTextWidth:
+  ldd r20, Y+VLABEL_OFFS_VALUE_LO
+  ldd r21, Y+VLABEL_OFFS_VALUE_HI
+  ldd r24, Y+VLABEL_OFFS_POSTKOMMADIGITS
+  bigcall IntToAscii                        ; X=pointer to text
+  rcall Widget_GetCharWidth                 ; R16=char width
+  mov r18, r16
+  bigcall Widget_CalcStringWidthSDRAM       ; r13:r12=size (r16)
+  sec
+valueLabelCalcTextWidth_ret:
+  ret
+; @end
+
+
+
+; ***************************************************************************
+; data in FLASH
+
+ValueLabel_DefaultSignalmap:
+  ; header
+  .dw Widget_DefaultSignalmap*2  ; next table to use
+  ; entries
+  .db 0,                           WIDGET_SIGNAL_DRAW,     LOW(ValueLabel_OnDraw),             HIGH(ValueLabel_OnDraw)
+  .db VLABEL_VALUE,                WIDGET_SIGNAL_SETVALUE, LOW(ValueLabel_OnSetValue),         HIGH(ValueLabel_OnSetValue)
+  .db WIDGET_VALUE_DEFAULT_WIDTH,  WIDGET_SIGNAL_GETVALUE, LOW(ValueLabel_OnGetDefaultWidth),  HIGH(ValueLabel_OnGetDefaultWidth)
+  .db WIDGET_VALUE_DEFAULT_HEIGHT, WIDGET_SIGNAL_GETVALUE, LOW(ValueLabel_OnGetDefaultHeight), HIGH(ValueLabel_OnGetDefaultHeight)
+
+  .db 0, 0, 0, 0  ; end of table
+
+
+#endif
+
diff --git a/avr/modules/lcd2/gui2/base/widget.asm b/avr/modules/lcd2/gui2/base/widget.asm
index e457cf0..93870b9 100644
--- a/avr/modules/lcd2/gui2/base/widget.asm
+++ b/avr/modules/lcd2/gui2/base/widget.asm
@@ -462,6 +462,32 @@ Widget_UngrabTouchEvents:
 
 
 
+; ---------------------------------------------------------------------------
+; @routine Widget_AddOuterStyleBorders @global
+;
+; @param  Y       address of object
+; @param  r19:r18  value to add the border sizes to
+; @return r19:r18  value with added border sizes
+; @clobbers r20, r21
+
+Widget_AddOuterStyleBorders:
+  push zl
+    push zh
+      ; add borders
+      ldd zl, Y+WIDGET_OFFS_STYLE_LO
+      ldd zh, Y+WIDGET_OFFS_STYLE_HI
+      adiw zh:zl, WIDGET_STYLE_OFFS_OUTERBORDERSIZE
+      lpm r20, Z
+      clr r21
+      add r18, r20                   ; add border at begin
+      adc r19, r21
+      add r18, r20                   ; add border at end
+      adc r19, r21
+    pop zh
+  pop zl
+  ret
+; @end
+
 
 
 
@@ -989,6 +1015,35 @@ Widget_CalcStringWidthFLASH_done:
 
 
 
+; ---------------------------------------------------------------------------
+; @routine Widget_CalcStringWidthSDRAM
+;
+; @param  X       pointer to text in SDRAM
+; @param  R18     char width in px
+; @return r13:r12 width of string
+; @clobbers r16
+
+Widget_CalcStringWidthSDRAM:
+  clr r12
+  clr r13
+  push xl
+    push xh
+Widget_CalcStringWidthSDRAM_loop:
+        ld r16, X+
+        tst r16
+        breq Widget_CalcStringWidthSDRAM_done
+        add r12, r18
+        adc r13, r18
+        sub r13, r18
+      rjmp Widget_CalcStringWidthSDRAM_loop
+Widget_CalcStringWidthSDRAM_done:
+    pop xh
+  pop xl
+  ret
+; @end
+
+
+
 ; ---------------------------------------------------------------------------
 ; @routine Widget_PackSelfX @global
 ;