From 245181112ae86646c3f0b07a70626e0145819804 Mon Sep 17 00:00:00 2001
From: Martin Preuss <martin@aquamaniac.de>
Date: Fri, 8 May 2026 00:31:31 +0200
Subject: [PATCH] gui: started with dialog NodeValueId

- lets you input a node address and a value id
- needed e.g. for light settings
---
 avr/modules/lcd2/gui/aqhome/d_nodevalueid.asm | 317 ++++++++++++++++++
 1 file changed, 317 insertions(+)
 create mode 100644 avr/modules/lcd2/gui/aqhome/d_nodevalueid.asm

diff --git a/avr/modules/lcd2/gui/aqhome/d_nodevalueid.asm b/avr/modules/lcd2/gui/aqhome/d_nodevalueid.asm
new file mode 100644
index 0000000..34d7787
--- /dev/null
+++ b/avr/modules/lcd2/gui/aqhome/d_nodevalueid.asm
@@ -0,0 +1,317 @@
+; ***************************************************************************
+; copyright   : (C) 2026 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+#ifndef AQH_AVR_GUI2_AQHOME_D_NODEVALUEID_ASM
+#define AQH_AVR_GUI2_AQHOME_D_NODEVALUEID_ASM
+
+
+; ***************************************************************************
+; defines
+
+
+; widget
+.equ DLGNODEVALUEID_OFFS_BEGIN            = CDIALOG_SIZE
+.equ DLGNODEVALUEID_SIZE                  = DLGNODEVALUEID_OFFS_BEGIN+0
+
+
+; selectors
+.equ DLGNODEVALUEID_SEL_DIALOG_OK    = 1
+.equ DLGNODEVALUEID_SEL_DIALOG_ABORT = 2
+.equ DLGNODEVALUEID_SEL_NODEADDR     = 3
+.equ DLGNODEVALUEID_SEL_VALUEID      = 4
+
+
+
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_new @global
+;
+; @param  Y       pointer to GUIAPP
+; @param  r21:r20 ressource id for title
+; @return CFLAG   set of okay, cleared otherwise
+; @return Y       address of newly created object
+
+DlgNodeValueId_new:
+  bigcall GuiApp_GetRootWindow        ; r19:r18=root window (none)
+  brcc DlgNodeValueId_new_ret
+  mov xl, r18                         ; use root window as parent for main window
+  mov xh, r19
+  ldi r24, LOW(DLGNODEVALUEID_SIZE)
+  ldi r25, HIGH(DLGNODEVALUEID_SIZE)
+  push r20
+    push r21
+      bigcall Object_Alloc            ; Y=space (!r16, !r17, !X)
+    pop r21
+  pop r20
+  brcc DlgNodeValueId_new_ret
+  rcall DlgNodeValueId_Init
+DlgNodeValueId_new_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_Init @global
+;
+; @param  Y       pointer to dialog
+; @param  X       pointer to root window
+; @param  r21:r20 ressource id for title
+; @return CFLAG set of okay, cleared otherwise
+; @clobbers any, !Y
+
+DlgNodeValueId_Init:
+  ldi r16, 0                                                                                           ; OPTS
+  ldi r17, (WIDGET_PACK_FILLED<<WIDGET_PACK_HSELF0_BIT) | (WIDGET_PACK_FILLED<<WIDGET_PACK_VSELF0_BIT) ; PACK
+  ldi r22, LOW(DlgNodeValueId_Config*2)
+  ldi r23, HIGH(DlgNodeValueId_Config*2)
+  bigcall CDialog_Init               ; Y=main window
+  brcc DlgNodeValueId_Init_ret
+
+  ; set default signal map
+  ldi r16, LOW(DlgNodeValueId_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_LO, r16
+  ldi r16, HIGH(DlgNodeValueId_DefaultSignalmap*2)
+  std Y+OBJECT_OFFS_SIGNALMAP_HI, r16
+
+DlgNodeValueId_Init_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_SetNodeAddr @global
+;
+; @param Y pointer to dialog
+; @param X new value (only xl used)
+; @clobbers any, !Y
+
+DlgNodeValueId_SetNodeAddr:
+  ldi r16, DLGNODEVALUEID_SEL_NODEADDR
+  rjmp dlgNodeValueIdSetChildValue
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_GetNodeAddr @global
+;
+; @param  Y       pointer to dialog
+; @return r19:r18 value
+; @clobbers any, !Y
+
+DlgNodeValueId_GetNodeAddr:
+  ldi r16, DLGNODEVALUEID_SEL_NODEADDR
+  rjmp dlgNodeValueIdGetChildValue
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_SetValueId @global
+;
+; @param Y pointer to dialog
+; @param X new value (only xl used)
+; @clobbers any, !Y
+
+DlgNodeValueId_SetValueId:
+  ldi r16, DLGNODEVALUEID_SEL_VALUEID
+  rjmp dlgNodeValueIdSetChildValue
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_GetValueId @global
+;
+; @param  Y       pointer to dialog
+; @return r19:r18 value
+; @clobbers any, !Y
+
+DlgNodeValueId_GetValueId:
+  ldi r16, DLGNODEVALUEID_SEL_VALUEID
+  rjmp dlgNodeValueIdGetChildValue
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine dlgNodeValueIdSetChildValue
+;
+; @param Y pointer to dialog
+; @param X   new value
+; @param R16 selector of child to set value to
+; @clobbers any, !Y
+
+dlgNodeValueIdSetChildValue:
+  bigcall CDialog_GetChildBySelector   ; r19:r18=result (R16-R19)
+  brcc dlgNodeValueIdSetChildValue_ret
+  push yl
+    push yh
+      mov yl, r18
+      mov yh, r19
+      bigcall Widget_SetCurrentValue
+    pop yh
+  pop yl
+dlgNodeValueIdSetChildValue_ret:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine dlgNodeValueIdGetChildValue
+;
+; @param Y pointer to dialog
+; @param R16 selector of child to set value to
+; @clobbers any, !Y
+
+dlgNodeValueIdGetChildValue:
+  bigcall CDialog_GetChildBySelector   ; r19:r18=result (R16-R19)
+  brcc dlgNodeValueIdGetChildValue_retZero
+  push yl
+    push yh
+      mov yl, r18
+      mov yh, r19
+      bigcall Widget_GetCurrentValue
+    pop yh
+  pop yl
+  brcs dlgNodeValueIdGetChildValue_ret
+dlgNodeValueIdGetChildValue_retZero:
+  clr r18
+  clr r19
+dlgNodeValueIdGetChildValue_ret:
+  ret
+; @end
+
+
+
+; ***************************************************************************
+; signal handlers
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_OnOk @global
+;
+; @param Y pointer to dialog
+; @clobbers any, !Y
+
+DlgNodeValueId_OnOk:
+  sec
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine DlgNodeValueId_OnAbort @global
+;
+; @param Y pointer to dialog
+; @clobbers any, !Y
+
+DlgNodeValueId_OnAbort:
+  sec
+  ret
+; @end
+
+
+
+
+
+; ***************************************************************************
+; data in FLASH
+
+
+
+; dialog setup data
+DlgNodeValueId_Config:
+  .db CWIDGETCFG_MAINWIDGET_TYPE_MLAYOUT, 0                 ; TYPE, FLAGS
+  .db 2, 0                                                  ; PARAM1, PARAM2
+  
+  ; line 1, left widget
+  .db CWIDGETCFG_WIDGET_TYPE_LABEL, 0                       ; TYPE, FLAGS
+  .db 0, 0                                                  ; SELECTOR, RESERVED
+  .db 0, (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
+         (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
+         (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
+         (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)    ; OPTS, PACK
+  .dw 0                                                     ; STYLE
+  .dw RESSOURCE_TXT_NODEADDR                                ; PARAM1, PARAM2
+  .dw 0                                                     ; PARAM3, PARAM4
+  .dw 0, 0                                                  ; MINVAL, MAXVAL
+
+  ; line 1, right widget
+  .db CWIDGETCFG_WIDGET_TYPE_HSPINNER, (1<<CWIDGETCFG_WIDGET_FLAGS_MINMAXVALUES_BIT)  ; TYPE, FLAGS
+  .db DLGNODEVALUEID_SEL_NODEADDR, 0                        ; SELECTOR, RESERVED
+  .db (1<<WIDGET_OPTS_BORDER_BIT), \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
+  .dw 0                                                     ; STYLE
+  .db 0, 5                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
+  .dw 0                                                     ; PARAM3, PARAM4
+  .dw 1, 254                                                ; MINVAL, MAXVAL
+
+  ; line 2, left widget
+  .db CWIDGETCFG_WIDGET_TYPE_LABEL, 0                       ; TYPE, FLAGS
+  .db 0, 0                                                  ; SELECTOR, RESERVED
+  .db 0, \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
+  .dw 0                                                     ; STYLE
+  .dw RESSOURCE_TXT_VALUEID                                 ; PARAM1, PARAM2
+  .dw 0                                                     ; PARAM3, PARAM4
+  .dw 0, 0                                                  ; MINVAL, MAXVAL
+
+
+  ; line 2, right widget
+  .db CWIDGETCFG_WIDGET_TYPE_HSPINNER, (1<<CWIDGETCFG_WIDGET_FLAGS_MINMAXVALUES_BIT)  ; TYPE, FLAGS
+  .db DLGNODEVALUEID_SEL_VALUEID, 0                         ; SELECTOR, RESERVED
+  .db (1<<WIDGET_OPTS_BORDER_BIT), \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HSELF0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VSELF0_BIT) | \
+      (WIDGET_PACK_BEGIN<<WIDGET_PACK_HCONTENT0_BIT) | \
+      (WIDGET_PACK_CENTER<<WIDGET_PACK_VCONTENT0_BIT)       ; OPTS, PACK
+  .dw 0                                                     ; STYLE
+  .db 0, 5                                                  ; PARAM1, PARAM2 (postkomma digits, total digits)
+  .dw 0                                                     ; PARAM3, PARAM4
+  .dw 1, 255                                                ; MINVAL, MAXVAL
+
+  ; end of configuration
+  .dw 0
+
+
+
+; signal map
+DlgNodeValueId_DefaultSignalmap:
+  ; header
+  .dw MainWindow_DefaultSignalmap*2  ; next table to use
+
+  ; entries
+  .db DLGNODEVALUEID_SEL_DIALOG_OK,    WIDGET_SIGNAL_COMMAND,  LOW(DlgNodeValueId_OnOk),    HIGH(DlgNodeValueId_OnOk)
+  .db DLGNODEVALUEID_SEL_DIALOG_ABORT, WIDGET_SIGNAL_COMMAND,  LOW(DlgNodeValueId_OnAbort), HIGH(DlgNodeValueId_OnAbort)
+  ; end of table
+  .db 0, 0, 0, 0
+
+
+
+#endif
+