gui2: more work on gui.

avr/modules/lcd2/gui2/base/guiapp.asm

@@ -25,11 +25,21 @@
 .equ GUIAPP_OFFS_CURRENTWINDOW_HI      =  GUIAPP_OFFS_BEGIN+5
 .equ GUIAPP_OFFS_TOUCHWIDGET_LO        =  GUIAPP_OFFS_BEGIN+6
 .equ GUIAPP_OFFS_TOUCHWIDGET_HI        =  GUIAPP_OFFS_BEGIN+7
-.equ GUIAPP_OFFS_DRAWTIMER             =  GUIAPP_OFFS_BEGIN+8
+.equ GUIAPP_OFFS_GUITIMER              =  GUIAPP_OFFS_BEGIN+8
 .equ GUIAPP_SIZE                       =  WIDGET_OFFS_BEGIN+9
 
 
-.equ GUIAPP_DRAWTIMER = 2
+.equ GUIAPP_GUITIMER = 2
+
+
+
+; ***************************************************************************
+; data
+
+.dseg
+
+guiapp_touch_event:
+  .byte WIDGET_TOUCH_SIZE
 
 
 
@@ -105,8 +115,8 @@ GuiApp_Init:
   std Y+GUIAPP_OFFS_ROOTWINDOW_LO, xl
   std Y+GUIAPP_OFFS_ROOTWINDOW_HI, xh
 
-  ldi r16, GUIAPP_DRAWTIMER
-  std Y+GUIAPP_OFFS_DRAWTIMER, r16
+  ldi r16, GUIAPP_GUITIMER
+  std Y+GUIAPP_OFFS_GUITIMER, r16
 
 GuiApp_Init_ret:
   ret
@@ -353,8 +363,13 @@ GuiApp_OnDestroy:
 ; @routine GuiApp_OnTimer
 ;
 ; @param Y address of object in SDRAM
+; @clobbers any, !Y
 
 GuiApp_OnTimer:
+  rcall guiAppCheckTouch          ; (any, !Y)
+  rcall guiAppSendTimerEvents     ; (any, !Y)
+  rcall guiAppCheckSendGuiEvents  ; (any, !Y)
+  sec
   ret
 ; @end
 
@@ -372,6 +387,165 @@ GuiApp_OnMsgReceived:
 
 
 
+; ---------------------------------------------------------------------------
+; @routine GuiApp_OnTouch
+;
+; @param Y address of object in SDRAM
+; @clobbers any, !Y
+
+GuiApp_OnTouch:
+  rcall guiAppSendTouchEvents
+  ret
+; @end
+
+
+
+
+; ---------------------------------------------------------------------------
+; @routine guiAppSendTimerEvents
+;
+; @param Y ptr to GUIAPP
+; @clobbers any, !Y
+
+guiAppSendTimerEvents:
+  push yl
+    push yh
+      ldd r16, Y+GUIAPP_OFFS_ROOTWINDOW_LO
+      ldd yh, Y+GUIAPP_OFFS_ROOTWINDOW_HI
+      mov yl, r16
+      or yl, yh
+      breq guiAppSendTimerEvents_done
+      ldi r16, OBJECT_SIGNAL_TIMER
+      clr r17
+      ldi r20, OBJECT_OPTSLO_TIMER_BIT
+      mov r21, r20
+      bigcall OBJ_TreeHandleSignalIfMatchingOptsLo
+guiAppSendTimerEvents_done:
+    pop yh
+  pop yl
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine guiAppCheckSendGuiEvents
+;
+; Send GUI events to current window if timer elapsed.
+;
+; @param Y ptr to GUIAPP
+; @clobbers any, !Y
+
+guiAppCheckSendGuiEvents:
+  push yl
+    push yh
+      ldd r16, Y+GUIAPP_OFFS_CURRENTWINDOW_LO
+      ldd yh, Y+GUIAPP_OFFS_CURRENTWINDOW_HI
+      mov yl, r16
+      or yl, yh
+      breq guiAppCheckSendGuiEvents_done
+
+      ldd r16, Y+GUIAPP_OFFS_GUITIMER
+      tst r16
+      breq guiAppCheckSendGuiEvents_done
+      dec r16
+      std Y+GUIAPP_OFFS_GUITIMER, r16
+      brne guiAppCheckSendGuiEvents_done
+      
+      ; timer elapsed, send layout events, draw events
+      ldi r16, WIDGET_SIGNAL_LAYOUT
+      clr r17
+      ldi r20, (1<<WIDGET_FLAGS_VISIBLE_BIT) | (1<<WIDGET_FLAGS_LAYOUT_BIT)
+      bigcall OBJ_TreeHandleSignalIfFlagsSet  ; (any, !Y)
+
+      ldi r16, WIDGET_SIGNAL_DRAW
+      clr r17
+      ldi r20, (1<<WIDGET_FLAGS_VISIBLE_BIT) | (1<<WIDGET_FLAGS_DIRTY_BIT)
+      bigcall OBJ_TreeHandleSignalIfFlagsSet  ; (any, !Y)
+      
+      ldi r16, GUIAPP_GUITIMER
+      std Y+GUIAPP_OFFS_GUITIMER, r16
+      
+guiAppCheckSendGuiEvents_done:
+    pop yh
+  pop yl  
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine guiAppSendTouchEvents
+;
+; Send touch events to current window or grabbing widget.
+;
+; @param Y ptr to GUIAPP
+; @clobbers any, !Y
+
+guiAppSendTouchEvents:
+  push yl
+    push yh
+      ldd r18, Y+GUIAPP_OFFS_TOUCHWIDGET_LO
+      ldd r19, Y+GUIAPP_OFFS_TOUCHWIDGET_HI
+      mov r16, r18
+      or r16, r19
+      breq GuiApp_OnTouch_sendToAll
+      mov yl, r18
+      mov yh, r19
+      ldi r16, WIDGET_SIGNAL_TOUCH
+      clr r17
+      bigcall OBJ_HandleSignal
+      rjmp GuiApp_OnTouch_done
+GuiApp_OnTouch_sendToAll:
+      ldd r18, Y+GUIAPP_OFFS_CURRENTWINDOW_LO
+      ldd r19, Y+GUIAPP_OFFS_CURRENTWINDOW_HI
+      mov r16, r18
+      or r16, r19
+      breq GuiApp_OnTouch_done
+      ; send touch signal
+      ldi r16, WIDGET_SIGNAL_TOUCH
+      clr r17
+      ldi r20, (1<<WIDGET_OPTSLO_INPUT_BIT)
+      ldi r21, (1<<WIDGET_OPTSLO_INPUT_BIT)
+      bigcall OBJ_TreeHandleSignalIfMatchingOptsLo
+GuiApp_OnTouch_done:
+    pop yh
+  pop yl
+  ; send keepAlive to screensaver
+  rcall GuiApp_PreventScreenSaver
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine guiAppCheckTouch
+;
+; @param Y ptr to GUIAPP
+; @clobbers any, !Y
+
+guiAppCheckTouch:
+  bigcall Display_InputGetState    ; r16=flags, r5:r4=x, r7:r6=y
+  mov r17, r16
+  andi r17, (1<<DISPLAY_IFLAGS_CHGCOORD_BIT) | (1<<DISPLAY_IFLAGS_CHGPRESS_BIT)
+  breq guiAppCheckTouch_ret
+  ldi xl, LOW(guiapp_touch_event)
+  ldi xh, HIGH(guiapp_touch_event)
+  st X+, r4  ; X
+  st X+, r5
+  st X+, r6  ; Y
+  st X+, r7
+  st X, r16  ; flags
+  sbiw xh:xl, 4 ; (4 times incremented)
+  ; send touch signal
+  ldi r16, WIDGET_SIGNAL_TOUCH
+  clr r17
+  bigcall OBJ_HandleSignal
+guiAppCheckTouch_ret:
+  ret
+; @end
+