martin/aqhomecontrol
Public Access
1
0
Fork 0
Code Issues Pull Requests Packages Projects Releases Wiki Activity

c03: removed outdated files.

Browse Source
This commit is contained in:
Martin Preuss
2026-01-19 23:25:59 +01:00
parent 3225350be5
commit 242c3061bf
2 changed files with 0 additions and 494 deletions
Download Patch File Download Diff File Expand all files Collapse all files

307
avr/devices/c03/main/dlg_netstats.asm
View File

@@ -1,307 +0,0 @@
; ***************************************************************************
; copyright : (C) 2025 by Martin Preuss
; email : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome". *
; * Please see toplevel file COPYING of that project for license details. *
; ***************************************************************************
#ifndef AQH_AVR_DEVICE_C03_DLG_NETSTATS_ASM
#define AQH_AVR_DEVICE_C03_DLG_NETSTATS_ASM
.equ DLG_NETSTATS_TIMER_100ms = 50
.equ DLG_NETSTATS_FLAGS_BUTTON_DOWN_BIT = 0
.cseg
DlgNetStats_Init:
ldi yl, LOW(dlgNetstats)
ldi yh, HIGH(dlgNetstats)
bigcall Dialog_Init
; set handler
ldi r16, LOW(DlgNetStats_Handler)
std Y+DIALOG_OFFS_HANDLER_LO, r16
ldi r16, HIGH(DlgNetStats_Handler)
std Y+DIALOG_OFFS_HANDLER_HI, r16
; clear vars
clr r16
sts dlgNetstatsUpdateNum, r16
sts dlgNetstatsUpdateNum+1, r16
sts dlgNetstatsTimer, r16
sts dlgNetstatsFlags, r16
ret
; @end
DlgNetStats_Handler:
cpi r23, (DIALOG_FN_TIMER+1)
brcc DlgNetStats_Handler_ret
ldi zl, LOW(DlgNetStats_Handler_Fns)
ldi zh, HIGH(DlgNetStats_Handler_Fns)
add zl, r23
adc zh, r23
sub zh, r23
ijmp
DlgNetStats_Handler_ret:
ret
; @end
DlgNetStats_Handler_Fns:
rjmp dlgNetStatsOnInit
rjmp dlgNetStatsOnFini
rjmp dlgNetStatsOnShow
rjmp dlgNetStatsOnHide
rjmp dlgNetStatsOnTouch
rjmp dlgNetStatsOnTimer
dlgNetStatsOnInit:
ret
dlgNetStatsOnFini:
ret
dlgNetStatsOnShow:
push yl
push yh
mov yl, xl
mov yh, xh
rcall DlgNetStats_Show
pop yh
pop yl
ret
dlgNetStatsOnHide:
ret
dlgNetStatsOnTouch:
mov r16, r18
mov yl, xl
mov yh, xh
; check close button
push r18
rcall dlgNetStatsCheckCloseButton
pop r18
brcs dlgNetStatsOnTouch_closeActivated
rjmp dlgNetStatsTouch_ret
dlgNetStatsOnTouch_closeActivated:
; close activated, TODO
dlgNetStatsTouch_ret:
ret
dlgNetStatsCheckCloseButton:
ldi zl, LOW(dlgNetstats_CloseBtn*2)
ldi zh, HIGH(dlgNetstats_CloseBtn*2)
clr r19
lds r16, dlgNetstatsFlags
sbrc r16, DLG_NETSTATS_FLAGS_BUTTON_DOWN_BIT
sbr r19, (1<<BUTTON_STATE_DOWN_BIT)
bigcall Button_HandleTouch
lds r16, dlgNetstatsFlags
cbr r16, (1<<DLG_NETSTATS_FLAGS_BUTTON_DOWN_BIT)
sbrc r19, 0
sbr r16, (1<<DLG_NETSTATS_FLAGS_BUTTON_DOWN_BIT)
sts dlgNetstatsFlags, r16
clc
sbrs r19, BUTTON_STATE_ACTIVATED_BIT
rjmp dlgNetStatsCheckCloseButton_ret
; button activated
sec
dlgNetStatsCheckCloseButton_ret:
ret
dlgNetStatsOnTimer:
ldd r16, Y+DIALOG_OFFS_OPTIONS
andi r16, (1<<DIALOG_OPT_ACTIVE_BIT)
breq dlgNetStatsTimer_ret ; not visible, hold timer
lds r16, dlgNetstatsTimer
inc r16
sts dlgNetstatsTimer, r16
cpi r16, DLG_NETSTATS_TIMER_100ms
brcs dlgNetStatsTimer_ret
push yl
push yh
mov yl, xl
mov yh, xh
rcall DlgNetStats_Update
pop yh
pop yl
clr r16
sts dlgNetstatsTimer, r16
dlgNetStatsTimer_ret:
ret
; @param @0 Y
; @param @1 label addr
.macro DLGNETSTATS_PRINTLABEL
; packets in
ldi zl, LOW(@1 * 2)
ldi zh, HIGH(@1 * 2)
ldi r16, 2 ; X
mov r4, r16
clr r5
ldi r16, LOW(STYLE_WIN_TITLE_HEIGHT+@0) ; Y
mov r6, r16
ldi r16, HIGH(STYLE_WIN_TITLE_HEIGHT+@0)
mov r7, r16
bigcall Window_DrawTextFlash
.endmacro
; @param @0 X
; @param @1 Y
; @param @2 data address
.macro DLGNETSTATS_PRINTDATA
ldi r16, @0 ; X
mov r4, r16
clr r5
ldi r16, LOW(STYLE_WIN_TITLE_HEIGHT+@1) ; Y
mov r6, r16
ldi r16, HIGH(@1)
mov r7, r16
lds r16, @2 ; data
lds r17, @2+1
bigcall Window_WriteHexWordAt
.endmacro
DlgNetStats_Show:
; draw title window basics (with title)
ldi zl, LOW(dlgNetstats_title*2)
ldi zh, HIGH(dlgNetstats_title*2)
bigcall TitleWindow_DrawTitle
bigcall TitleWindow_ClearContentArea
; packets in
DLGNETSTATS_PRINTLABEL 2, dlgNetstats_lPacketsIn
; packets out
DLGNETSTATS_PRINTLABEL 1*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstats_lPacketsOut
; eContent
DLGNETSTATS_PRINTLABEL 2*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstats_lContentErr
; eIO
DLGNETSTATS_PRINTLABEL 3*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstats_lIoErr
; eMsgSize
DLGNETSTATS_PRINTLABEL 4*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstats_lMsgSizeErr
; update num
DLGNETSTATS_PRINTLABEL 5*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstats_lUpdate
; draw horizontal line
ldi r16, 4 ; x
mov r4, r16
clr r5
ldi r16, LOW((DISPLAY_HEIGHT-8)-(STYLE_WIN_FONT_HEIGHT+4))
mov r6, r16 ; y
ldi r16, HIGH((DISPLAY_HEIGHT-8)-(STYLE_WIN_FONT_HEIGHT+4))
mov r7, r16
ldi r16, LOW(DISPLAY_WIDTH-8)
mov r8, r16 ; w
ldi r16, HIGH(DISPLAY_WIDTH-8)
mov r9, r16
ldi r16, LOW(STYLE_WIN_FOREGROUND)
mov r2, r16 ; color
ldi r16, HIGH(STYLE_WIN_FOREGROUND)
mov r3, r16
bigcall Display_DrawHLine
; draw "close" button
ldi zl, LOW(dlgNetstats_CloseBtn*2)
ldi zh, HIGH(dlgNetstats_CloseBtn*2)
bigcall Button_Draw_Up
; show values
rcall DlgNetStats_Update
ret
; @end
DlgNetStats_Update:
lds r16, dlgNetstatsUpdateNum
inc r16
sts dlgNetstatsUpdateNum, r16
; packets in
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 2, netInterfaceData+NET_IFACE_OFFS_PACKETSIN_LOW
; packets out
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 1*(2+STYLE_WIN_FONT_HEIGHT), netInterfaceData+NET_IFACE_OFFS_PACKETSOUT_LOW
; eContent
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 2*(2+STYLE_WIN_FONT_HEIGHT), netInterfaceData+NET_IFACE_OFFS_ERR_CONTENT_LOW
; eIO
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 3*(2+STYLE_WIN_FONT_HEIGHT), netInterfaceData+NET_IFACE_OFFS_ERR_IO_LOW
; eMsgSize
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 4*(2+STYLE_WIN_FONT_HEIGHT), netInterfaceData+NET_IFACE_OFFS_ERR_MSGSIZE_LOW
DLGNETSTATS_PRINTDATA (12*STYLE_WIN_FONT_WIDTH), 5*(2+STYLE_WIN_FONT_HEIGHT), dlgNetstatsUpdateNum
ret
; @end
dlgNetstats_title: .db "Network Statistics", 0, 0
dlgNetstats_lPacketsIn: .db "Pkgs In :", 0
dlgNetstats_lPacketsOut: .db "Pkgs Out:", 0
dlgNetstats_lContentErr: .db "eContent:", 0
dlgNetstats_lIoErr: .db "eIO :", 0
dlgNetstats_lMsgSizeErr: .db "eMsgSize:", 0
dlgNetstats_lUpdate: .db "Update :", 0
dlgNetstats_lClose: .db "Close", 0
dlgNetstats_CloseBtn:
; .dw ((DISPLAY_WIDTH-((5*STYLE_WIN_FONT_WIDTH)+4))/2) ; 5 = string length ("close")
.dw ((DISPLAY_WIDTH-4-((5*STYLE_WIN_FONT_WIDTH)+4))) ; 5 = string length ("close"), align right
.dw ((DISPLAY_HEIGHT-4)-(STYLE_WIN_FONT_HEIGHT+4))
.dw (5*STYLE_WIN_FONT_WIDTH)+4 ; 5 = string length ("close")
.dw (STYLE_WIN_FONT_HEIGHT+4)
.dw (dlgNetstats_lClose*2)
.dseg
dlgNetstats: .byte DIALOG_SIZE
dlgNetstatsUpdateNum: .byte 2
dlgNetstatsTimer: .byte 1
dlgNetstatsFlags: .byte 1
#endif ; AQH_AVR_DEVICE_C03_DLG_NETSTATS_ASM

187
avr/devices/c03/main/win_netstats.asm
View File

@@ -1,187 +0,0 @@
; ***************************************************************************
; copyright : (C) 2025 by Martin Preuss
; email : martin@libchipcard.de
;
; ***************************************************************************
; * This file is part of the project "AqHome". *
; * Please see toplevel file COPYING of that project for license details. *
; ***************************************************************************
#ifndef AQH_AVR_DEVICE_C02_WIN_NETSTATS_ASM
#define AQH_AVR_DEVICE_C02_WIN_NETSTATS_ASM
.cseg
WinNetStats_Init:
clr r16
sts winNetstatsUpdateNum, r16
sts winNetstatsUpdateNum+1, r16
; setup
ldi yl, LOW(winNetstats)
ldi yh, HIGH(winNetstats)
bigcall TitleWindow_Init
ldi zl, LOW(STYLE_WIN_FONT*2)
ldi zh, HIGH(STYLE_WIN_FONT*2)
std Y+WIN_OFFS_FONT_LO, zl
std Y+WIN_OFFS_FONT_HI, zh
bigcall TitleWindow_SetFullSize
bigcall TitleWindow_SetStyleColors
ret
; @end
; @param @0 Y
; @param @1 label addr
.macro WINNETSTATS_PRINTLABEL
; packets in
ldi zl, LOW(@1 * 2)
ldi zh, HIGH(@1 * 2)
ldi r16, 2 ; X
mov r4, r16
clr r5
ldi r16, LOW(STYLE_WIN_TITLE_HEIGHT+@0) ; Y
mov r6, r16
ldi r16, HIGH(STYLE_WIN_TITLE_HEIGHT+@0)
mov r7, r16
bigcall Window_DrawTextFlash
.endmacro
; @param @0 X
; @param @1 Y
; @param @2 data address
.macro WINNETSTATS_PRINTDATA
ldi r16, @0 ; X
mov r4, r16
clr r5
ldi r16, LOW(STYLE_WIN_TITLE_HEIGHT+@1) ; Y
mov r6, r16
ldi r16, HIGH(@1)
mov r7, r16
lds r16, @2 ; data
lds r17, @2+1
bigcall Window_WriteHexWordAt
.endmacro
WinNetStats_Show:
; draw title window basics (with title)
ldi yl, LOW(winNetstats)
ldi yh, HIGH(winNetstats)
ldi zl, LOW(winNetstats_title*2)
ldi zh, HIGH(winNetstats_title*2)
bigcall TitleWindow_DrawTitle
bigcall TitleWindow_ClearContentArea
; packets in
WINNETSTATS_PRINTLABEL 2, winNetstats_lPacketsIn
; packets out
WINNETSTATS_PRINTLABEL 24, winNetstats_lPacketsOut
; eContent
WINNETSTATS_PRINTLABEL 46, winNetstats_lContentErr
; eIO
WINNETSTATS_PRINTLABEL 68, winNetstats_lIoErr
; eMsgSize
WINNETSTATS_PRINTLABEL 90, winNetstats_lMsgSizeErr
; draw horizontal line
ldi r16, STYLE_WIN_TITLE_HEIGHT+112
mov r6, r16
clr r7
clr r4
clr r5
ldi r16, LOW(DISPLAY_WIDTH)
mov r8, r16
ldi r16, HIGH(DISPLAY_WIDTH)
mov r9, r16
clr r2
clr r3
bigcall Display_DrawHLine
; X
WINNETSTATS_PRINTLABEL 114, winNetstats_lX
; Y
WINNETSTATS_PRINTLABEL 136, winNetstats_lY
; Z
WINNETSTATS_PRINTLABEL 158, winNetstats_lZ
; update num
WINNETSTATS_PRINTLABEL 180, winNetstats_lUpdate
rcall WinNetStats_Update
ret
; @end
WinNetStats_Update:
lds r16, winNetstatsUpdateNum
inc r16
sts winNetstatsUpdateNum, r16
ldi yl, LOW(winNetstats)
ldi yh, HIGH(winNetstats)
; packets in
WINNETSTATS_PRINTDATA 160, 2, netInterfaceData+NET_IFACE_OFFS_PACKETSIN_LOW
; packets out
WINNETSTATS_PRINTDATA 160, 24, netInterfaceData+NET_IFACE_OFFS_PACKETSOUT_LOW
; eContent
WINNETSTATS_PRINTDATA 160, 46, netInterfaceData+NET_IFACE_OFFS_ERR_CONTENT_LOW
; eIO
WINNETSTATS_PRINTDATA 160, 68, netInterfaceData+NET_IFACE_OFFS_ERR_IO_LOW
; eMsgSize
WINNETSTATS_PRINTDATA 160, 90, netInterfaceData+NET_IFACE_OFFS_ERR_MSGSIZE_LOW
; X
WINNETSTATS_PRINTDATA 160, 114, xpt2046CurrentX
WINNETSTATS_PRINTDATA 240, 114, xpt2046RawX
; Y
WINNETSTATS_PRINTDATA 160, 136, xpt2046CurrentY
WINNETSTATS_PRINTDATA 240, 136, xpt2046RawY
; Z
WINNETSTATS_PRINTDATA 160, 158, xpt2046CurrentZ
; update num
WINNETSTATS_PRINTDATA 160, 180, winNetstatsUpdateNum
ret
; @end
winNetstats_title: .db "Network Statistics", 0, 0
winNetstats_lPacketsIn: .db "Pkgs In :", 0
winNetstats_lPacketsOut: .db "Pkgs Out:", 0
winNetstats_lContentErr: .db "eContent:", 0
winNetstats_lIoErr: .db "eIO :", 0
winNetstats_lMsgSizeErr: .db "eMsgSize:", 0
winNetstats_lX: .db "X :", 0
winNetstats_lY: .db "Y :", 0
winNetstats_lZ: .db "Z :", 0
winNetstats_lUpdate: .db "Update :", 0
.dseg
winNetstats:
.byte WIN_SIZE
.dseg
winNetstatsUpdateNum: .byte 2
#endif