avr: introduced network module

this will be the base module for network modules.

avr/modules/network/buffer.asm

@@ -0,0 +1,125 @@
+; ***************************************************************************
+; copyright   : (C) 2025 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+
+; ===========================================================================
+; defs
+
+.equ NET_BUFFER_INUSE_BIT          = 7
+.equ NET_BUFFER_IFACENUM1_BIT      = 1
+.equ NET_BUFFER_IFACENUM0_BIT      = 0
+
+
+
+
+; ===========================================================================
+; code segment
+
+.cseg
+
+; ---------------------------------------------------------------------------
+; @routine NET_Buffer_Init @global
+;
+; @clobbers R16, R17, X
+
+NET_Buffer_Init:
+  ldi xl, LOW(netBuffers)
+  ldi xh, HIGH(netBuffers)
+  m_fixedbuf_init NET_BUFFERS_SIZE, NET_BUFFERS_NUM
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine NET_Buffer_Alloc @global
+;
+; @return CFLAG set if buffer available, cleared otherwise
+; @return r16 buffer num
+; @return X pointer to start of buffer
+; @clobbers R16, R17, X
+
+NET_Buffer_Alloc:
+  ldi xl, LOW(netBuffers)
+  ldi xh, HIGH(netBuffers)
+  m_fixedbuf_reserve NET_BUFFERS_SIZE, NET_BUFFERS_NUM
+  brcc NET_Buffer_Alloc_end
+  ldi r17, (1<<NET_BUFFER_INUSE_BIT)
+  st X, r17
+NET_Buffer_Alloc_end:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine NET_Buffer_ReleaseByAddr @global
+;
+; @param X pointer to start of buffer
+; @clobbers R16
+
+NET_Buffer_ReleaseByAddr:
+  m_fixedbuf_release
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine NET_Buffer_ReleaseByNum @global
+;
+; @param r16 buffer number
+; @clobbers X (R16)
+
+NET_Buffer_ReleaseByNum:
+  rcall NET_Buffer_Locate          ; (R16)
+  brcc NET_Buffer_ReleaseByNum_end
+  rcall NET_Buffer_ReleaseByAddr   ; (R16)
+NET_Buffer_ReleaseByNum_end:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine NET_Buffer_Locate
+;
+; Get position of a given buffer.
+;
+; CAVE: need to change this routine if UART_HW_FIXEDBUFFERS_SIZE is changed!
+;
+; @return CFLAG set if okay, cleared on error
+; @return X points to start of buffer with the given num
+; @param r16 buffer num (0-max)
+; @clobbers r16
+
+NET_Buffer_Locate:
+  cpi r16, NET_BUFFERS_NUM
+  brcc NET_Buffer_Locate_end ; out of range
+  mov xh, r16  ; * 256
+  clr xl
+  lsr xh       ; *128
+  ror xl
+  lsr xh       ; *64
+  ror xl
+  lsr xh       ; *32
+  ror xl
+  ldi r16, LOW(netBuffers)
+  add xl, r16
+  ldi r16, HIGH(netBuffers)
+  adc xh, r16
+  sec
+NET_Buffer_Locate_end:
+  ret
+; @end
+
+
+
+
+