make router functionality of r05 an app.

avr/apps/0BUILD

@@ -9,6 +9,7 @@
     network
     reportsensors
     stats
+    router
   </subdirs>
 
   <extradist>

avr/apps/router/0BUILD

@@ -0,0 +1,15 @@
+<?xml?>
+
+<gwbuild>
+
+  <subdirs>
+  </subdirs>
+
+  <extradist>
+    main.asm
+  </extradist>
+  
+
+</gwbuild>
+
+

avr/apps/router/main.asm

@@ -0,0 +1,158 @@
+; ***************************************************************************
+; copyright   : (C) 2025 by Martin Preuss
+; email       : martin@libchipcard.de
+;
+; ***************************************************************************
+; * This file is part of the project "AqHome".                              *
+; * Please see toplevel file COPYING of that project for license details.   *
+; ***************************************************************************
+
+
+
+; ***************************************************************************
+; defines
+
+; ---------------------------------------------------------------------------
+; network interfaces
+
+.equ NETDEV0_IFACENUM = 1
+.equ NETDEV1_IFACENUM = 2
+
+
+
+; ***************************************************************************
+; code
+
+.cseg
+
+; ---------------------------------------------------------------------------
+; @routine AppRouter_Init @global
+
+AppRouter_Init:
+  ; set interface number for NETDEV0
+  ldi r16, NETDEV0_IFACENUM
+  sts netInterfaceData+NET_IFACE_OFFS_IFACENUM, r16
+  ; set interface number for NETDEV1
+  ldi r16, NETDEV1_IFACENUM
+  sts netInterfaceData2+NET_IFACE_OFFS_IFACENUM, r16
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine AppRouter_Run @global
+;
+; Read messages from either interface and forward to the other one.
+
+AppRouter_Run:
+  rjmp appRouterCheckRecvdMsg
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine appRouterCheckRecvdMsg
+;
+; Read messages from either interface and forward to the other one.
+
+appRouterCheckRecvdMsg:
+    rcall NET_PeekNextIncomingMsgNum          ; check read queue (bufNum->r16)
+    brcc appRouterCheckRecvdMsg_end                    ; no msg, jmp
+    rcall NET_Buffer_Locate                   ; (R17)
+    ; let system handle incoming messages
+    push r16
+      adiw xh:xl, 1
+      rcall appRouterLetSysHandleMsg
+      sbiw xh:xl, 1
+    pop r16
+
+    ; forward to other interface
+    ld r17, X
+    andi r17, (1<<NET_IFACE_BUFFER_IFACENUM1_BIT) | (1<<NET_IFACE_BUFFER_IFACENUM0_BIT)
+    rcall appRouterReverseInterfaceNum                 ; (R16, R17)
+    rcall appRouterAddMsgToInterface
+    brcc appRouterCheckRecvdMsg_end                    ; could not add, jmp
+    rcall NET_GetNextIncomingMsgNum                    ; take off the queue
+  rjmp appRouterCheckRecvdMsg
+appRouterCheckRecvdMsg_end:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine appRouterLetSysHandleMsg
+;
+; @param X pointer to msg to handle (point behind the buffer header!)
+; @clobbers any, !X
+
+appRouterLetSysHandleMsg:
+  ld r16, X
+  cpi r16, 0xff
+  breq appRouterLetSysHandleMsg_forMe
+  lds r17, netInterfaceData+NET_IFACE_OFFS_ADDRESS
+  cp r16, r17
+  brne appRouterLetSysHandleMsg_end
+appRouterLetSysHandleMsg_forMe:
+  push xl
+    push xh
+      rcall onMessageReceived
+    pop xh
+  pop xl
+  push xl
+    push xh
+      rcall mainModulesOnPacketReceived
+    pop xh
+  pop xl
+  push xl
+    push xh
+      rcall mainAppsOnPacketReceived
+    pop xh
+  pop xl
+appRouterLetSysHandleMsg_end:
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine appRouterReverseInterfaceNum
+;
+; @param r17 buffer num
+; @return r17 reversed interface number
+; @clobbers r16, r17
+
+appRouterReverseInterfaceNum:
+  ldi r16, (1<<NET_IFACE_BUFFER_IFACENUM1_BIT) | (1<<NET_IFACE_BUFFER_IFACENUM0_BIT)
+  eor r17, r16
+  and r17, r16
+  ret
+; @end
+
+
+
+; ---------------------------------------------------------------------------
+; @routine appRouterAddMsgToInterface
+; @param r16 buffer num
+; @param r17 interface num
+
+appRouterAddMsgToInterface:
+  cpi r17, NETDEV0_IFACENUM
+  brne appRouterAddMsgToInterface_notNetDev0
+  ldi yl, LOW(netInterfaceData)
+  ldi yh, HIGH(netInterfaceData)
+  rjmp NET_Interface_AddOutgoingMsgNum     ; try to add msg to interface
+appRouterAddMsgToInterface_notNetDev0:
+  ldi yl, LOW(netInterfaceData2)
+  ldi yh, HIGH(netInterfaceData2)
+  rjmp NET_Interface_AddOutgoingMsgNum     ; try to add msg to interface
+appRouterAddMsgToInterface_end:
+  clc
+  ret
+; @end
+
+
+
+
+