From 393df322f043ee0529fbc1288189782834212d1a Mon Sep 17 00:00:00 2001
From: Martin Preuss <martin@aquamaniac.de>
Date: Sun, 15 Mar 2026 20:20:06 +0100
Subject: [PATCH] avr: added rtc module for ds3231

---
 avr/modules/0BUILD              |   1 +
 avr/modules/rtc/0BUILD          |  10 ++
 avr/modules/rtc/ds3231/0BUILD   |  13 ++
 avr/modules/rtc/ds3231/main.asm | 226 ++++++++++++++++++++++++++++++++
 avr/modules/rtc/ds3231/recv.asm |  57 ++++++++
 avr/modules/rtc/ds3231/send.asm | 113 ++++++++++++++++
 6 files changed, 420 insertions(+)
 create mode 100644 avr/modules/rtc/0BUILD
 create mode 100644 avr/modules/rtc/ds3231/0BUILD
 create mode 100644 avr/modules/rtc/ds3231/main.asm
 create mode 100644 avr/modules/rtc/ds3231/recv.asm
 create mode 100644 avr/modules/rtc/ds3231/send.asm

diff --git a/avr/modules/0BUILD b/avr/modules/0BUILD
index 4cfef6f..8fe82d9 100644
--- a/avr/modules/0BUILD
+++ b/avr/modules/0BUILD
@@ -42,6 +42,7 @@
     xram
     heap
     brightness
+    rtc
   </subdirs>
 
 </gwbuild>
diff --git a/avr/modules/rtc/0BUILD b/avr/modules/rtc/0BUILD
new file mode 100644
index 0000000..8a211af
--- /dev/null
+++ b/avr/modules/rtc/0BUILD
@@ -0,0 +1,10 @@
+<?xml?>
+
+<gwbuild>
+
+  <subdirs>
+    ds3231
+  </subdirs>
+
+</gwbuild>
+
diff --git a/avr/modules/rtc/ds3231/0BUILD b/avr/modules/rtc/ds3231/0BUILD
new file mode 100644
index 0000000..c7ca6fd
--- /dev/null
+++ b/avr/modules/rtc/ds3231/0BUILD
@@ -0,0 +1,13 @@
+<?xml?>
+
+<gwbuild>
+
+  <extradist>
+    main.asm
+    recv.asm
+    send.asm
+  </extradist>
+
+</gwbuild>
+
+
diff --git a/avr/modules/rtc/ds3231/main.asm b/avr/modules/rtc/ds3231/main.asm
new file mode 100644
index 0000000..9400bfe
--- /dev/null
+++ b/avr/modules/rtc/ds3231/main.asm
@@ -0,0 +1,226 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+
+
+; ***************************************************************************
+; defs
+
+.equ DS3231_FLAGS_PRESENT_BIT = 7
+.equ DS3231_FLAGS_VALID_BIT   = 6
+
+
+
+
+
+; ***************************************************************************
+; data
+
+.dseg
+
+ds3231DataBegin:
+  ds3231Flags:      .byte 1
+  ds3231RecvBuffer: .byte 7
+ds3231DataEnd:
+
+
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+
+
+; ---------------------------------------------------------------------------
+; @routine Ds3231_Init @global
+;
+; @return CFLAG set if okay, cleared on error
+; @clobbers
+
+Ds3231_Init:
+  ldi xh, HIGH(ds3231DataBegin)
+  ldi xl, LOW(ds3231DataBegin)
+  clr r16
+  ldi r17, (ds3231DataEnd-ds3231DataBegin)
+  rcall Utils_FillSram
+
+  rcall ds3231CheckPresence
+  brcc Ds3231_Init_ret
+  ldi r16, (1<<DS3231_FLAGS_PRESENT_BIT)
+  sts ds3231Flags, r16
+  sec
+Ds3231_Init_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine Ds3231_Fini @global
+;
+; @return CFLAG set if okay, cleared on error
+; @clobbers none
+
+Ds3231_Fini:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine Ds3231_Fini @global
+;
+; @return CFLAG set if okay, cleared on error
+; @clobbers
+
+Ds3231_OnEveryMinute:
+  push r15
+    in r15, SREG
+    cli
+
+    lds r16, ds3231Flags
+    sbrs r16, DS3231_FLAGS_PRESENT_BIT
+      rjmp Ds3231_OnEveryMinute_ret
+    ; clear valid bit
+    cbr r16, (1<<DS3231_FLAGS_VALID_BIT)
+    sts ds3231Flags, r16
+    ; read time from clock
+    ldi xl, LOW(ds3231RecvBuffer)
+    ldi xh, HIGH(ds3231RecvBuffer)
+    clr r16
+    ldi r17, 7
+    rcall ds3231ReadData
+    brcc Ds3231_OnEveryMinute_ret
+    ; set valid bit
+    lds r16, ds3231Flags
+    sbr r16, (1<<DS3231_FLAGS_VALID_BIT)
+    sts ds3231Flags, r16
+#ifdef MODULES_NETWORK
+;    rcall ds3231SendDebug
+    rcall Ds3231_AnnounceTime
+#endif  
+Ds3231_OnEveryMinute_ret:
+    out SREG, r15
+  pop r15
+
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ds3231CheckPresence
+;
+; Expects interrupts being disabled!
+;
+; @return CFLAG set if okay, clear on error
+; @clobbers R16 (R17, R18, R22)
+
+ds3231CheckPresence:
+  ldi r16, (DS3231_ADDR*2)   ; write access
+  rjmp twiCheckPresence      ; (R16, R17, R18, R22)
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ds3231ReadData
+;
+; @param r16 start address
+; @param r17 number of bytes to read
+; @param X pointer to buffer to receive data
+; @return CFLAG set if okay, cleared on error
+; @return r16 number of bytes received if CFLAG set
+; @clobbers r16, r17, r18, r19, r20, r22, X
+
+ds3231ReadData:
+  mov r20, r16
+  mov r19, r17
+  rcall twiStart                         ; (R22)
+  ldi r16, (DS3231_ADDR*2)               ; write access
+  rcall twiSendByteExpectAck             ; (R16, R17, R18, R22)
+  brcc ds3231ReadData_error
+  mov r16, r20
+  rcall twiSendByteExpectAck
+  brcc ds3231ReadData_error
+  rcall twiRestart                       ; (R22)
+  ldi r16, (DS3231_ADDR*2)+1             ; read access
+  rcall twiSendByteExpectAck
+  brcc ds3231ReadData_error
+
+  clr r20
+ds3231ReadData_loop1:
+    cpi r19, 1
+    breq ds3231ReadData_recvLast
+    rcall twiReceiveByteSendAck            ; (R16, R17, R18, R22)
+    rjmp ds3231ReadData_recvd
+ds3231ReadData_recvLast:
+    rcall twiReceiveByte                   ; don't send ACK (R16, R17, R18, R22)
+ds3231ReadData_recvd:
+    brcc ds3231ReadData_error
+    st X+, r16
+    inc r20
+    dec r19
+  brne ds3231ReadData_loop1
+  rcall twiStop                          ; (R22)
+  mov r16, r20
+  sec
+  ret
+ds3231ReadData_error:
+  rcall twiStop                          ; (R22)
+  clc
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ds3231SendData
+;
+; @param r16 start address
+; @param r17 number of bytes to read
+; @param Z   pointer to buffer to send
+; @return    CFLAG set if okay, cleared on error
+; @return    r16 number of bytes received if CFLAG set
+; @clobbers r16, r17, r18, r19, r20, r22, Z
+
+ds3231SendData:
+  mov r20, r16
+  mov r19, r17
+  rcall twiStart                         ; (R22)
+  ldi r16, (DS3231_ADDR*2)               ; write access
+  rcall twiSendByteExpectAck             ; (R16, R17, R18, R22)
+  brcc ds3231SendData_error
+
+  mov r16, r20                           ; address
+  rcall twiSendByteExpectAck             ; (R16, R17, R18, R22)
+  brcc ds3231SendData_error
+
+  clr r20
+ds3231SendData_loop1:
+    ld r16, Z+
+    rcall twiSendByteExpectAck             ; (R16, R17, R18, R22)
+    brcc ds3231SendData_error
+    inc r20
+    dec r19
+  brne ds3231SendData_loop1
+  rcall twiStop                          ; (R22)
+  mov r16, r20
+  sec
+  ret
+ds3231SendData_error:
+  rcall twiStop                          ; (R22)
+  clc
+  ret
+; @end
+
+
+
diff --git a/avr/modules/rtc/ds3231/recv.asm b/avr/modules/rtc/ds3231/recv.asm
new file mode 100644
index 0000000..380899c
--- /dev/null
+++ b/avr/modules/rtc/ds3231/recv.asm
@@ -0,0 +1,57 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+
+
+; ***************************************************************************
+; defs
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+Ds3231_OnPacketReceived:
+  adiw xh:xl, NETMSG_OFFS_CMD               ; command
+  ld r16, X
+  sbiw xh:xl, NETMSG_OFFS_CMD
+  cpi r16, NETMSG_CMD_TIME_REQSET
+  breq Ds3231_OnPacketReceived_set
+  clc                                       ; unexpected msg
+  ret
+Ds3231_OnPacketReceived_set:
+  ldi zl, LOW(ds3231RecvBuffer)
+  ldi zh, HIGH(ds3231RecvBuffer)
+  bigcall netMsgTimeRead                    ; r22=sender, r23=command, r25:r24=msg id
+  
+  push r22
+    push r15
+      in r15, SREG
+      cli
+      clr r16
+      ldi r17, 7
+      ldi zl, LOW(ds3231RecvBuffer)
+      ldi zh, HIGH(ds3231RecvBuffer)
+      rcall ds3231SendData                  ; (r16, r17, r18, r19, r20, r22, Z)
+      out SREG, r15
+    pop r15
+  pop r22
+  
+  lds r16, ds3231Flags
+  sbr r16, (1<<DS3231_FLAGS_VALID_BIT)
+  sts ds3231Flags, r16
+#ifdef MODULES_NETWORK
+  rcall Ds3231RespondToSetTime
+#endif
+  sec
+  ret
+; @end
+
+
diff --git a/avr/modules/rtc/ds3231/send.asm b/avr/modules/rtc/ds3231/send.asm
new file mode 100644
index 0000000..c3e2765
--- /dev/null
+++ b/avr/modules/rtc/ds3231/send.asm
@@ -0,0 +1,113 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+
+
+; ***************************************************************************
+; defs
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+
+; ---------------------------------------------------------------------------
+; @routine Ds3231_AnnounceTime
+;
+; @return CFLAG on success, cleared on error
+; @clobbers R16, R17, R18, R19, R20, R21, R23, R24, R25, X, Y, Z
+
+Ds3231_AnnounceTime:
+  ldi r22, 0xff
+  ldi r23, NETMSG_CMD_TIME_ANNOUNCE
+  clr r24
+  clr r25
+  rjmp ds3231SendTime
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine Ds3231RespondToSetTime
+;
+; @return CFLAG on success, cleared on error
+; @param r22     dest address
+; @param r25:r24 msg id/ref msg id
+
+Ds3231RespondToSetTime:
+  ldi r23, NETMSG_CMD_TIME_RSPSET
+  rjmp ds3231SendTime
+
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ds3231SendTime
+;
+; @return CFLAG on success, cleared on error
+; @param r22     dest address
+; @param r23     command
+; @param r25:r24 msg id/ref msg id
+
+ds3231SendTime:
+  lds r16, ds3231Flags
+  clc
+  sbrs r16, DS3231_FLAGS_VALID_BIT
+    rjmp Ds3231_SendTime_ret
+
+  ; allocate network buffer
+  rcall NET_Buffer_Alloc                 ; (R16, R17, X)
+  brcc Ds3231_SendTime_ret
+
+  push r16                               ; buffer number
+    mov r16, r22
+    adiw xh:xl, 1
+    ldi yl, LOW(netInterfaceData)
+    ldi yh, HIGH(netInterfaceData)
+    ldi zl, LOW(ds3231RecvBuffer)
+    ldi zh, HIGH(ds3231RecvBuffer)
+    bigcall netMsgTimeWrite
+    sbiw xh:xl, 1
+  pop r16                                ; buffer number
+  rcall NET_Interface_AddOrReleaseOutMsg ; (R16, R17, R18, X)
+Ds3231_SendTime_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine ds3231SendDebug
+;
+; @return CFLAG on success, cleared on error
+
+ds3231SendDebug:
+  ; allocate network buffer
+  rcall NET_Buffer_Alloc                 ; (R16, R17, X)
+  brcc ds3231SendDebug_ret
+
+  push r16                               ; buffer number
+    mov r16, r22
+    adiw xh:xl, 1
+    ldi yl, LOW(netInterfaceData)
+    ldi yh, HIGH(netInterfaceData)
+
+    ldi r20, ds3231DataEnd-ds3231DataBegin
+    ldi zl, LOW(ds3231DataBegin)
+    ldi zh, HIGH(ds3231DataBegin)
+    bigcall NETMSG_Debug_Write2
+    sbiw xh:xl, 1
+  pop r16                                ; buffer number
+  rcall NET_Interface_AddOrReleaseOutMsg ; (R16, R17, R18, X)
+ds3231SendDebug_ret:
+  ret
+; @end
+